[gentoo-commits] gentoo-x86 commit in app-i18n/ibus-table: ChangeLog ibus-table-0.1.1.20081014.ebuild

[Matsuu Takuto (matsuu)]

matsuu      08/10/19 14:18:23

  Modified:             ChangeLog
  Added:                ibus-table-0.1.1.20081014.ebuild
  Log:
  Version bumped. Fixed QA issue.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64)

Revision  Changes    Path
1.2                  app-i18n/ibus-table/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus-table/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus-table/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus-table/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/ibus-table/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	10 Sep 2008 00:18:25 -0000	1.1
+++ ChangeLog	19 Oct 2008 14:18:23 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/ibus-table
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-table/ChangeLog,v 1.1 2008/09/10 00:18:25 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-table/ChangeLog,v 1.2 2008/10/19 14:18:23 matsuu Exp $
+
+*ibus-table-0.1.1.20081014 (19 Oct 2008)
+
+  19 Oct 2008; MATSUU Takuto <matsuu@g.o>
+  +ibus-table-0.1.1.20081014.ebuild:
+  Version bumped. Fixed QA issue.
 
 *ibus-table-0.1.1.20080901 (10 Sep 2008)
 



1.1                  app-i18n/ibus-table/ibus-table-0.1.1.20081014.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus-table/ibus-table-0.1.1.20081014.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus-table/ibus-table-0.1.1.20081014.ebuild?rev=1.1&content-type=text/plain

Index: ibus-table-0.1.1.20081014.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-table/ibus-table-0.1.1.20081014.ebuild,v 1.1 2008/10/19 14:18:23 matsuu Exp $

EAPI="1"
inherit eutils python

DESCRIPTION="The Table Engine for IBus Framework"
HOMEPAGE="http://code.google.com/p/ibus/"
SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+additional cangjie5 erbi-qs extra-phrases nls wubi zhengma"

RDEPEND="app-i18n/ibus
	>=dev-lang/python-2.5
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.16.1 )"

pkg_setup() {
	if ! built_with_use '>=dev-lang/python-2.5' sqlite; then
		ewarn "You need build dev-lang/python with \"sqlite\" USE flag!"
		die "Please rebuild dev-lang/python with sqlite USE flag!"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	mv py-compile py-compile.orig || die
	ln -s "$(type -P true)" py-compile || die
}

src_compile() {
	econf \
		$(use_enable additional) \
		$(use_enable cangjie5) \
		$(use_enable erbi-qs) \
		$(use_enable extra-phrases) \
		$(use_enable wubi wubi86) \
		$(use_enable wubi wubi98) \
		$(use_enable zhengma) \
		$(use_enable nls) || die

	# Parallel make uses a lot of memory to generate databases.
	emake -j1 || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	ewarn "This package is very experimental, please report your bugs to"
	ewarn "http://ibus.googlecode.com/issues/list"
	elog
	elog "You should run ibus-setup and enable IM Engines you want to use!"
	elog
	python_mod_optimize /usr/share/${PN}/engine
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}/engine
}