[gentoo-commits] gentoo-x86 commit in media-sound/amarok: metadata.xml ChangeLog amarok-2.5.0-r1.ebuild amarok-2.4.3-r1.ebuild

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    11/12/28 01:39:32

  Modified:             metadata.xml ChangeLog
  Added:                amarok-2.5.0-r1.ebuild amarok-2.4.3-r1.ebuild
  Log:
  [media-sound/amarok] Drop the player use flag until upstream allows to
  disable the player again. Apply Matěj Laitl's patch to amarok-2.5.0.
  
  (Portage version: 2.2.0_alpha83/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 media-sound/amarok/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/metadata.xml?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/metadata.xml?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/metadata.xml?r1=1.28&r2=1.29

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/metadata.xml,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- metadata.xml	19 Apr 2011 02:40:12 -0000	1.28
+++ metadata.xml	28 Dec 2011 01:39:32 -0000	1.29
@@ -19,11 +19,20 @@
       Try disabling this if you encounter -PIC related in amarok,                                                             
       it will make amarok rely only on standalone MySQL server.                                                               
     </flag>
-    <flag name="lastfm">Enable Last.fm streaming services support through <pkg>media-libs/liblastfm</pkg></flag>
+    <flag name="lastfm">
+      Enable Last.fm streaming services support through
+      <pkg>media-libs/liblastfm</pkg>
+    </flag>
     <flag name="mp3tunes">Enable mp3tunes integration</flag>
+    <flag name="ofa">
+      Use <pkg>media-libs/libofa</pkg> to compute MusicDNS acoustic
+      fingerprints (used by MusicBrainz)
+    </flag>
 	<flag name="playdar">Build the playdar collection</flag>
 	<flag name="player">Build the player</flag>
 	<flag name="upnp">Support for upnp servers</flag>
-	<flag name="utils">Build the utils - old <pkg>media-sound/amarok-utils</pkg></flag>
+	<flag name="utils">
+      Build the utils - old <pkg>media-sound/amarok-utils</pkg>
+    </flag>
   </use>
 </pkgmetadata>



1.415                media-sound/amarok/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.415&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?rev=1.415&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/ChangeLog?r1=1.414&r2=1.415

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v
retrieving revision 1.414
retrieving revision 1.415
diff -u -r1.414 -r1.415
--- ChangeLog	20 Dec 2011 09:22:09 -0000	1.414
+++ ChangeLog	28 Dec 2011 01:39:32 -0000	1.415
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/amarok
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.414 2011/12/20 09:22:09 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.415 2011/12/28 01:39:32 jmbsvicetto Exp $
+
+*amarok-2.5.0-r1 (28 Dec 2011)
+*amarok-2.4.3-r1 (28 Dec 2011)
+
+  28 Dec 2011; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +amarok-2.4.3-r1.ebuild, +amarok-2.5.0-r1.ebuild, metadata.xml:
+  [media-sound/amarok] Drop the player use flag until upstream allows to
+  disable the player again. Apply Matěj Laitl's patch to amarok-2.5.0.
 
 *amarok-2.5.0 (20 Dec 2011)
 



1.1                  media-sound/amarok/amarok-2.5.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.5.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.5.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: amarok-2.5.0-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.5.0-r1.ebuild,v 1.1 2011/12/28 01:39:32 jmbsvicetto Exp $

EAPI=4

KDE_LINGUAS="af ar ast be bg bs ca ca@valencia cs csb da de el en_GB eo es et
eu fa fi fr ga gl he hr hu is it ja km ko ku lt lv mai ml ms nb nds ne nl nn
oc pa pl pt pt_BR ro ru se si sk sl sq sr sr@ijekavian sr@ijekavianlatin
sr@Latn sv tg th tr ug uk wa zh_CN zh_TW"
KDE_SCM="git"
KDE_REQUIRED="never"
inherit flag-o-matic kde4-base

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"
if [[ ${PV} != *9999* ]]; then
	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
	KEYWORDS="~amd64 ~ppc ~x86"
else
	KEYWORDS=""
fi

LICENSE="GPL-2"
SLOT="4"
IUSE="cdda daap debug +embedded ipod lastfm mp3tunes mtp ofa opengl semantic-desktop +utils"

# Tests require gmock - http://code.google.com/p/gmock/
# It's not in the tree yet
RESTRICT="test"

# ipod requires gdk enabled and also gtk compiled in libgpod
COMMONDEPEND="
	app-crypt/qca:2
	>=app-misc/strigi-0.5.7
	$(add_kdebase_dep kdelibs 'opengl?,semantic-desktop?')
	$(add_kdebase_dep kdebase-kioslaves)
	>=media-libs/taglib-1.6.1[asf,mp4]
	>=media-libs/taglib-extras-1.0.1
	sys-libs/zlib
	>=virtual/mysql-5.1[embedded?]
	x11-libs/qt-script
	>=x11-libs/qtscriptgenerator-0.1.0
	cdda? (
		$(add_kdebase_dep libkcddb)
		$(add_kdebase_dep libkcompactdisc)
		$(add_kdebase_dep kdemultimedia-kioslaves)
	)
	ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
	lastfm? ( >=media-libs/liblastfm-0.3.0 )
	mp3tunes? (
		dev-libs/glib:2
		dev-libs/libxml2
		dev-libs/openssl
		net-libs/loudmouth
		net-misc/curl
		x11-libs/qt-core[glib]
	)
	mtp? ( >=media-libs/libmtp-1.0.0 )
	opengl? ( virtual/opengl )
"
DEPEND="${COMMONDEPEND}
	dev-util/automoc
	dev-util/pkgconfig
"
RDEPEND="${COMMONDEPEND}
	$(add_kdebase_dep phonon-kde)
	!media-sound/amarok-utils
"

src_prepare() {
	# en locale is special in a way that it is always enabled. English Amarok
	# handbook however lies in the doc/en_US folder and thus is not picked
	# up by kde4-functions eclass. Rename it.
	sed -e 's:add_subdirectory(en_US):add_subdirectory(en):' \
		-i "${S}/doc/CMakeLists.txt" \
		|| die "Replacing en_US by en in doc/CMakeLists.txt failed."
	mv "${S}/doc/en_US" "${S}/doc/en" || die "Moving doc/en_US to doc/en failed."

	kde4-base_src_prepare
}

src_configure() {
	# Append minimal-toc cflag for ppc64, see bug 280552 and 292707
	use ppc64 && append-flags -mminimal-toc
	local mycmakeargs

	# Mygpo-qt not yet in portage, add IUSE when available
	mycmakeargs=(
		-DWITH_PLAYER=ON
		-DWITH_Libgcrypt=OFF
		-DWITH_Mygpo-qt=OFF
		$(cmake-utils_use embedded WITH_MYSQL_EMBEDDED)
		$(cmake-utils_use_with ipod)
		$(cmake-utils_use_with ipod Gdk)
		$(cmake-utils_use_with lastfm LibLastFm)
		$(cmake-utils_use_with mtp)
		$(cmake-utils_use_with mp3tunes MP3Tunes)
	)

	mycmakeargs+=(
		$(cmake-utils_use_with utils UTILITIES)
	)
		# $(cmake-utils_use_with semantic-desktop Nepomuk)
		# $(cmake-utils_use_with semantic-desktop Soprano)

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if use daap; then
		echo
		elog "You have installed amarok with daap support."
		elog "You may be interested in installing www-servers/mongrel as well."
		echo
	fi

	if ! use embedded; then
		echo
		elog "You've disabled the amarok support for embedded mysql DBs."
		elog "You'll have to configure amarok to use an external db server."
		echo
		elog "Please read http://amarok.kde.org/wiki/MySQL_Server for details on how"
		elog "to configure the external db and migrate your data from the embedded database."
		echo

		if has_version "virtual/mysql[minimal]"; then
			elog "You built mysql with the minimal use flag, so it doesn't include the server."
			elog "You won't be able to use the local mysql installation to store your amarok collection."
			echo
		fi
	fi
}



1.1                  media-sound/amarok/amarok-2.4.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/amarok/amarok-2.4.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: amarok-2.4.3-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.3-r1.ebuild,v 1.1 2011/12/28 01:39:32 jmbsvicetto Exp $

EAPI=4

KDE_LINGUAS="bg ca cs da de en_GB es et eu fi fr it ja km nb nds nl pa
pl pt pt_BR ru sl sr sr@latin sv th tr uk wa zh_TW"
KDE_SCM="git"
KDE_REQUIRED="never"
inherit flag-o-matic kde4-base

DESCRIPTION="Advanced audio player based on KDE framework."
HOMEPAGE="http://amarok.kde.org/"
if [[ ${PV} != *9999* ]]; then
	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
	KEYWORDS="~amd64 ~ppc ~x86"
else
	KEYWORDS=""
fi

LICENSE="GPL-2"
SLOT="4"
IUSE="cdda daap debug +embedded ipod lastfm mp3tunes mtp opengl semantic-desktop +utils"

# Tests require gmock - http://code.google.com/p/gmock/
# It's not in the tree yet
RESTRICT="test"

# ipod requires gdk enabled and also gtk compiled in libgpod
COMMONDEPEND="
	app-crypt/qca:2
	>=app-misc/strigi-0.5.7
	$(add_kdebase_dep kdelibs 'opengl?,semantic-desktop?')
	$(add_kdebase_dep kdebase-kioslaves)
	>=media-libs/taglib-1.6.1[asf,mp4]
	>=media-libs/taglib-extras-1.0.1
	sys-libs/zlib
	>=virtual/mysql-5.1[embedded?]
	x11-libs/qt-script
	>=x11-libs/qtscriptgenerator-0.1.0
	cdda? (
		$(add_kdebase_dep libkcddb)
		$(add_kdebase_dep libkcompactdisc)
		$(add_kdebase_dep kdemultimedia-kioslaves)
	)
	ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
	lastfm? ( >=media-libs/liblastfm-0.3.0 )
	mp3tunes? (
		dev-libs/glib:2
		dev-libs/libxml2
		dev-libs/openssl
		net-libs/loudmouth
		net-misc/curl
		x11-libs/qt-core[glib]
	)
	mtp? ( >=media-libs/libmtp-1.0.0 )
	opengl? ( virtual/opengl )
"
DEPEND="${COMMONDEPEND}
	dev-util/automoc
	dev-util/pkgconfig
"
RDEPEND="${COMMONDEPEND}
	$(add_kdebase_dep phonon-kde)
	!media-sound/amarok-utils
"

src_configure() {
	# Append minimal-toc cflag for ppc64, see bug 280552 and 292707
	use ppc64 && append-flags -mminimal-toc
	local mycmakeargs

	mycmakeargs=(
		-DWITH_PLAYER=ON
		-DWITH_Libgcrypt=OFF
		$(cmake-utils_use embedded WITH_MYSQL_EMBEDDED)
		$(cmake-utils_use_with ipod)
		$(cmake-utils_use_with ipod Gdk)
		$(cmake-utils_use_with lastfm LibLastFm)
		$(cmake-utils_use_with mtp)
		$(cmake-utils_use_with mp3tunes MP3Tunes)
	)

	mycmakeargs+=(
		$(cmake-utils_use_with utils UTILITIES)
	)
		# $(cmake-utils_use_with semantic-desktop Nepomuk)
		# $(cmake-utils_use_with semantic-desktop Soprano)

	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if use daap; then
		echo
		elog "You have installed amarok with daap support."
		elog "You may be interested in installing www-servers/mongrel as well."
		echo
	fi

	if ! use embedded; then
		echo
		elog "You've disabled the amarok support for embedded mysql DBs."
		elog "You'll have to configure amarok to use an external db server."
		echo
		elog "Please read http://amarok.kde.org/wiki/MySQL_Server for details on how"
		elog "to configure the external db and migrate your data from the embedded database."
		echo

		if has_version "virtual/mysql[minimal]"; then
			elog "You built mysql with the minimal use flag, so it doesn't include the server."
			elog "You won't be able to use the local mysql installation to store your amarok collection."
			echo
		fi
	fi
}