[gentoo-commits] gentoo-x86 commit in net-p2p/gnunet: metadata.xml ChangeLog gnunet-0.8.1-r2.ebuild gnunet-0.8.1-r1.ebuild

[Stanislav Ochotnicky (sochotnicky)]

sochotnicky    11/01/18 23:58:04

  Modified:             metadata.xml ChangeLog
  Added:                gnunet-0.8.1-r2.ebuild
  Removed:              gnunet-0.8.1-r1.ebuild
  Log:
  Fix potential buffer overflow in identity application (#339355)
  Fix bugs #351872 and #351658 (Use flag names, mysql support fix)
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-p2p/gnunet/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/gnunet/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	14 Jan 2011 00:52:11 -0000	1.2
+++ metadata.xml	18 Jan 2011 23:58:04 -0000	1.3
@@ -4,13 +4,13 @@
   <herd>net-p2p</herd>
   <longdescription>GNUnet is a framework for secure peer-to-peer networking that does not use any centralized or otherwise trusted services</longdescription>
   <use>
-    <flag name="c-ares">enable asynchronous dns support through c-ares library</flag>
-    <flag name="esmtp">enable SMTP support</flag>
+    <flag name="ares">enable asynchronous dns support through <pkg>net-dns/c-ares</pkg> library</flag>
+    <flag name="smtp">enable SMTP support using <pkg>net-libs/libesmtp</pkg></flag>
     <flag name="microhttpd">enable embedded http server support</flag>
     <flag name="setup">enable setup wizard</flag>
-    <flag name="dialog">enable ncurses dialog setup wizard</flag>
+    <flag name="ncurses">enable ncurses setup wizard using <pkg>dev-util/dialog</pkg></flag>
     <flag name="gtk">enable gtk setup wizard</flag>
-    <flag name="qt">enable qt setup wizard</flag>
+    <flag name="qt4">enable qt4 setup wizard</flag>
     <flag name="sqlite">enable sqlite database backend</flag>
     <flag name="mysql">enable mysql database backend</flag>
   </use>



1.70                 net-p2p/gnunet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/gnunet/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog	14 Jan 2011 00:52:11 -0000	1.69
+++ ChangeLog	18 Jan 2011 23:58:04 -0000	1.70
@@ -1,6 +1,14 @@
 # ChangeLog for net-p2p/gnunet
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/gnunet/ChangeLog,v 1.69 2011/01/14 00:52:11 sochotnicky Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/gnunet/ChangeLog,v 1.70 2011/01/18 23:58:04 sochotnicky Exp $
+
+*gnunet-0.8.1-r2 (18 Jan 2011)
+
+  18 Jan 2011; Stanislav Ochotnicky <sochotnicky@g.o>
+  +files/0.8.1-Fix-buffer-overflow.patch, -gnunet-0.8.1-r1.ebuild,
+  +gnunet-0.8.1-r2.ebuild, metadata.xml:
+  Fix potential buffer overflow in identity application (#339355)
+  Fix bugs #351872 and #351658 (Use flag names, mysql support fix)
 
 *gnunet-0.8.1-r1 (14 Jan 2011)
 



1.1                  net-p2p/gnunet/gnunet-0.8.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/gnunet-0.8.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gnunet/gnunet-0.8.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: gnunet-0.8.1-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/gnunet/gnunet-0.8.1-r2.ebuild,v 1.1 2011/01/18 23:58:04 sochotnicky Exp $

EAPI=2

inherit autotools eutils

S="${WORKDIR}/GNUnet-${PV}"
DESCRIPTION="GNUnet is an anonymous, distributed, reputation based network."
HOMEPAGE="http://gnunet.org/"
SRC_URI="http://gnunet.org/download/GNUnet-${PV}.tar.gz"
#tests don't work
RESTRICT="test"

IUSE="nls +sqlite mysql ares adns +setup ncurses gtk qt4 smtp microhttpd"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
LICENSE="GPL-2"
SLOT="0"

DEPEND=">=dev-libs/libgcrypt-1.2.0
	>=media-libs/libextractor-0.5.18a
	>=dev-libs/gmp-4.0.0
	net-misc/curl
	sys-libs/zlib
	sys-apps/sed
	sqlite? ( >=dev-db/sqlite-3.0.8 )
	mysql? ( >=virtual/mysql-4.0 )
	!sqlite? ( !mysql? ( >=dev-db/sqlite-3.0.8 ) )
	setup? ( >=dev-scheme/guile-1.8.0
	  ncurses? ( dev-util/dialog )
	  gtk? ( >=x11-libs/gtk+-2.6.10
			 gnome-base/libglade )
	  qt4? ( x11-libs/qt-gui )
	)
	adns? ( net-libs/adns )
	ares? ( net-dns/c-ares )
	smtp? ( net-libs/libesmtp )
	!ppc? ( !ppc64? ( !sparc? ( microhttpd? ( net-libs/libmicrohttpd ) ) ) )
	nls? ( sys-devel/gettext )"

RDEPEND="${DEPEND}"

pkg_preinst() {
	enewgroup gnunetd
	enewuser gnunetd -1 -1 /dev/null gnunetd
}

src_prepare() {
	if ! use setup && ( use ncurses || use gtk || use qt4 ); then
		ewarn
		ewarn "You chose NOT to install setup utility. Ignoring setup frontends (ncurses, gtk, qt4)."
		ewarn
	fi

	if ! use sqlite; then
		# make mysql default sqstore if we do not compile sqlite support
		# (bug #107330)
		if use mysql; then \
			sed -i 's:default "sqstore_sqlite":default "sqstore_mysql":' \
			contrib/config-daemon.in
		else
			ewarn
			ewarn "You didn't specify preferred database (mysql or sqlite)"
			ewarn "Choosing sqlite for you."
			ewarn
		fi
	fi

	# we do not want to built gtk support with USE=-gtk
	if ! use gtk ; then
		sed -i "s:AC_DEFINE_UNQUOTED..HAVE_GTK.*:true:" configure.ac
	fi

	epatch "${FILESDIR}"/${PV}-asneeded.patch
	epatch "${FILESDIR}"/${PV}-parallel-build.patch
	epatch "${FILESDIR}"/${PV}-Fix-buffer-overflow.patch
	eautoreconf
}

src_configure() {
	local myconf

	# if neither sqlite nor mysql are chosen pick sqlite
	if ! use sqlite; then
		if use mysql; then
			myconf="${myconf} --without-sqlite"
		else
			# fallback to sqlite
			myconf="${myconf} --with-sqlite"
		fi
	fi

	# doesn't work for --with-qt4 so use_with is unusable
	use qt4 || myconf="${myconf} --without-qt"
	use mysql || myconf="${myconf} --without-mysql"

	econf \
		$(use_enable nls) \
		$(use_with gtk x) \
		$(use_with ncurses dialog) \
		$(use_with adns) \
		$(use_with ares c-ares) \
		$(use_with smtp esmtp) \
		$(use_with microhttpd) \
		$(use_with setup guile) \
		${myconf} || die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog INSTALL NEWS PLATFORMS README UPDATING || die
	insinto /etc
	newins contrib/gnunet.conf gnunet.conf
	docinto contrib
	dodoc contrib/* || die
	newinitd "${FILESDIR}"/${PN}.initd gnunet
	dodir /var/lib/gnunet
	chown gnunetd:gnunetd "${D}"/var/lib/gnunet
}

pkg_postinst() {
	# make sure permissions are ok
	chown -R gnunetd:gnunetd "${ROOT}"/var/lib/gnunet

	einfo
	einfo "To configure"
	einfo "	 1) Add user(s) to the gnunetd group"
	einfo "	 2) Run 'gnunet-setup' to generate your client config file"
	einfo "	 3) Run gnunet-setup -d as root to generate a server config file"
	einfo
}