[gentoo-commits] gentoo-x86 commit in dev-lang/qu-prolog: ChangeLog qu-prolog-8.3.ebuild

[Keri Harris (keri)]

keri        07/12/22 06:28:28

  Modified:             ChangeLog
  Added:                qu-prolog-8.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.4_rc10)

Revision  Changes    Path
1.39                 dev-lang/qu-prolog/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	22 Nov 2007 05:33:10 -0000	1.38
+++ ChangeLog	22 Dec 2007 06:28:28 -0000	1.39
@@ -1,6 +1,13 @@
 # ChangeLog for dev-lang/qu-prolog
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v 1.38 2007/11/22 05:33:10 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/ChangeLog,v 1.39 2007/12/22 06:28:28 keri Exp $
+
+*qu-prolog-8.3 (22 Dec 2007)
+
+  22 Dec 2007; keri <keri@g.o> +files/qu-prolog-8.3-configure.patch,
+  +files/qu-prolog-8.3-debug.patch, +files/qu-prolog-8.3-gcc4.patch,
+  +files/qu-prolog-8.3-portage.patch, +qu-prolog-8.3.ebuild:
+  Version bump.
 
   22 Nov 2007; keri <keri@g.o> -files/qu-prolog-7.4-configure.patch,
   -files/qu-prolog-7.4-debug.patch, -files/qu-prolog-7.4-gcc4.patch,



1.1                  dev-lang/qu-prolog/qu-prolog-8.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/qu-prolog-8.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/qu-prolog/qu-prolog-8.3.ebuild?rev=1.1&content-type=text/plain

Index: qu-prolog-8.3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/qu-prolog-8.3.ebuild,v 1.1 2007/12/22 06:28:28 keri Exp $

inherit eutils

MY_P=qp${PV}

DESCRIPTION="Qu-Prolog is an extended Prolog supporting quantifiers, object-variables and substitutions"
HOMEPAGE="http://www.itee.uq.edu.au/~pjr/HomePages/QuPrologHome.html"
SRC_URI="http://www.itee.uq.edu.au/~pjr/HomePages/QPFiles/${MY_P}.tar.gz
	qt4? ( mirror://gentoo/${P}-xqp-qt4.tar.gz )"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~ppc ~sparc ~x86"
IUSE="debug doc examples qt4 threads"

DEPEND="qt4? ( >=x11-libs/qt-4.1.0 )"

S="${WORKDIR}"/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-portage.patch
	epatch "${FILESDIR}"/${P}-configure.patch
	epatch "${FILESDIR}"/${P}-gcc4.patch
	epatch "${FILESDIR}"/${P}-debug.patch
}

src_compile() {
	econf \
		$(use_enable debug) \
		$(use_enable threads multiple-threads) \
		|| die "econf failed"
	emake || die "emake failed"

	if use qt4; then
		cd "${S}"/src/xqp/qt4
		qmake || die "qmake xqp failed"
		emake || die "emake xqp failed"
	fi
}

src_install() {
	exeinto /usr/bin
	doexe src/qa src/qdeal src/qem src/ql
	doexe bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp bin/qppp

	if use qt4; then
		doexe src/xqp/qt4/xqp
	fi

	insinto /usr/$(get_libdir)/${PN}/bin
	doins prolog/qc1/qc1.qx \
		prolog/qecat/qecat.qx \
		prolog/qg/qg.qx \
		prolog/qp/qp.qx

	insinto /usr/$(get_libdir)/${PN}/library
	doins prolog/library/*.qo

	insinto /usr/$(get_libdir)/${PN}/compiler
	doins prolog/compiler/*.qo

	doman doc/man/man1/*.1

	dodoc README

	if use doc ; then
		docinto reference-manual
		dodoc doc/manual/*.html
		docinto user-guide
		dodoc doc/user/main.ps
	fi

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.ql
		docinto examples
		dodoc examples/README
	fi
}



-- 
gentoo-commits@g.o mailing list