[gentoo-commits] gentoo-x86 commit in net-mail/mpop: mpop-1.0.26.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    12/01/08 04:27:20

  Modified:             ChangeLog
  Added:                mpop-1.0.26.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  net-mail/mpop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mpop/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mpop/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mpop/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/mpop/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	17 Oct 2011 18:12:36 -0000	1.1
+++ ChangeLog	8 Jan 2012 04:27:20 -0000	1.2
@@ -1,6 +1,11 @@
 # ChangeLog for net-mail/mpop
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/mpop/ChangeLog,v 1.1 2011/10/17 18:12:36 radhermit Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-mail/mpop/ChangeLog,v 1.2 2012/01/08 04:27:20 radhermit Exp $
+
+*mpop-1.0.26 (08 Jan 2012)
+
+  08 Jan 2012; Tim Harder <radhermit@g.o> +mpop-1.0.26.ebuild:
+  Version bump.
 
 *mpop-1.0.25 (17 Oct 2011)
 



1.1                  net-mail/mpop/mpop-1.0.26.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mpop/mpop-1.0.26.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mpop/mpop-1.0.26.ebuild?rev=1.1&content-type=text/plain

Index: mpop-1.0.26.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/mpop/mpop-1.0.26.ebuild,v 1.1 2012/01/08 04:27:20 radhermit Exp $

EAPI="4"

inherit python

DESCRIPTION="A small, fast, and portable POP3 client"
HOMEPAGE="http://mpop.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome-keyring gnutls idn nls sasl ssl vim-syntax"

RDEPEND="
	gnome-keyring? (
		dev-python/gnome-keyring-python
		gnome-base/libgnome-keyring
	)
	idn? ( net-dns/libidn )
	nls? ( virtual/libintl )
	sasl? ( virtual/gsasl )
	ssl? (
		gnutls? ( net-libs/gnutls )
		!gnutls? ( dev-libs/openssl )
	)"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	dev-util/pkgconfig"

REQUIRED_USE="gnutls? ( ssl )"

DOCS="AUTHORS ChangeLog NEWS NOTES README THANKS"

src_prepare() {
	python_convert_shebangs 2 scripts/mpop-gnome-tool/mpop-gnome-tool.py
}

src_configure() {
	econf \
		$(use_with gnome-keyring ) \
		$(use_with idn libidn) \
		$(use_enable nls) \
		$(use_with sasl libgsasl) \
		$(use_with ssl ssl $(use gnutls && echo "gnutls" || echo "openssl"))
}

src_install() {
	default

	if use gnome-keyring ; then
		src_install_contrib mpop-gnome-tool mpop-gnome-tool.py README
	fi

	if use vim-syntax ; then
		insinto /usr/share/vim/vimfiles/syntax
		doins scripts/vim/mpop.vim
	fi
}

src_install_contrib() {
	subdir="$1"
	bins="$2"
	docs="$3"
	local dir=/usr/share/${PN}/$subdir
	insinto ${dir}
	exeinto ${dir}
	for i in $bins ; do
		doexe scripts/$subdir/$i
	done
	for i in $docs ; do
		newdoc scripts/$subdir/$i $subdir.$i
	done
}