[gentoo-commits] gentoo-x86 commit in sys-apps/policycoreutils: ChangeLog policycoreutils-2.0.69.ebuild

[Chris PeBenito (pebenito)]

pebenito    09/08/02 01:25:55

  Modified:             ChangeLog
  Added:                policycoreutils-2.0.69.ebuild
  Log:
  new upstream release.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.73                 sys-apps/policycoreutils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/policycoreutils/ChangeLog?rev=1.73&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/policycoreutils/ChangeLog?rev=1.73&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/policycoreutils/ChangeLog?r1=1.72&r2=1.73

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/ChangeLog,v
retrieving revision 1.72
retrieving revision 1.73
diff -u -r1.72 -r1.73
--- ChangeLog	22 Jul 2009 13:20:53 -0000	1.72
+++ ChangeLog	2 Aug 2009 01:25:55 -0000	1.73
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/policycoreutils
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/ChangeLog,v 1.72 2009/07/22 13:20:53 pebenito Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/ChangeLog,v 1.73 2009/08/02 01:25:55 pebenito Exp $
+
+*policycoreutils-2.0.69 (02 Aug 2009)
+
+  02 Aug 2009; Chris PeBenito <pebenito@g.o>
+  +policycoreutils-2.0.69.ebuild:
+  New upstream release.
 
   18 Jul 2009; Chris PeBenito <pebenito@g.o>
   -policycoreutils-1.34.15.ebuild, policycoreutils-2.0.55.ebuild:



1.1                  sys-apps/policycoreutils/policycoreutils-2.0.69.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/policycoreutils/policycoreutils-2.0.69.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/policycoreutils/policycoreutils-2.0.69.ebuild?rev=1.1&content-type=text/plain

Index: policycoreutils-2.0.69.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/policycoreutils/policycoreutils-2.0.69.ebuild,v 1.1 2009/08/02 01:25:55 pebenito Exp $

IUSE="nls"

inherit eutils python

EXTRAS_VER="1.19"
SEMNG_VER="2.0"
SELNX_VER="2.0"

#BUGFIX_PATCH="${FILESDIR}/policycoreutils-2.0.62-po.diff"

DESCRIPTION="SELinux core utilities"
HOMEPAGE="http://userspace.selinuxproject.org"
SRC_URI="http://userspace.selinuxproject.org/releases/current/devel/${P}.tar.gz
	mirror://gentoo/policycoreutils-extra-${EXTRAS_VER}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

COMMON_DEPS=">=sys-libs/libselinux-${SELNX_VER}
        >=sys-libs/glibc-2.4
        >=sys-process/audit-1.5.1 
        >=sys-libs/libcap-1.10-r10
        sys-libs/pam
        =sys-libs/libsemanage-${SEMNG_VER}*"

RDEPEND="${COMMON_DEPS}
	dev-python/sepolgen"

DEPEND="${COMMON_DEPS}
	nls? ( sys-devel/gettext )"

S2=${WORKDIR}/policycoreutils-extra

src_unpack() {
	unpack ${A}
	cd "${S}"

	[ ! -z "${BUGFIX_PATCH}" ] && epatch "${BUGFIX_PATCH}"

	# rlpkg is more useful than fixfiles
	sed -i -e '/^all/s/fixfiles//' "${S}/scripts/Makefile" \
		|| die "fixfiles sed 1 failed"
	sed -i -e '/fixfiles/d' "${S}/scripts/Makefile" \
		|| die "fixfiles sed 2 failed"

	local SUBDIRS="`cd ${S} && find -type d | cut -d/ -f2`"

	if ! useq nls; then
		for i in ${SUBDIRS}; do
			# disable locale stuff
			sed -i -e s/-DUSE_NLS// "${S}/${i}/Makefile" \
				|| die "${i} NLS sed failed"
		done
	fi

	# Gentoo Fixes
	for i in ${SUBDIRS}; do
		# add in CFLAGS
		sed -i -e "s:-Wall:-Wall ${CFLAGS}:g" "${S}/${i}/Makefile" \
			|| die "${i} Makefile CFLAGS fix failed."
	done
}

src_compile() {
	python_version

	einfo "Compiling policycoreutils"
	emake -C "${S}" PYLIBVER="python${PYVER}" AUDIT_LOG_PRIV=y || die
	einfo "Compiling policycoreutils-extra"
	emake -C "${S2}" || die
}

src_install() {
	python_version

	einfo "Installing policycoreutils"
	make DESTDIR="${D}" -C "${S}" PYLIBVER="python${PYVER}" AUDIT_LOG_PRIV=y install || die
	einfo "Installing policycoreutils-extra"
	make DESTDIR="${D}" -C "${S2}" install || die

	# remove redhat-style init script
	rm -fR "${D}/etc/rc.d"

	# compatibility symlinks
	dosym /sbin/setfiles /usr/sbin/setfiles
	dosym /lib/rc/runscript_selinux.so /lib/rcscripts/runscript_selinux.so

	if has_version '<sys-libs/pam-0.99'; then
		# install compat pam.d entries
		# for older pam
		make DESTDIR="${D}" -C "${S2}/pam.d" install || die
	fi
}

pkg_postinst() {
	python_version
	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages
}

pkg_postrm() {
	python_version
	python_mod_cleanup /usr/$(get_libdir)/python${PYVER}/site-packages
}