[gentoo-commits] gentoo-x86 commit in kde-base/kalzium: ChangeLog kalzium-4.0.2.ebuild

[Wulf Krueger (philantrop)]

philantrop    08/03/10 23:21:11

  Modified:             ChangeLog
  Added:                kalzium-4.0.2.ebuild
  Log:
  Version bump to KDE 4.0.2.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.88                 kde-base/kalzium/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/ChangeLog?rev=1.88&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/ChangeLog?rev=1.88&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/ChangeLog?r1=1.87&r2=1.88

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kalzium/ChangeLog,v
retrieving revision 1.87
retrieving revision 1.88
diff -u -r1.87 -r1.88
--- ChangeLog	4 Mar 2008 03:34:03 -0000	1.87
+++ ChangeLog	10 Mar 2008 23:21:11 -0000	1.88
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kalzium
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kalzium/ChangeLog,v 1.87 2008/03/04 03:34:03 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kalzium/ChangeLog,v 1.88 2008/03/10 23:21:11 philantrop Exp $
+
+*kalzium-4.0.2 (10 Mar 2008)
+
+  10 Mar 2008; Wulf C. Krueger <philantrop@g.o>
+  +kalzium-4.0.2.ebuild:
+  Version bump to KDE 4.0.2
 
   04 Mar 2008; Jeroen Roovers <jer@g.o> kalzium-3.5.8.ebuild,
   kalzium-3.5.9.ebuild, kalzium-4.0.1.ebuild:



1.1                  kde-base/kalzium/kalzium-4.0.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/kalzium-4.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kalzium/kalzium-4.0.2.ebuild?rev=1.1&content-type=text/plain

Index: kalzium-4.0.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kalzium/kalzium-4.0.2.ebuild,v 1.1 2008/03/10 23:21:11 philantrop Exp $

EAPI="1"

KMNAME=kdeedu
CPPUNIT_REQUIRED="optional"
inherit kde4-meta

DESCRIPTION="KDE: periodic table of the elements."
KEYWORDS="~amd64 ~x86"
IUSE="${IUSE} cviewer debug htmlhandbook solver"

COMMONDEPEND=">=kde-base/libkdeedu-${PV}:${SLOT}
	cviewer? ( >=dev-cpp/eigen-1.0.5
		>=sci-chemistry/openbabel-2.1
		|| ( x11-libs/qt-opengl:4
			>=x11-libs/qt-4.3.3:4 )
		virtual/opengl )"
DEPEND="${DEPEND} ${COMMONDEPEND}
	solver? ( dev-ml/facile )"
RDEPEND="${RDEPEND} ${COMMONDEPEND}"

KMEXTRACTONLY="libkdeedu/kdeeduui libkdeedu/libscience"

pkg_setup() {
	if use cviewer && has_version '<x11-libs/qt-4.4.0_alpha:4'; then
		QT4_BUILT_WITH_USE_CHECK="${QT4_BUILT_WITH_USE_CHECK} opengl"
	fi

	if use solver && ! built_with_use --missing true dev-lang/ocaml ocamlopt; then
		eerror "In order to build the solver for ${PN}, you first need"
		eerror "to have dev-lang/ocaml built with the ocamlopt useflag"
		eerror "in order to get a native code ocaml compiler"
		die "Please install dev-lang/ocaml with ocamlopt support"
	fi
	if use solver && ! built_with_use --missing true dev-ml/facile ocamlopt; then
		eerror "In order to build the solver for ${PN}, you first need"
		eerror "to have dev-ml/facile built with the ocamlopt useflag"
		eerror "in order to get the native code library"
		die "Please install dev-ml/facile with ocamlopt support"
	fi

	kde4-meta_pkg_setup
}

src_compile() {
	if use solver ; then
		# Compile the solver on its own as the cmake-based build is
		# currently broken. Fixes bug 206620.
		cd "${S}/${PN}/src/solver"
		emake || die "compiling the ocaml resolver failed"
		mkdir -p "${WORKDIR}/${PN}_build/${PN}/src/"
		cp * "${WORKDIR}/${PN}_build/${PN}/src/"
	fi

	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_with cviewer Eigen)
		$(cmake-utils_use_with cviewer OpenBabel2)
		$(cmake-utils_use_with cviewer OpenGL)
		$(cmake-utils_use_with solver OCaml)
		$(cmake-utils_use_with solver Libfacile)"

	kde4-meta_src_compile
}



-- 
gentoo-commits@l.g.o mailing list