Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Alexey Shvetsov (alexxy)" <alexxy@g.o>
Subject: gentoo-x86 commit in kde-base/kdelibs: ChangeLog kdelibs-4.1.4.ebuild
Date: Tue, 13 Jan 2009 21:41:05 +0000
alexxy      09/01/13 21:41:05

  Modified:             ChangeLog
  Added:                kdelibs-4.1.4.ebuild
  Log:
  Bump kde to 4.1.4
  (Portage version: 2.2_rc21/cvs/Linux 2.6.28-gentoo x86_64)

Revision  Changes    Path
1.551                kde-base/kdelibs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/ChangeLog?rev=1.551&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/ChangeLog?rev=1.551&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/ChangeLog?r1=1.550&r2=1.551

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v
retrieving revision 1.550
retrieving revision 1.551
diff -u -r1.550 -r1.551
--- ChangeLog	11 Dec 2008 13:32:29 -0000	1.550
+++ ChangeLog	13 Jan 2009 21:41:04 -0000	1.551
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdelibs
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.550 2008/12/11 13:32:29 scarabeus Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.551 2009/01/13 21:41:04 alexxy Exp $
+
+*kdelibs-4.1.4 (13 Jan 2009)
+
+  13 Jan 2009; Alexey Shvetsov <alexxy@g.o> +kdelibs-4.1.4.ebuild:
+  Bump to 4.1.4
 
   11 Dec 2008; Tomas Chvatal <scarabeus@g.o>
   +files/kdelibs-4.1.3-gcc4.1.patch, kdelibs-4.1.3-r1.ebuild:



1.1                  kde-base/kdelibs/kdelibs-4.1.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/kdelibs-4.1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/kdelibs-4.1.4.ebuild?rev=1.1&content-type=text/plain

Index: kdelibs-4.1.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-4.1.4.ebuild,v 1.1 2009/01/13 21:41:04 alexxy Exp $

EAPI="2"

CPPUNIT_REQUIRED="optional"
OPENGL_REQUIRED="optional"
inherit kde4-base fdo-mime

DESCRIPTION="KDE libraries needed by all KDE programs."
HOMEPAGE="http://www.kde.org/"

KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="3dnow acl alsa altivec bindist +bzip2 debug doc fam htmlhandbook jpeg2k
kerberos mmx nls openexr +semantic-desktop spell sse sse2 ssl zeroconf"
LICENSE="LGPL-2.1"
RESTRICT="test"

COMMONDEPEND="
	!<kde-base/kdebase-3.5.7-r6
	!<kde-base/kdebase-startkde-3.5.7-r1
	!=kde-base/kdebase-3.5.8
	!=kde-base/kdebase-3.5.8-r1
	!=kde-base/kdebase-3.5.8-r2
	!=kde-base/kdebase-startkde-3.5.8
	!kdeprefix? ( !<=kde-misc/kdnssd-avahi-0.1.2:0 )
	>=app-misc/strigi-0.5.9
	>=dev-libs/libxml2-2.6.6
	>=dev-libs/libxslt-1.1.17
	media-libs/fontconfig
	>=media-libs/freetype-2
	media-libs/giflib
	media-libs/jpeg
	media-libs/libpng
	>=media-sound/phonon-4.2.0
	>=sys-apps/dbus-0.91[X]
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXcursor
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXft
	x11-libs/libXpm
	x11-libs/libXrender
	x11-libs/libXtst
	>=x11-misc/shared-mime-info-0.20
	acl? ( kernel_linux? ( sys-apps/acl ) )
	alsa? ( >=media-libs/alsa-lib-1.0.14a[midi] )
	fam? ( virtual/fam )
	jpeg2k? ( media-libs/jasper )
	kerberos? ( virtual/krb5 )
	nls? ( virtual/libintl )
	openexr? ( >=media-libs/openexr-1.2.2-r2 media-libs/ilmbase )
	opengl? ( virtual/opengl )
	>=dev-libs/libpcre-4.5
	semantic-desktop? ( >=dev-libs/soprano-2.1 )
	spell? ( app-text/aspell app-dicts/aspell-en app-text/enchant )
	ssl? ( >=dev-libs/openssl-0.9.7d )
	zeroconf? ( || ( net-dns/avahi[mdnsresponder-compat]
		!bindist? ( net-misc/mDNSResponder ) ) )
"

DEPEND="${COMMONDEPEND}
	doc? ( app-doc/doxygen )
	sys-devel/gettext
"

RDEPEND="${COMMONDEPEND}
	x11-apps/rgb
	x11-apps/iceauth
"

PATCHES=( "${FILESDIR}/${PN}-4.1.1-cmake-modules.patch" "${FILESDIR}/4.1.3-cmake-config.patch" )

src_configure() {
	if use zeroconf; then
		if has_version net-dns/avahi; then
			mycmakeargs="${mycmakeargs} -DWITH_Avahi=ON -DWITH_DNSSD=OFF"
		elif has_version net-misc/mDNSResponder; then
			mycmakeargs="${mycmakeargs} -DWITH_Avahi=OFF -DWITH_DNSSD=ON"
		else
			die "USE=\"zeroconf\" enabled but neither net-dns/avahi nor net-misc/mDNSResponder were found."
		fi
	fi
	if use kdeprefix; then
		HME=".kde${SLOT}"
	else
		HME=".kde4"
	fi
	mycmakeargs="${mycmakeargs}
		-DWITH_HSPELL=OFF
		-DKDE_DEFAULT_HOME=${HME}
		$(cmake-utils_has 3dnow X86_3DNOW)
		$(cmake-utils_has altivec PPC_ALTIVEC)
		$(cmake-utils_has mmx X86_MMX)
		$(cmake-utils_has sse X86_SSE)
		$(cmake-utils_has sse2 X86_SSE2)
		$(cmake-utils_use_with acl ACL)
		$(cmake-utils_use_with alsa Alsa)
		$(cmake-utils_use_with bzip2 BZip2)
		$(cmake-utils_use_with fam FAM)
		$(cmake-utils_use_with jpeg2k Jasper)
		$(cmake-utils_use_with kerberos GSSAPI)
		$(cmake-utils_use_with nls Libintl)
		$(cmake-utils_use_with openexr OpenEXR)
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with semantic-desktop Soprano)
		$(cmake-utils_use_with spell ASPELL)
		$(cmake-utils_use_with spell ENCHANT)
		$(cmake-utils_use_with ssl OpenSSL)
	"
	kde4-base_src_configure
}

src_compile() {
	kde4-base_src_compile

	# The building of apidox is not managed anymore by the build system
	if use doc; then
		einfo "Building API documentation"
		cd "${S}"/doc/api/
		./doxygen.sh "${S}" || die "APIDOX generation failed"
	fi
}

src_install() {
	kde4-base_src_install

	if use doc; then
		einfo "Installing API documentation. This could take a bit of time."
		cd "${S}"/doc/api/
		docinto /HTML/en/kdelibs-apidox
		dohtml -r ${P}-apidocs/* || die "Install phase of KDE4 API Documentation failed"
	fi

	dodir /etc/env.d
	dodir /etc/revdep-rebuild

	# List all the multilib libdirs
	local _libdir _libdirs
	for _libdir in $(get_all_libdirs); do
		_libdirs="${_libdirs}:${PREFIX}/${_libdir}"
	done
	_libdirs=${_libdirs#:}

	if use kdeprefix; then
		cat <<-EOF > "${T}"/43kdepaths-${SLOT} # number goes down with version
PATH="${PREFIX}/bin"
ROOTPATH="${PREFIX}/sbin:${PREFIX}/bin"
LDPATH="${_libdirs}"
MANPATH="${PREFIX}/share/man"
CONFIG_PROTECT="${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown /usr/share/config"
#KDE_IS_PRELINKED=1
XDG_DATA_DIRS="/usr/share:${PREFIX}/share:/usr/local/share"
COLON_SEPARATED="XDG_DATA_DIRS"
EOF
		doenvd "${T}"/43kdepaths-${SLOT}

		# make sure 'source /etc/profile' doesn't hose the PATH
		dodir /etc/profile.d
		cat <<-'EOF' > "${D}"/etc/profile.d/44kdereorderpaths-${SLOT}.sh
if [ -n "${KDEDIR}" ]; then
	export PATH=${KDEDIR}/bin:$(echo ${PATH} | sed "s#${KDEDIR}/s\?bin:##g")
	export ROOTPATH=${KDEDIR}/sbin:${KDEDIR}/bin:$(echo ${PATH} | sed "s#${KDEDIR}/s\?bin:##g")
fi
EOF

		cat <<-EOF > "${D}/etc/revdep-rebuild/50-kde-${SLOT}"
SEARCH_DIRS="${PREFIX}/bin ${PREFIX}/lib*"
EOF
	else # Much simpler for the FHS compliant -kdeprefix install
		cat <<-EOF > "${T}"/43kdepaths # number goes down with version
CONFIG_PROTECT="/usr/share/config"
#KDE_IS_PRELINKED=1
XDG_DATA_DIRS="/usr/share:/usr/local/share"
COLON_SEPARATED="XDG_DATA_DIRS"
		EOF
		doenvd "${T}"/43kdepaths
	fi
	# Ensure that the correct permissions are set on ${PREFIX}/share/config
	chmod 755 "${D}"/"${PREFIX}"/share/config
}

pkg_postinst() {
	fdo-mime_mime_database_update

	if use zeroconf; then
		echo
		elog "To make zeroconf support available in KDE make sure that the 'mdnsd' daemon"
		elog "is running. Make sure also that multicast dns lookups are enabled by editing"
		elog "the 'hosts:' line in /etc/nsswitch.conf to include 'mdns', e.g.:"
		elog "	hosts: files mdns dns"
		echo
	fi

	kde4-base_pkg_postinst
}

pkg_postrm() {
	fdo-mime_mime_database_update

	kde4-base_pkg_postrm
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.1.4.ebuild
Next by thread:
gentoo-x86 commit in kde-base/kdelibs: ChangeLog kdelibs-4.1.4.ebuild
Previous by date:
gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.1.4.ebuild
Next by date:
gentoo-x86 commit in kde-base/kdemaildir: kdemaildir-4.1.4.ebuild ChangeLog


Updated Mar 19, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.