[gentoo-commits] gentoo-x86 commit in app-arch/file-roller: metadata.xml ChangeLog file-roller-2.22.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/03/22 22:40:18

  Modified:             metadata.xml ChangeLog
  Added:                file-roller-2.22.0.ebuild
  Log:
  New version for GNOME-2.22, renamed gnome USE flag to nautilus and added description in metadata.xml
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.2                  app-arch/file-roller/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/file-roller/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	4 Jul 2003 00:16:52 -0000	1.1
+++ metadata.xml	22 Mar 2008 22:40:18 -0000	1.2
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+	<flag name="nautilus">Enable file-roller to integrate with
+	<pkg>gnome-base/nautilus</pkg> by providing entries in its context menu.</flag>
+</use>
 </pkgmetadata>



1.231                app-arch/file-roller/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/ChangeLog?rev=1.231&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/ChangeLog?rev=1.231&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/ChangeLog?r1=1.230&r2=1.231

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v
retrieving revision 1.230
retrieving revision 1.231
diff -u -r1.230 -r1.231
--- ChangeLog	4 Feb 2008 03:54:45 -0000	1.230
+++ ChangeLog	22 Mar 2008 22:40:18 -0000	1.231
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/file-roller
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.230 2008/02/04 03:54:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.231 2008/03/22 22:40:18 eva Exp $
+
+*file-roller-2.22.0 (22 Mar 2008)
+
+  22 Mar 2008; Gilles Dartiguelongue <eva@g.o> metadata.xml,
+  +file-roller-2.22.0.ebuild:
+  New version for GNOME-2.22, renamed gnome USE flag to nautilus and added
+  description in metadata.xml
 
   04 Feb 2008; Jeroen Roovers <jer@g.o> file-roller-2.20.3.ebuild:
   Stable for HPPA (bug #208366).



1.1                  app-arch/file-roller/file-roller-2.22.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/file-roller-2.22.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/file-roller-2.22.0.ebuild?rev=1.1&content-type=text/plain

Index: file-roller-2.22.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/file-roller-2.22.0.ebuild,v 1.1 2008/03/22 22:40:18 eva Exp $

inherit eutils gnome2

DESCRIPTION="archive manager for GNOME"
HOMEPAGE="http://fileroller.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="nautilus"

RDEPEND=">=dev-libs/glib-2.12
	>=x11-libs/gtk+-2.10
	>=gnome-base/libgnome-2.6
	>=gnome-base/libgnomeui-2.6
	>=gnome-base/gnome-vfs-2.10
	>=gnome-base/libglade-2.4
	>=gnome-base/gconf-2
	nautilus? ( >=gnome-base/nautilus-2.10 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.19
	>=app-text/gnome-doc-utils-0.3.2"

DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF} --disable-scrollkeeper"

	if ! use nautilus ; then
		G2CONF="${G2CONF} --disable-nautilus-actions"
	fi
}

src_unpack() {
	gnome2_src_unpack

	# Use absolute path to GNU tar since star doesn't have the same
	# options.  On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
	epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch

	# use a local rpm2cpio script to avoid the dep
	epatch "${FILESDIR}"/${PN}-2.10-use_fr_rpm2cpio.patch
}

src_install() {
	gnome2_src_install
	dobin "${FILESDIR}"/rpm2cpio-file-roller
}

pkg_postinst() {
	elog "${PN} is a frontend for several archiving utility. If you want a"
	elog "particular achive format support, see ${HOMEPAGE}"
	elog "and install the relevant package."
	elog
	elog "for example:"
	elog "  7-zip   - app-arch/p7zip"
	elog "  ace     - app-arch/unace"
	elog "  arj     - app-arch/arj"
	elog "  lzma    - app-arch/lzma"
	elog "  lzop    - app-arch/lzop"
	elog "  cpio    - app-arch/cpio"
	elog "  iso     - app-arch/cdrtools"
	elog "  jar,zip - app-arch/zip and app-arch/unzip"
	elog "  lha     - app-arch/lha"
	elog "  rar     - app-arch/unrar"
	elog "  rpm     - app-arch/rpm"
	elog "  unstuff - app-arch/stuffit"
	elog "  zoo     - app-arch/zoo"
}



-- 
gentoo-commits@l.g.o mailing list