[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-vfs: ChangeLog gnome-vfs-2.22.0.ebuild

[Mart Raudsepp (leio)]

leio        08/03/23 01:54:52

  Modified:             ChangeLog
  Added:                gnome-vfs-2.22.0.ebuild
  Log:
  Version bump for GNOME-2.22. Just bug fixes as this library is deprecated now and applications and libraries using it should be converting to the GIO API in glib-2.16, which can be combined with gnome-base/gvfs for VFS functionality in a seamless manner
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.284                gnome-base/gnome-vfs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/ChangeLog?rev=1.284&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/ChangeLog?rev=1.284&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/ChangeLog?r1=1.283&r2=1.284

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v
retrieving revision 1.283
retrieving revision 1.284
diff -u -r1.283 -r1.284
--- ChangeLog	11 Mar 2008 21:58:27 -0000	1.283
+++ ChangeLog	23 Mar 2008 01:54:51 -0000	1.284
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-base/gnome-vfs
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v 1.283 2008/03/11 21:58:27 leio Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v 1.284 2008/03/23 01:54:51 leio Exp $
+
+*gnome-vfs-2.22.0 (23 Mar 2008)
+
+  23 Mar 2008; Mart Raudsepp <leio@g.o> +gnome-vfs-2.22.0.ebuild:
+  Version bump for GNOME-2.22. Just bug fixes as this library is deprecated
+  now and applications and libraries using it should be converting to the GIO
+  API in glib-2.16, which can be combined with gnome-base/gvfs for VFS
+  functionality in a seamless manner
 
   11 Mar 2008; Mart Raudsepp <leio@g.o> gnome-vfs-2.18.1.ebuild,
   gnome-vfs-2.20.1-r1.ebuild:



1.1                  gnome-base/gnome-vfs/gnome-vfs-2.22.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.22.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.22.0.ebuild?rev=1.1&content-type=text/plain

Index: gnome-vfs-2.22.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.22.0.ebuild,v 1.1 2008/03/23 01:54:51 leio Exp $

WANT_AUTOMAKE=1.8
inherit eutils gnome2 autotools

DESCRIPTION="Gnome Virtual Filesystem"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="acl avahi doc gnutls hal ipv6 kerberos samba ssl"

RDEPEND=">=gnome-base/gconf-2
	>=dev-libs/glib-2.9.3
	>=dev-libs/libxml2-2.6
	>=net-misc/neon-0.25.3
	app-arch/bzip2
	virtual/fam
	gnome-base/gnome-mime-data
	>=x11-misc/shared-mime-info-0.14
	>=dev-libs/dbus-glib-0.71
	samba? ( >=net-fs/samba-3 )
	gnutls?	(
				net-libs/gnutls
				!gnome-extra/gnome-vfs-sftp
			)
	ssl?	(
		!gnutls?	(
				>=dev-libs/openssl-0.9.5
				!gnome-extra/gnome-vfs-sftp
				)
		)
	hal? ( >=sys-apps/hal-0.5.7 )
	avahi? ( >=net-dns/avahi-0.6 )
	kerberos? ( virtual/krb5 )
	acl? (
		sys-apps/acl
		sys-apps/attr
	)"
DEPEND="${RDEPEND}
	sys-devel/gettext
	gnome-base/gnome-common
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.9
	doc? ( >=dev-util/gtk-doc-1 )"
PDEPEND="hal? ( >=gnome-base/gnome-mount-0.4 )"

DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-schemas-install
		--disable-cdda
		--disable-howl
		--enable-http-neon
		$(use_enable ssl openssl)
		$(use_enable gnutls)
		$(use_enable samba)
		$(use_enable ipv6)
		$(use_enable hal)
		$(use_enable avahi)
		$(use_enable kerberos krb5)
		$(use_enable acl)"

	if use hal ; then
		G2CONF="${G2CONF}
			--with-hal-mount=/usr/bin/gnome-mount
			--with-hal-umount=/usr/bin/gnome-umount
			--with-hal-eject=/usr/bin/gnome-eject"
	fi

	# this works because of the order of conifgure parsing
	# so should always be behind the use_enable options
	# foser <foser@g.o 19 Apr 2004
	use gnutls && use ssl && G2CONF="${G2CONF} --disable-openssl"
}

src_unpack() {
	gnome2_src_unpack

	# Allow the Trash on afs filesystems (#106118)
	epatch "${FILESDIR}"/${PN}-2.12.0-afs.patch

	# Fix compiling with headers missing
	epatch "${FILESDIR}"/${PN}-2.15.2-headers-define.patch

	# Fix for crashes running programs via sudo
	epatch "${FILESDIR}"/${PN}-2.16.0-no-dbus-crash.patch

	# Fix automagic dependencies
	epatch "${FILESDIR}"/${PN}-2.20.0-automagic-deps.patch
	epatch "${FILESDIR}"/${PN}-2.20.1-automagic-deps.patch

	# Fix to identify ${HOME} (#200897)
	# thanks to debian folks
	epatch "${FILESDIR}"/${PN}-2.20.0-home_dir_fakeroot.patch

	use doc || epatch "${FILESDIR}/${PN}-2.18.1-drop-gtk-doc-check.patch"

	# Fix deprecated API disabling in used libraries - this is not future-proof, bug 212163
	sed -i -e '/DISABLE_DEPRECATED/d' \
		"${S}/daemon/Makefile.am" "${S}/daemon/Makefile.in" \
		"${S}/libgnomevfs/Makefile.am" "${S}/libgnomevfs/Makefile.in" \
		"${S}/modules/Makefile.am" "${S}/modules/Makefile.in" \
		"${S}/test/Makefile.am" "${S}/test/Makefile.in"
	sed -i -e 's:-DG_DISABLE_DEPRECATED:$(NULL):g' \
		"${S}/programs/Makefile.am" "${S}/programs/Makefile.in"

	eautoreconf
	intltoolize --force
}



-- 
gentoo-commits@l.g.o mailing list