[gentoo-commits] gentoo-x86 commit in media-sound/alsaplayer: ChangeLog alsaplayer-0.99.81.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/11/09 13:29:37

  Modified:             ChangeLog
  Added:                alsaplayer-0.99.81.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

Revision  Changes    Path
1.74                 media-sound/alsaplayer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsaplayer/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsaplayer/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsaplayer/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	23 May 2010 18:17:43 -0000	1.73
+++ ChangeLog	9 Nov 2010 13:29:37 -0000	1.74
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/alsaplayer
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/ChangeLog,v 1.73 2010/05/23 18:17:43 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/ChangeLog,v 1.74 2010/11/09 13:29:37 ssuominen Exp $
+
+*alsaplayer-0.99.81 (09 Nov 2010)
+
+  09 Nov 2010; Samuli Suominen <ssuominen@g.o>
+  +alsaplayer-0.99.81.ebuild:
+  Version bump.
 
   23 May 2010; Pacho Ramos <pacho@g.o> alsaplayer-0.99.80-r1.ebuild:
   stable amd64, bug 307483



1.1                  media-sound/alsaplayer/alsaplayer-0.99.81.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsaplayer/alsaplayer-0.99.81.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsaplayer/alsaplayer-0.99.81.ebuild?rev=1.1&content-type=text/plain

Index: alsaplayer-0.99.81.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsaplayer/alsaplayer-0.99.81.ebuild,v 1.1 2010/11/09 13:29:37 ssuominen Exp $

EAPI=2
inherit autotools eutils

DESCRIPTION="A heavily multi-threaded pluggable audio player."
HOMEPAGE="http://www.alsaplayer.org"
SRC_URI="http://www.${PN}.org/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~mips ~ppc ~sparc ~x86"
IUSE="alsa audiofile doc esd flac gtk id3tag jack mad mikmod nas nls ogg opengl oss vorbis xosd"

RDEPEND="media-libs/libsndfile
	sys-libs/zlib
	alsa? ( media-libs/alsa-lib )
	audiofile? ( media-libs/audiofile )
	esd? ( media-sound/esound )
	flac? ( media-libs/flac )
	gtk? ( >=x11-libs/gtk+-2.10 )
	id3tag? ( media-libs/libid3tag )
	jack? ( >=media-sound/jack-audio-connection-kit-0.80 )
	mad? ( media-libs/libmad )
	mikmod? ( media-libs/libmikmod )
	nas? ( media-libs/nas )
	ogg? ( media-libs/libogg )
	opengl? ( virtual/opengl )
	vorbis? ( media-libs/libvorbis )
	xosd? ( x11-libs/xosd )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )
	nls? ( sys-devel/gettext )"

src_prepare() {
	sed -i \
		-e 's:AM_CFLAGS = $(AM_CXXFLAGS)::' \
		output/jack/Makefile.am || die

	sed -i \
		-e 's:-O2 -funroll-loops -finline-functions -ffast-math::' \
		configure.ac || die

	eautoreconf
}

src_configure() {
	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
	use xosd || export ac_cv_lib_xosd_xosd_create=no

	local myconf
	if ! use alsa && ! use oss && ! use esd && ! use jack && ! use nas; then
		myconf="--enable-oss"
	fi

	econf \
		--docdir=/usr/share/doc/${PF} \
		--disable-dependency-tracking \
		$(use_enable nls) \
		$(use_enable opengl) \
		$(use_enable mikmod) \
		$(use_enable vorbis oggvorbis) \
		$(use_enable audiofile) \
		$(use_enable flac) \
		$(use_enable mad) \
		$(use_enable id3tag) \
		$(use_enable gtk systray) \
		$(use_enable jack) \
		$(use_enable alsa) \
		$(use_enable esd) \
		$(use_enable oss) \
		$(use_enable gtk gtk2) \
		$(use_enable nas) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog README TODO docs/*.txt
	newicon interface/gtk2/pixmaps/logo.xpm ${PN}.xpm

	find "${D}" -name '*.la' -exec rm -f '{}' +
}