[gentoo-commits] gentoo-x86 commit in net-im/centerim: ChangeLog centerim-4.22.3.ebuild

[Sven Wegener (swegener)]

swegener    08/03/12 19:17:49

  Modified:             ChangeLog
  Added:                centerim-4.22.3.ebuild
  Log:
  Version bump, bug #213105.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.13                 net-im/centerim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	17 Feb 2008 13:09:37 -0000	1.12
+++ ChangeLog	12 Mar 2008 19:17:49 -0000	1.13
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/centerim
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v 1.12 2008/02/17 13:09:37 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v 1.13 2008/03/12 19:17:49 swegener Exp $
+
+*centerim-4.22.3 (12 Mar 2008)
+
+  12 Mar 2008; Sven Wegener <swegener@g.o> +centerim-4.22.3.ebuild:
+  Version bump, bug #213105.
 
   17 Feb 2008; Christian Faulhammer <opfer@g.o>
   centerim-4.22.2.ebuild:



1.1                  net-im/centerim/centerim-4.22.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/centerim/centerim-4.22.3.ebuild?rev=1.1&content-type=text/plain

Index: centerim-4.22.3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.3.ebuild,v 1.1 2008/03/12 19:17:49 swegener Exp $

inherit eutils

PROTOCOL_IUSE="aim gadu icq irc jabber lj msn rss yahoo"
IUSE="${PROTOCOL_IUSE} bidi nls ssl crypt jpeg otr"

DESCRIPTION="CenterIM is a fork of CenterICQ - a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
if [[ ${PV} = *_p* ]] # is this a snaphot?
then
	SRC_URI="http://www.centerim.org/download/snapshots/${PN}-${PV/*_p/}.tar.gz"
else
	SRC_URI="http://www.centerim.org/download/releases/${P}.tar.gz"
fi
HOMEPAGE="http://www.centerim.org/"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"

DEPEND=">=sys-libs/ncurses-5.2
	bidi? ( dev-libs/fribidi )
	ssl? ( >=dev-libs/openssl-0.9.6g )
	jpeg? ( media-libs/jpeg )
	jabber? (
		otr? ( net-libs/libotr )
		crypt? ( >=app-crypt/gpgme-1.0.2 )
	)
	msn? (
		net-misc/curl
		dev-libs/openssl
	)"

RDEPEND="${DEPEND}
	nls? ( sys-devel/gettext )"

S="${WORKDIR}"/${P/_p*}

check_protocol_iuse() {
	local flag

	for flag in ${PROTOCOL_IUSE}
	do
		use ${flag} && return 0
	done

	return 1
}

pkg_setup() {
	if ! check_protocol_iuse
	then
		eerror
		eerror "Please activate at least one of the following protocol USE flags:"
		eerror "${PROTOCOL_IUSE}"
		eerror
		die "Please activate at least one protocol USE flag!"
	fi

	if use msn && ! built_with_use net-misc/curl ssl
	then
		eerror
		eerror "As of right now, the msn use flags requires curl to be built"
		eerror "with SSL support. Make sure ssl is in your USE flags and"
		eerror "re-emerge net-misc/curl."
		eerror
		die "net-misc/curl dependencie issue"
	fi

	if use otr && ! use jabber
	then
		eerror
		eerror "Support for OTR is only supported with Jabber!"
		eerror
		die "Support for OTR is only supported with Jabber!"
	fi

	if use gadu && ! use jpeg
	then
		ewarn
		ewarn "You need jpeg support to be able to register Gadu-Gadu accounts!"
		ewarn
	fi
}

src_compile() {
	econf \
		$(use_with ssl) \
		$(use_enable aim) \
		$(use_with bidi fribidi) \
		$(use_with jpeg libjpeg) \
		$(use_with otr libotr) \
		$(use_enable gadu gg) \
		$(use_enable icq) \
		$(use_enable irc) \
		$(use_enable jabber) \
		$(use_enable lj) \
		$(use_enable msn) \
		$(use_enable nls locales-fix) \
		$(use_enable nls) \
		$(use_enable rss) \
		$(use_enable yahoo) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog FAQ README THANKS TODO
}



-- 
gentoo-commits@l.g.o mailing list