Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Maciej Mrozowski (reavertm)" <reavertm@g.o>
Subject: gentoo-x86 commit in app-admin/system-config-printer-common: system-config-printer-common-1.3.9-r2.ebuild ChangeLog system-config-printer-common-1.3.9-r1.ebuild
Date: Tue, 19 Jun 2012 22:20:07 +0000 (UTC)
reavertm    12/06/19 22:20:07

  Modified:             ChangeLog
  Added:                system-config-printer-common-1.3.9-r2.ebuild
  Removed:              system-config-printer-common-1.3.9-r1.ebuild
  Log:
  Revbump, fix changelog
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.72                 app-admin/system-config-printer-common/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	19 Jun 2012 22:10:03 -0000	1.71
+++ ChangeLog	19 Jun 2012 22:20:07 -0000	1.72
@@ -1,10 +1,11 @@
 # ChangeLog for app-admin/system-config-printer-common
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.71 2012/06/19 22:10:03 reavertm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.72 2012/06/19 22:20:07 reavertm Exp $
 
   19 Jun 2012; Maciej Mrozowski <reavertm@g.o>
   +files/system-config-printer-common-1.3.9-cups_filters_path.patch,
-  system-config-printer-common-1.3.9-r1.ebuild:
+  +system-config-printer-common-1.3.9-r2.ebuild:
+  -system-config-printer-common-1.3.9-r1.ebuild:
   Add additional cupsfilters search paths, bug 420671.
 
   24 May 2012; Samuli Suominen <ssuominen@g.o>



1.1                  app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r2.ebuild?rev=1.1&content-type=text/plain

Index: system-config-printer-common-1.3.9-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r2.ebuild,v 1.1 2012/06/19 22:20:07 reavertm Exp $

EAPI="3"

PYTHON_DEPEND="2"
WANT_AUTOMAKE="1.11"
inherit eutils python autotools

MY_P="${PN%-common}-${PV}"

DESCRIPTION="Common modules of Red Hat's printer administration tool"
HOMEPAGE="http://cyberelk.net/tim/software/system-config-printer/"
SRC_URI="http://cyberelk.net/tim/data/system-config-printer/1.3/${MY_P}.tar.xz"

LICENSE="GPL-2"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ppc ppc64 ~sh ~sparc x86"
SLOT="0"
IUSE="doc policykit"

# Needs cups running, bug 284005
RESTRICT="test"

# system-config-printer split since 1.1.3
COMMON_DEPEND="
	dev-libs/glib:2
	dev-libs/libxml2[python]
	dev-python/dbus-python
	>=dev-python/pycups-1.9.60
	dev-python/pycurl
	>=dev-python/pygobject-2.21.5:2
	>=net-print/cups-1.4.6[dbus]
	>=sys-fs/udev-164-r2
	virtual/libusb:0
"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	virtual/pkgconfig
	doc? ( dev-python/epydoc )
"
RDEPEND="${COMMON_DEPEND}
	!<app-admin/system-config-printer-gnome-${PVR}
	policykit? ( sys-auth/polkit )
"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.3.9-split.patch"
	epatch "${FILESDIR}/${PN}-1.3.9-cups_filters_path.patch"
	eautoreconf
}

src_configure() {
	econf \
		--disable-nls \
		--with-udev-rules
}

src_compile() {
	emake || die "emake failed"
	if use doc; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	dodoc AUTHORS ChangeLog README || die "dodoc failed"

	if use doc; then
		dohtml -r html/ || die "installing html docs failed"
	fi

	emake DESTDIR="${ED}" install \
		udevrulesdir=/lib/udev/rules.d \
		udevhelperdir=/lib/udev \
		|| die "emake install failed"

	python_convert_shebangs -q -r $(python_get_version) "${ED}"
}

pkg_postinst() {
	python_mod_optimize cupshelpers
}

pkg_postrm() {
	python_mod_cleanup cupshelpers /usr/share/system-config-printer
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
proj/gentoolkit:gentoolkit commit in: pym/gentoolkit/glsa/
Next by thread:
gentoo-x86 commit in x11-libs/qt-bearer/files: - New directory
Previous by date:
gentoo-x86 commit in dev-libs/geoip: ChangeLog geoip-1.4.8.ebuild
Next by date:
gentoo-x86 commit in profiles: ChangeLog package.mask


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.