[gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog metadata.xml wireshark-0.99.8_rc1.ebuild

[Peter Volkov (pva)]

pva         08/02/20 07:56:38

  Modified:             ChangeLog metadata.xml
  Added:                wireshark-0.99.8_rc1.ebuild
  Log:
  Version bump to pre-release. Took maintainance.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.78                 net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	26 Jan 2008 15:52:12 -0000	1.77
+++ ChangeLog	20 Feb 2008 07:56:38 -0000	1.78
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.77 2008/01/26 15:52:12 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.78 2008/02/20 07:56:38 pva Exp $
+
+*wireshark-0.99.8_rc1 (20 Feb 2008)
+
+  20 Feb 2008; <pva@g.o> metadata.xml, +wireshark-0.99.8_rc1.ebuild:
+  Version bump to pre-release. Took maintainance.
 
 *wireshark-0.99.7-r2 (27 Jan 2008)
 



1.2                  net-analyzer/wireshark/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	30 Jun 2006 13:27:33 -0000	1.1
+++ metadata.xml	20 Feb 2008 07:56:38 -0000	1.2
@@ -2,5 +2,30 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>netmon</herd>
-<longdescription>A commercial-quality network protocol analyzer</longdescription>
+<maintainer>
+	<email>pva@g.o</email>
+	<name>Peter Volkov</name>
+</maintainer>
+<longdescription>
+	Wireshark is the world's foremost network protocol analyzer, and is the de
+	facto (and often de jure) standard across many industries and educational
+	institutions. Wireshark has a rich feature set which includes 1) deep
+	inspection of hundreds of protocols, with more being added all the time, 2)
+	live capture and offline analysis, 3) standard three-pane packet browser, 4)
+	captured network data can be browsed via a GUI, or via the TTY-mode TShark
+	utility, 5) the most powerful display filters in the industry, 6) rich VoIP
+	analysis, 7) read/write many different capture file formats: tcpdump
+	(libpcap), Catapult DCT2000, Cisco Secure IDS iplog, Microsoft Network
+	Monitor, Network General Sniffer® (compressed and uncompressed), Sniffer®
+	Pro, and NetXray®, Network Instruments Observer, Novell LANalyzer, RADCOM
+	WAN/LAN Analyzer, Shomiti/Finisar Surveyor, Tektronix K12xx, Visual Networks
+	Visual UpTime, WildPackets EtherPeek/TokenPeek/AiroPeek, and many others, 8)
+	capture files compressed with gzip can be decompressed on the fly, 9) live
+	data can be read from Ethernet, IEEE 802.11, PPP/HDLC, ATM, Bluetooth, USB,
+	Token Ring, Frame Relay, FDDI, and others, 10) decryption support for many
+	protocols, including IPsec, ISAKMP, Kerberos, SNMPv3, SSL/TLS, WEP, and
+	WPA/WPA2, 11) coloring rules can be applied to the packet list for quick,
+	intuitive analysis, 12) output can be exported to XML, PostScript®, CSV, or
+	plain text 
+</longdescription>
 </pkgmetadata>



1.1                  net-analyzer/wireshark/wireshark-0.99.8_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/wireshark-0.99.8_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/wireshark/wireshark-0.99.8_rc1.ebuild?rev=1.1&content-type=text/plain

Index: wireshark-0.99.8_rc1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-0.99.8_rc1.ebuild,v 1.1 2008/02/20 07:56:38 pva Exp $

WANT_AUTOMAKE="1.9"
inherit autotools libtool flag-o-matic eutils toolchain-funcs

DESCRIPTION="A network protocol analyzer formerly known as ethereal"
HOMEPAGE="http://www.wireshark.org/"

# _rc versions has different download location.
[[ -n ${PV#*_rc} && ${PV#*_rc} != ${PV} ]] && {
SRC_URI="http://www.wireshark.org/download/prerelease/${PN}-${PV/_rc/pre}.tar.gz";
S=${WORKDIR}/${PN}-${PV/_rc/pre} ; } || \
SRC_URI="http://www.wireshark.org/download/src/all-versions/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="adns gtk ipv6 lua portaudio snmp ssl kerberos threads selinux"

RDEPEND="sys-libs/zlib
	snmp? ( net-analyzer/net-snmp )
	gtk? ( >=dev-libs/glib-2.0.4
		=x11-libs/gtk+-2*
		x11-libs/pango
		dev-libs/atk )
	!gtk? ( =dev-libs/glib-1.2* )
	ssl? ( dev-libs/openssl )
	!ssl? (	net-libs/gnutls )
	net-libs/libpcap
	dev-libs/libpcre
	sys-libs/libcap
	adns? ( net-libs/adns )
	kerberos? ( virtual/krb5 )
	portaudio? ( media-libs/portaudio )
	lua? ( >=dev-lang/lua-5.1 )
	selinux? ( sec-policy/selinux-wireshark )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.15.0
	dev-lang/perl
	sys-devel/bison
	sys-devel/flex
	sys-apps/sed"

pkg_setup() {
	# bug 119208
	if has_version "<=dev-lang/perl-5.8.8_rc1" && built_with_use dev-lang/perl minimal ; then
		ewarn "wireshark will not build if dev-lang/perl is compiled with"
		ewarn "USE=minimal. Rebuild dev-lang/perl with USE=-minimal and try again."
		ebeep 5
		die "dev-lang/perl compiled with USE=minimal"
	fi

	if ! use gtk; then
		ewarn "USE=-gtk will mean no gui called wireshark will be created and"
		ewarn "only command line utils are available"
	fi

	# Add group for users allowed to sniff.
	enewgroup wireshark || die "Failed to create wireshark group"
}

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}"/${PN}-0.99.7-asneeded.patch

	cd "${S}"/epan
	epatch "${FILESDIR}"/wireshark-except-double-free.diff

	cd "${S}"
	AT_M4DIR="${S}/aclocal-fallback"
	eautoreconf
}

src_compile() {
	# optimization bug, see bug #165340, bug #40660
	if [[ $(gcc-version) == 3.4 ]] ; then
		elog "Found gcc 3.4, forcing -O3 into CFLAGS"
		replace-flags -O? -O3
	elif [[ $(gcc-version) == 3.3 || $(gcc-version) == 3.2 ]] ; then
		elog "Found <=gcc-3.3, forcing -O into CFLAGS"
		replace-flags -O? -O
	fi

	# see bug #133092
	filter-flags -fstack-protector

	local myconf

	if use gtk; then
		einfo "Building with gtk support"
	else
		einfo "Building without gtk support"
		myconf="${myconf} --disable-wireshark --disable-warnings-as-errors"
		# the asn1 plugin needs gtk
		sed -i -e '/plugins.asn1/d' Makefile.in || die "sed failed"
		sed -i -e '/^SUBDIRS/s/asn1//' plugins/Makefile.in || die "sed failed"
	fi

	econf $(use_with ssl) \
		$(use_enable ipv6) \
		$(use_with lua) \
		$(use_with adns) \
		$(use_with kerberos krb5) \
		$(use_with snmp net-snmp) \
		$(use_with portaudio) \
		$(use_enable gtk gtk2) \
		$(use_enable threads) \
		--with-libcap \
		--enable-setuid-install \
		--without-ucd-snmp \
		--enable-dftest \
		--enable-randpkt \
		--sysconfdir=/etc/wireshark \
		--enable-editcap \
		--enable-capinfos \
		--enable-text2pcap \
		${myconf} || die "econf failed"

	# fixes an access violation caused by libnetsnmp - see bug 79068
	use snmp && export MIBDIRS="${D}/usr/share/snmp/mibs"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	for file in /usr/bin/tshark /usr/bin/dumpcap
	do
		fowners 0:wireshark ${file}
		fperms 6550 ${file}
	done

	insinto /usr/include/wiretap
	doins wiretap/wtap.h

	dodoc AUTHORS ChangeLog NEWS README*

	if use gtk ; then
		insinto /usr/share/icons/hicolor/16x16/apps
		newins image/hi16-app-wireshark.png wireshark.png
		insinto /usr/share/icons/hicolor/32x32/apps
		newins image/hi32-app-wireshark.png wireshark.png
		insinto /usr/share/icons/hicolor/48x48/apps
		newins image/hi48-app-wireshark.png wireshark.png
		insinto /usr/share/applications
		doins wireshark.desktop
	fi
}

pkg_postinst() {
	echo
	ewarn "With version 0.99.7, all function calls that require elevated privileges"
	ewarn "have been moved out of the GUI to dumpcap. WIRESHARK CONTAINS OVER ONE"
	ewarn "POINT FIVE MILLION LINES OF SOURCE CODE. DO NOT RUN THEM AS ROOT."
	ewarn
	ewarn "NOTE: To run wireshark as normal user you have to add yourself into"
	ewarn "wireshark group. This security measure ensures that only trusted"
	ewarn "users allowed to sniff your traffic."
	echo
}



-- 
gentoo-commits@l.g.o mailing list