[gentoo-commits] gentoo-x86 commit in media-video/mediainfo: ChangeLog mediainfo-0.7.47.ebuild mediainfo-0.7.44.ebuild mediainfo-0.7.43.ebuild

[Tim Harder (radhermit)]

radhermit    11/07/15 22:22:37

  Modified:             ChangeLog
  Added:                mediainfo-0.7.47.ebuild
  Removed:              mediainfo-0.7.44.ebuild mediainfo-0.7.43.ebuild
  Log:
  Version bump and remove old.
  
  (Portage version: 2.2.0_alpha45/cvs/Linux x86_64)

Revision  Changes    Path
1.22                 media-video/mediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	6 Jul 2011 23:58:36 -0000	1.21
+++ ChangeLog	15 Jul 2011 22:22:37 -0000	1.22
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/mediainfo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.21 2011/07/06 23:58:36 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.22 2011/07/15 22:22:37 radhermit Exp $
+
+*mediainfo-0.7.47 (15 Jul 2011)
+
+  15 Jul 2011; Tim Harder <radhermit@g.o> -mediainfo-0.7.43.ebuild,
+  -mediainfo-0.7.44.ebuild, +mediainfo-0.7.47.ebuild:
+  Version bump and remove old.
 
 *mediainfo-0.7.46 (06 Jul 2011)
 



1.1                  media-video/mediainfo/mediainfo-0.7.47.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/mediainfo-0.7.47.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/mediainfo-0.7.47.ebuild?rev=1.1&content-type=text/plain

Index: mediainfo-0.7.47.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/mediainfo-0.7.47.ebuild,v 1.1 2011/07/15 22:22:37 radhermit Exp $

EAPI="4"
WX_GTK_VER="2.8"

inherit autotools-utils wxwidgets multilib

DESCRIPTION="MediaInfo supplies technical and tag information about media files"
HOMEPAGE="http://mediainfo.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl debug libmms wxwidgets"

RDEPEND="sys-libs/zlib
	media-libs/libzen
	~media-libs/lib${P}[curl=,libmms=]
	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

AUTOTOOLS_IN_SOURCE_BUILD=1

S="${WORKDIR}/MediaInfo"

pkg_setup() {
	TARGETS="CLI"
	use wxwidgets && TARGETS+=" GUI"
}

src_prepare() {
	local target
	for target in ${TARGETS}; do
		cd "${S}/Project/GNU/${target}"
		sed -i -e "s:-O2::" configure.ac
		eautoreconf
	done
}

src_configure() {
	local target
	for target in ${TARGETS}; do
		ECONF_SOURCE="${S}/Project/GNU/${target}"
		[[ ${target} == "GUI" ]] && local myeconfargs=( --with-wxwidgets --with-wx-gui )
		autotools-utils_src_configure
	done
}

src_compile() {
	local target
	for target in ${TARGETS}; do
		ECONF_SOURCE="${S}/Project/GNU/${target}"
		autotools-utils_src_compile
	done
}
src_install() {
	local target
	for target in ${TARGETS}; do
		ECONF_SOURCE="${S}/Project/GNU/${target}"
		autotools-utils_src_install
		dodoc "${S}"/History_${target}.txt
		if [[ ${target} == "GUI" ]]; then
			newicon "${S}"/Source/Ressource/Image/MediaInfo.png ${PN}.png
			make_desktop_entry ${PN}-gui MediaInfo ${PN} "AudioVideo;GTK"
		fi
	done

	dohtml "${S}"/ReadMe.html
}