[gentoo-commits] gentoo-x86 commit in sys-apps/pkgcore: ChangeLog pkgcore-0.4.7.9.ebuild

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    08/10/06 23:20:58

  Modified:             ChangeLog
  Added:                pkgcore-0.4.7.9.ebuild
  Log:
  Bumped pkgcore to the 0.4.7.9 release as requested by Brian Harring (ferringb).
  (Portage version: 2.2_rc11/cvs/Linux 2.6.26-gentoo-r1 x86_64)

Revision  Changes    Path
1.67                 sys-apps/pkgcore/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	3 Sep 2008 20:55:33 -0000	1.66
+++ ChangeLog	6 Oct 2008 23:20:57 -0000	1.67
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/pkgcore
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v 1.66 2008/09/03 20:55:33 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v 1.67 2008/10/06 23:20:57 jmbsvicetto Exp $
+
+*pkgcore-0.4.7.9 (06 Oct 2008)
+
+  06 Oct 2008; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +pkgcore-0.4.7.9.ebuild:
+  Bumped pkgcore to the 0.4.7.9 release as requested by Brian Harring
+  (ferringb).
 
 *pkgcore-0.4.7.8 (03 Sep 2008)
 



1.1                  sys-apps/pkgcore/pkgcore-0.4.7.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/pkgcore-0.4.7.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/pkgcore-0.4.7.9.ebuild?rev=1.1&content-type=text/plain

Index: pkgcore-0.4.7.9.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/pkgcore-0.4.7.9.ebuild,v 1.1 2008/10/06 23:20:57 jmbsvicetto Exp $

inherit distutils eutils

DESCRIPTION="pkgcore package manager"
HOMEPAGE="http://www.pkgcore.org"
SRC_URI="http://www.pkgcore.org/releases/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc"

RDEPEND=">=dev-lang/python-2.4
	>=dev-python/snakeoil-0.2
	>=app-shells/bash-3.0
	|| ( >=dev-lang/python-2.5 dev-python/pycrypto )"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/docutils-0.4 )"

DOCS="AUTHORS NEWS"

src_compile() {
	distutils_src_compile

	if use doc; then
		./build_docs.py || die "doc building failed"
	fi
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r doc dev-notes
		doman man/*.1
	fi

	dodoc doc/*.rst man/*.rst
	docinto dev-notes
	dodoc dev-notes/*.rst
}

pkg_postinst() {
	distutils_pkg_postinst
	pplugincache

	if [[ -d "${ROOT}etc/pkgcore/plugins" ]]; then
		elog "You still have an /etc/pkgcore/plugins from pkgcore 0.1."
		elog "It is unused by pkgcore >= 0.2, remove it now."
		die "remove /etc/pkgcore/plugins from pkgcore 0.1"
	fi

	# This is left behind by pkgcore 0.2.
	rm -f "${ROOT}"usr/$(get_libdir)/python${PYVER}/site-packages/pkgcore/plugins/plugincache
}

pkg_postrm() {
	python_version
	# Careful not to remove this on up/downgrades.
	local sitep="${ROOT}"usr/$(get_libdir)/python${PYVER}/site-packages
	if [[ -e "${sitep}/pkgcore/plugins/plugincache2" ]] &&
		! [[ -e "${sitep}/pkgcore/plugin.py" ]]; then
		rm "${sitep}/pkgcore/plugins/plugincache2"
	fi
	distutils_pkg_postrm
}

src_test() {
	"${python}" setup.py test || die "testing returned non zero"
}