[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.8.2-r1.ebuild

[Alex Alexander (wired)]

wired       12/03/22 14:34:49

  Modified:             ChangeLog
  Added:                mc-4.8.2-r1.ebuild
  Log:
  fixed bug #409107
  
  (Portage version: 2.2.0_alpha93/cvs/Linux x86_64)

Revision  Changes    Path
1.249                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.249&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.249&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?r1=1.248&r2=1.249

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.248
retrieving revision 1.249
diff -u -r1.248 -r1.249
--- ChangeLog	20 Mar 2012 19:58:49 -0000	1.248
+++ ChangeLog	22 Mar 2012 14:34:49 -0000	1.249
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.248 2012/03/20 19:58:49 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.249 2012/03/22 14:34:49 wired Exp $
+
+*mc-4.8.2-r1 (22 Mar 2012)
+
+  22 Mar 2012; Alex Alexander <wired@g.o> +mc-4.8.2-r1.ebuild,
+  +files/mc-4.8.2-mcedit-without-file-param-fix.patch:
+  fixed bug #409107
 
 *mc-4.8.2 (20 Mar 2012)
 



1.1                  app-misc/mc/mc-4.8.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.8.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.8.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.8.2-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.8.2-r1.ebuild,v 1.1 2012/03/22 14:34:49 wired Exp $

EAPI=4

inherit flag-o-matic

MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="+edit gpm mclib nls samba +slang test X +xdg"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )
	test? ( dev-libs/check )
	"

S=${WORKDIR}/${MY_P}

src_prepare() {
	cp "${FILESDIR}"/${P}-missing-do_panel_cd_stub_env.c \
		tests/src/filemanager/do_panel_cd_stub_env.c || die
	
	# bug 409107
	epatch "${FILESDIR}"/"${P}"-mcedit-without-file-param-fix.patch
}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang
	[[ ${CHOST} == *-solaris* ]] && append-ldflags "-lnsl -lsocket"

	local homedir=".mc"
	use xdg && homedir="XDG"

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_enable samba vfs-smb) \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit) \
		$(use_enable mclib) \
		$(use_enable test tests) \
		--with-homedir=${homedir}
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS README NEWS

	# fix bug #334383
	if use kernel_linux && [[ ${EUID} == 0 ]] ; then
		fowners root:tty /usr/libexec/mc/cons.saver
		fperms g+s /usr/libexec/mc/cons.saver
	fi
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
}