[gentoo-commits] gentoo-x86 commit in media-gfx/graphicsmagick: ChangeLog graphicsmagick-1.3.13.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/12/28 20:59:28

  Modified:             ChangeLog
  Added:                graphicsmagick-1.3.13.ebuild
  Log:
  Version bump wrt #395611 by Ivan S. Titov
  
  (Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

Revision  Changes    Path
1.84                 media-gfx/graphicsmagick/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	16 Dec 2011 09:34:05 -0000	1.83
+++ ChangeLog	28 Dec 2011 20:59:28 -0000	1.84
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/graphicsmagick
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.83 2011/12/16 09:34:05 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/ChangeLog,v 1.84 2011/12/28 20:59:28 ssuominen Exp $
+
+*graphicsmagick-1.3.13 (28 Dec 2011)
+
+  28 Dec 2011; Samuli Suominen <ssuominen@g.o>
+  +graphicsmagick-1.3.13.ebuild,
+  +files/graphicsmagick-1.3.13-lzma_configure.patch:
+  Version bump wrt #395611 by Ivan S. Titov
 
   16 Dec 2011; Naohiro Aota <naota@g.o> graphicsmagick-1.3.12-r1.ebuild:
   Add ~x86-fbsd



1.1                  media-gfx/graphicsmagick/graphicsmagick-1.3.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.13.ebuild?rev=1.1&content-type=text/plain

Index: graphicsmagick-1.3.13.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphicsmagick/graphicsmagick-1.3.13.ebuild,v 1.1 2011/12/28 20:59:28 ssuominen Exp $

EAPI=4
inherit eutils toolchain-funcs

MY_P=${P/graphicsm/GraphicsM}

DESCRIPTION="Collection of tools and libraries for many image formats"
HOMEPAGE="http://www.graphicsmagick.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="bzip2 cxx debug fpx imagemagick jbig jpeg jpeg2k lcms lzma modules openmp perl png q16 q32 static-libs svg threads tiff truetype wmf X zlib"

RDEPEND="app-text/ghostscript-gpl
	>=sys-devel/libtool-2.2.6b
	bzip2? ( app-arch/bzip2 )
	fpx? ( media-libs/libfpx )
	imagemagick? ( !media-gfx/imagemagick )
	jbig? ( media-libs/jbigkit )
	jpeg? ( virtual/jpeg )
	jpeg2k? ( >=media-libs/jasper-1.701.0 )
	lcms? ( media-libs/lcms:2 )
	lzma? ( app-arch/xz-utils )
	perl? ( dev-lang/perl )
	png? ( >=media-libs/libpng-1.2:0 )
	svg? ( dev-libs/libxml2 )
	tiff? ( >=media-libs/tiff-3.8.2:0 )
	truetype? ( >=media-libs/freetype-2.0 )
	wmf? ( media-libs/libwmf )
	X? (
		x11-libs/libSM
		x11-libs/libXext
		)
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${P}-lzma_configure.patch
}

src_configure() {
	local depth=8
	use q16 && depth=16
	use q32 && depth=32

	local openmp=disable
	if use openmp && tc-has-openmp; then
		openmp=enable
	fi

	econf \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
		--${openmp}-openmp \
		--enable-largefile \
		--enable-shared \
		$(use_enable static-libs static) \
		$(use_enable debug ccmalloc) \
		$(use_enable debug prof) \
		$(use_enable debug gcov) \
		$(use_enable imagemagick magick-compat) \
		$(use_with threads) \
		--without-included-ltdl \
		$(use_with modules) \
		--with-quantum-depth=${depth} \
		--without-frozenpaths \
		$(use_with cxx magick-plus-plus) \
		$(use_with perl) \
		--with-perl-options=INSTALLDIRS=vendor \
		$(use_with bzip2 bzlib) \
		$(use_with fpx) \
		--without-gslib \
		$(use_with jbig) \
		$(use_with jpeg) \
		$(use_with jpeg2k jp2) \
		--without-lcms \
		$(use_with lcms lcms2) \
		$(use_with lzma) \
		$(use_with png) \
		$(use_with tiff) \
		$(use_with truetype ttf) \
		$(use_with wmf) \
		--with-fontpath="${EPREFIX}"/usr/share/fonts \
		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/default/ghostscript \
		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts \
		$(use_with svg xml) \
		$(use_with zlib) \
		$(use_with X x)
}

src_compile() {
	emake
	use perl && emake perl-build
}

src_test() {
	emake check
}

src_install() {
	emake DESTDIR="${D}" install

	if use perl; then
		emake -C PerlMagick DESTDIR="${D}" install
		find "${ED}" -type f -name perllocal.pod -delete
		find "${ED}" -depth -mindepth 1 -type d -empty -delete
	fi

	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}