[gentoo-commits] gentoo-x86 commit in dev-java/java-gnome: ChangeLog java-gnome-4.0.11.ebuild

[Serkan Kaba (serkan)]

serkan      09/05/01 13:39:35

  Modified:             ChangeLog
  Added:                java-gnome-4.0.11.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc31/cvs/Linux x86_64)

Revision  Changes    Path
1.82                 dev-java/java-gnome/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/java-gnome/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/java-gnome/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/java-gnome/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/java-gnome/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	22 Mar 2009 18:33:56 -0000	1.81
+++ ChangeLog	1 May 2009 13:39:35 -0000	1.82
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/java-gnome
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/ChangeLog,v 1.81 2009/03/22 18:33:56 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/ChangeLog,v 1.82 2009/05/01 13:39:35 serkan Exp $
+
+*java-gnome-4.0.11 (01 May 2009)
+
+  01 May 2009; Serkan Kaba <serkan@g.o>
+  +files/java-gnome-4.0.11-force-unicode.patch, +java-gnome-4.0.11.ebuild:
+  Version bump.
 
   22 Mar 2009; Joseph Jezak <josejx@g.o> java-gnome-4.0.10.ebuild:
   Marked ~ppc.



1.1                  dev-java/java-gnome/java-gnome-4.0.11.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/java-gnome/java-gnome-4.0.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/java-gnome/java-gnome-4.0.11.ebuild?rev=1.1&content-type=text/plain

Index: java-gnome-4.0.11.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/java-gnome-4.0.11.ebuild,v 1.1 2009/05/01 13:39:35 serkan Exp $

EAPI=2
JAVA_PKG_IUSE="doc examples source"

inherit eutils versionator java-pkg-2 multilib

MY_PV="${PV/_/-}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Java bindings for GTK and GNOME"
HOMEPAGE="http://java-gnome.sourceforge.net/"
SRC_URI="mirror://gnome/sources/${PN}/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"

LICENSE="GPL-2-with-linking-exception"
SLOT="4.0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND=">=dev-libs/glib-2.16.1
	>=x11-libs/gtk+-2.14
	>=gnome-base/libglade-2.6.3
	>=gnome-base/libgnome-2.22.0
	>=gnome-base/gnome-desktop-2.22.0
	>=x11-libs/cairo-1.6.4[svg]
	>=virtual/jre-1.5"
DEPEND="${RDEPEND}
	dev-java/junit:0
	dev-lang/perl
	dev-util/pkgconfig
	>=virtual/jdk-1.5"

# Needs X11
RESTRICT="test"

S="${WORKDIR}/${MY_P}"

java_prepare() {
	epatch "${FILESDIR}"/${P}-force-unicode.patch
}

src_configure() {
	# Handwritten in perl so not using econf
	./configure prefix=/usr libdir=/usr/$(get_libdir)/${PN}-${SLOT} jardir=/usr/share/${PN}-${SLOT}/lib || die
}

src_compile() {
	# Fails parallel build in case GCJ is detected
	# See https://bugs.gentoo.org/show_bug.cgi?id=200550
	emake -j1 || die "Compilation of java-gnome failed"

	if use doc; then
		DISPLAY= emake -j1 doc || die "Making documentation failed"
	fi
}

src_install(){
	emake -j1 DESTDIR="${D}" install || die
	java-pkg_regjar /usr/share/${PN}-${SLOT}/lib/gtk-${SLOT}.jar
	java-pkg_regjar /usr/share/${PN}-${SLOT}/lib/gtk.jar

	dodoc AUTHORS HACKING NEWS README || die
	use doc && java-pkg_dojavadoc doc/api
	use examples && java-pkg_doexamples doc/examples
	use source && java-pkg_dosrc src/bindings/org
}