[gentoo-commits] proj/gnome:gnome-next commit in: x11-misc/colord/

[Alexandre Restovtsev]

commit:     7d719c43822108382a28568dc85a9c092ceb5007
Author:     Alexandre Rostovtsev <tetromino <AT> gmail <DOT> com>
AuthorDate: Tue Jul 12 04:30:30 2011 +0000
Commit:     Alexandre Restovtsev <tetromino <AT> gmail <DOT> com>
CommitDate: Tue Jul 12 04:35:38 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=7d719c43

x11-misc/colord: 0.1.9 → 0.1.10 + live ebuild

Version bump. Add doc and examples USE flags. Add a live ebuild (which
has optional introspection and vala support).

---
 x11-misc/colord/colord-0.1.10.ebuild |   84 ++++++++++++++++++++++++++++++
 x11-misc/colord/colord-0.1.9.ebuild  |   54 --------------------
 x11-misc/colord/colord-9999.ebuild   |   93 ++++++++++++++++++++++++++++++++++
 3 files changed, 177 insertions(+), 54 deletions(-)

diff --git a/x11-misc/colord/colord-0.1.10.ebuild b/x11-misc/colord/colord-0.1.10.ebuild
new file mode 100644
index 0000000..8f6a168
--- /dev/null
+++ b/x11-misc/colord/colord-0.1.10.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+
+inherit base
+if [[ ${PV} = 9999 ]]; then
+	GCONF_DEBUG="no"
+	inherit gnome2-live # need all the hacks from gnome2-live_src_prepare
+fi
+
+DESCRIPTION="System service to accurately color manage input and output devices"
+HOMEPAGE="http://colord.hughsie.com/"
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="git://gitorious.org/colord/master.git"
+else
+	SRC_URI="http://www.freedesktop.org/software/colord/releases/${P}.tar.xz"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} = 9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~x86"
+fi
+IUSE="doc examples scanner +udev"
+
+# XXX: raise to libusb-1.0.9:1 when available
+COMMON_DEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.28.0:2
+	>=dev-libs/libusb-1.0.8:1
+	>=media-libs/lcms-2.2:2
+	>=sys-auth/polkit-0.97
+	scanner? ( media-gfx/sane-backends )
+	udev? ( || ( sys-fs/udev[gudev] sys-fs/udev[extras] ) )
+"
+RDEPEND="${COMMON_DEPEND}
+	media-gfx/shared-color-profiles"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-sgml-utils
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	dev-util/pkgconfig
+	>=sys-devel/gettext-0.17
+	doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		>=dev-util/gtk-doc-1.9
+	)
+"
+
+# FIXME: needs pre-installed dbus service files
+RESTRICT="test"
+
+DOCS=(AUTHORS ChangeLog MAINTAINERS NEWS README TODO)
+
+src_configure() {
+	econf \
+		--disable-examples \
+		--disable-static \
+		--enable-polkit \
+		--enable-reverse \
+		$(use_enable doc gtk-doc) \
+		$(use_enable scanner sane) \
+		$(use_enable udev gudev)
+	# parallel make fails in doc/api
+	use doc && MAKEOPTS=-j1
+}
+
+src_install() {
+	base_src_install
+
+	# additional documentation files not included in tarball releases
+	[[ ${PV} = 9999 ]] && use doc && dodoc doc/*.txt doc/*.svg
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.c
+	fi
+
+	find "${D}" -name "*.la" -delete
+}

diff --git a/x11-misc/colord/colord-0.1.9.ebuild b/x11-misc/colord/colord-0.1.9.ebuild
deleted file mode 100644
index 1863ef0..0000000
--- a/x11-misc/colord/colord-0.1.9.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="3"
-
-inherit base
-
-DESCRIPTION="System service to accurately color manage input and output devices"
-HOMEPAGE="http://colord.hughsie.com/"
-SRC_URI="http://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="scanner +udev"
-
-# XXX: raise to libusb-1.0.9:1 when available
-RDEPEND="
-	dev-db/sqlite:3
-	>=dev-libs/glib-2.28.0:2
-	>=dev-libs/libusb-1.0.8:1
-	>=media-libs/lcms-2.2:2
-	>=sys-auth/polkit-0.97
-	scanner? ( media-gfx/sane-backends )
-	udev? ( || ( sys-fs/udev[gudev] sys-fs/udev[extras] ) )
-"
-DEPEND="${RDEPEND}
-	app-text/docbook-sgml-utils
-	dev-libs/libxslt
-	>=dev-util/intltool-0.35
-	dev-util/pkgconfig
-	>=sys-devel/gettext-0.17
-"
-
-# FIXME: needs pre-installed dbus service files
-RESTRICT="test"
-
-DOCS=(AUTHORS ChangeLog MAINTAINERS NEWS README TODO)
-
-src_configure() {
-	econf \
-		--disable-examples \
-		--disable-static \
-		--enable-polkit \
-		--enable-reverse \
-		$(use_enable scanner sane) \
-		$(use_enable udev gudev)
-}
-
-src_install() {
-	base_src_install
-	find "${D}" -name "*.la" -delete
-}

diff --git a/x11-misc/colord/colord-9999.ebuild b/x11-misc/colord/colord-9999.ebuild
new file mode 100644
index 0000000..5acd534
--- /dev/null
+++ b/x11-misc/colord/colord-9999.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+
+inherit base
+if [[ ${PV} = 9999 ]]; then
+	GCONF_DEBUG="no"
+	inherit gnome2-live # need all the hacks from gnome2-live_src_prepare
+fi
+
+DESCRIPTION="System service to accurately color manage input and output devices"
+HOMEPAGE="http://colord.hughsie.com/"
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="git://gitorious.org/colord/master.git"
+else
+	SRC_URI="http://www.freedesktop.org/software/colord/releases/${P}.tar.xz"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} = 9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~x86"
+fi
+IUSE="doc examples +introspection scanner +udev vala"
+
+# XXX: raise to libusb-1.0.9:1 when available
+COMMON_DEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.28.0:2
+	>=dev-libs/libusb-1.0.8:1
+	>=media-libs/lcms-2.2:2
+	>=sys-auth/polkit-0.97
+	introspection? ( >=dev-libs/gobject-introspection-0.9.8 )
+	scanner? ( media-gfx/sane-backends )
+	udev? ( || ( sys-fs/udev[gudev] sys-fs/udev[extras] ) )
+"
+RDEPEND="${COMMON_DEPEND}
+	media-gfx/shared-color-profiles"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-sgml-utils
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	dev-util/pkgconfig
+	>=sys-devel/gettext-0.17
+	doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		>=dev-util/gtk-doc-1.9
+	)
+	vala? ( dev-lang/vala:0.12 )
+"
+
+# FIXME: needs pre-installed dbus service files
+RESTRICT="test"
+
+DOCS=(AUTHORS ChangeLog MAINTAINERS NEWS README TODO)
+
+src_configure() {
+	if use vala; then
+		if use introspection; then
+			export VAPIGEN=$(type -p vapigen-0.12)
+		else
+			ewarn "Vala bindings cannot be built because the introspection USE flag is disabled"
+		fi
+	fi
+	econf \
+		--disable-examples \
+		--disable-static \
+		--enable-polkit \
+		--enable-reverse \
+		$(use_enable doc gtk-doc) \
+		$(use_enable scanner sane) \
+		$(use_enable udev gudev)
+	# parallel make fails in doc/api
+	use doc && MAKEOPTS=-j1
+}
+
+src_install() {
+	base_src_install
+
+	# additional documentation files not included in tarball releases
+	[[ ${PV} = 9999 ]] && use doc && dodoc doc/*.txt doc/*.svg
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.c
+	fi
+
+	find "${D}" -name "*.la" -delete
+}