[gentoo-commits] gentoo-x86 commit in media-sound/aqualung: aqualung-0.9_beta9_p1.ebuild metadata.xml Manifest ChangeLog

[Ben de Groot (yngwin)]

yngwin      08/04/15 03:05:05

  Added:                aqualung-0.9_beta9_p1.ebuild metadata.xml Manifest
                        ChangeLog
  Log:
  Initial commit for media-sound/aqualung. Fixes bug 88532 - after 3 years ;)
  (Portage version: 2.1.5_rc3)

Revision  Changes    Path
1.1                  media-sound/aqualung/aqualung-0.9_beta9_p1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta9_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta9_p1.ebuild?rev=1.1&content-type=text/plain

Index: aqualung-0.9_beta9_p1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta9_p1.ebuild,v 1.1 2008/04/15 03:05:05 yngwin Exp $

inherit eutils autotools versionator

MY_PV="$(delete_version_separator 2)"
MY_PV="${MY_PV/_p/.}"

DESCRIPTION="A music player for a wide range of formats designed for gapless playback"
HOMEPAGE="http://aqualung.factorial.hu/"
SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE="sndfile modplug mp3 vorbis speex flac musepack wavpack ffmpeg taglib ladspa
	cddb cdda jack alsa oss lame loop-playback systray debug"
KEYWORDS="~amd64 ~x86"

RDEPEND="vorbis? ( >=media-libs/libvorbis-1.0 )
	sndfile? ( >=media-libs/libsndfile-1.0.12 )
	flac? ( media-libs/flac )
	modplug? ( media-libs/libmodplug )
	alsa? ( virtual/alsa )
	mp3? ( media-libs/libmad )
	lame? ( media-sound/lame )
	musepack? ( media-libs/libmpcdec )
	ffmpeg? ( media-video/ffmpeg )
	speex? ( media-libs/speex media-libs/liboggz )
	wavpack? ( >=media-sound/wavpack-4.40.0 )
	cddb? ( !amd64? ( >=media-libs/libcddb-1.2.1 ) )
	cddb? ( amd64? ( >=media-libs/libcddb-1.3.0 ) )
	jack? ( media-sound/jack-audio-connection-kit )
	taglib? ( >=media-libs/taglib-1.4 )
	cdda? ( dev-libs/libcdio )
	systray? ( >=x11-libs/gtk+-2.10 )
	loop-playback? ( >=x11-libs/gtk+-2.8 )
	media-libs/libsamplerate
	>=x11-libs/gtk+-2.6"

DEPEND="ladspa? ( >=media-libs/liblrdf-0.4.0 )
	>=dev-util/pkgconfig-0.9.0
	dev-libs/libxml2
	media-libs/raptor
	${RDEPEND}"

S="${WORKDIR}/${PN}-${MY_PV}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/new-ffmpeg-headers.patch
}

src_compile() {
	econf \
		$(use_with alsa) \
		$(use_with oss) \
		$(use_with jack) \
		$(use_with flac) \
		$(use_with vorbis ogg) \
		$(use_with sndfile) \
		$(use_with mp3 mpeg) \
		$(use_with lame) \
		$(use_with modplug mod) \
		$(use_with musepack mpc) \
		$(use_with ffmpeg lavc) \
		$(use_with speex) \
		$(use_with wavpack) \
		$(use_with cddb) \
		$(use_with systray) \
		$(use_with ladspa) \
		$(use_with taglib metadata) \
		$(use_with cdda) \
		$(use_with loop-playback loop) \
		$(use_enable debug) \
		|| die "econf failed"

	emake || die "make failed"
}

src_install() {
	emake install DESTDIR="${D}" || die "make install failed"
	dodoc AUTHORS README
	newicon src/img/icon_64.png aqualung.png
	make_desktop_entry aqualung Aqualung
}



1.1                  media-sound/aqualung/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>sound</herd>
</pkgmetadata>



1.1                  media-sound/aqualung/Manifest

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
AUX new-ffmpeg-headers.patch 920 RMD160 15e8f3bad767612722319cf4157dd904baef0b16 SHA1 598f5718822f8e838ec54ae41f49f14e61918e1c SHA256 0f5395d9bcc1e50bed1fbbad3c3f4cb060bed554191c339c0cd2ff1da27deebc
DIST aqualung-0.9beta9.1.tar.gz 1071744 RMD160 6d50b4eb0c2ce80048c0ab488088f485833abbd1 SHA1 12b07679fd86017a863d252c15d0691f81bbd678 SHA256 b15a229077779e11c63c98666c2931e1778c720ad659afae1df72d63fb48bd17
EBUILD aqualung-0.9_beta9_p1.ebuild 2330 RMD160 5b2549c06bea848de74496ec946f46f793d4b506 SHA1 6b0a599b5a9275eeb680e858bbaee7aa431414fb SHA256 5ffcc5ec590036f97a9ea1d778bfbdc7df9628a70cd1d7a30966cadeb52fd11f
MISC ChangeLog 360 RMD160 a62fe28d4964aa6f7c8bfb8a84ea1f61c3100666 SHA1 a894e457f89441b4c9dca20e8c9a82a474f3b8a7 SHA256 99fe7ed6d6e7f7d07d580d1efa43042a2554afda355ccd477a96a26f0982d1c3
MISC metadata.xml 160 RMD160 10be84fed28405abd22adc6689e87e5bb77e3501 SHA1 0c1bb16a7cc376ef35b87d8699ec9504718d36b9 SHA256 6bafe4a5c7b42309f124ebc2a9d78ebe5379aec4dcdc88c0bda2ab79c9851a6b



1.1                  media-sound/aqualung/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-sound/aqualung
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.1 2008/04/15 03:05:05 yngwin Exp $

*aqualung-0.9_beta9_p1 (15 Apr 2008)

  15 Apr 2008; Ben de Groot <yngwin@g.o>
  +files/new-ffmpeg-headers.patch, +metadata.xml,
  +aqualung-0.9_beta9_p1.ebuild:
  Initial import. Ebuild adapted from Maarten Maathuis in bug 88532.




-- 
gentoo-commits@l.g.o mailing list