[gentoo-commits] gentoo-x86 commit in net-analyzer/snips: ChangeLog snips-1.2-r2.ebuild snips-1.2-r1.ebuild

[Tony Vroon (chainsaw)]

chainsaw    08/07/04 11:43:41

  Modified:             ChangeLog
  Added:                snips-1.2-r2.ebuild
  Removed:              snips-1.2-r1.ebuild
  Log:
  Add a snips user & group to the system and set permissions appropriately. Install 3 missing files.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.26-rc8-00204-gc461a97-dirty x86_64)

Revision  Changes    Path
1.3                  net-analyzer/snips/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/snips/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/snips/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/snips/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/snips/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	30 Jun 2008 12:18:52 -0000	1.2
+++ ChangeLog	4 Jul 2008 11:43:40 -0000	1.3
@@ -1,6 +1,14 @@
 # ChangeLog for net-analyzer/snips
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/snips/ChangeLog,v 1.2 2008/06/30 12:18:52 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/snips/ChangeLog,v 1.3 2008/07/04 11:43:40 chainsaw Exp $
+
+*snips-1.2-r2 (04 Jul 2008)
+
+  04 Jul 2008; <chainsaw@g.o> +files/snips-1.2-install-missing.patch,
+  -files/snips-1.2-r1-precache-config, +files/snips-1.2-r2-precache-config,
+  -snips-1.2-r1.ebuild, +snips-1.2-r2.ebuild:
+  Add a snips user & group to the system and set permissions appropriately.
+  Install 3 missing files.
 
 *snips-1.2-r1 (30 Jun 2008)
 



1.1                  net-analyzer/snips/snips-1.2-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/snips/snips-1.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/snips/snips-1.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: snips-1.2-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/snips/snips-1.2-r2.ebuild,v 1.1 2008/07/04 11:43:40 chainsaw Exp $

inherit eutils toolchain-funcs

DESCRIPTION="System & Network Integrated Polling Software"
HOMEPAGE="http://www.netplex-tech.com/snips/"
SRC_URI="http://www.netplex-tech.com/software/downloads/${PN}/${P}.tar.gz"
LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND="dev-lang/perl
	 mail-client/mailx
	 net-analyzer/rrdtool
	 >=net-misc/iputils-20071127-r2
	 sys-libs/gdbm
	 sys-libs/ncurses"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Gentoo-specific non-interactive configure override
	cp "${FILESDIR}/${PF}-precache-config" "${S}/Config.cache" \
		|| die "Unable to precache configure script answers"
	echo "CFLAGS=\"${CFLAGS} -fPIC\"" >> "${S}/Config.cache"
	echo "CC=\"$(tc-getCC)\"" >> "${S}/Config.cache"
	echo "SRCDIR=\"${S}\"" >> "${S}/Config.cache"
	epatch "${FILESDIR}/${P}-non-interactive.patch"
	# Applied to upstream CVS
	epatch "${FILESDIR}/${P}-install-missing.patch"
	epatch "${FILESDIR}/${P}-implicit-declarations.patch"
	epatch "${FILESDIR}/${P}-conflicting-types.patch"
	epatch "${FILESDIR}/${P}-code-ordering.patch"
	epatch "${FILESDIR}/${P}-destdir-awareness.patch"
}

src_compile() {
	# Looks horrid due to missing linebreaks, suppress output
	ebegin "Running configure script (with precached settings)"
		./Configure &> /dev/null || die "Unable to configure"
	eend $?
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_preinst() {
	enewgroup snips
	enewuser snips -1 -1 /usr/snips snips
}

pkg_postinst() {
	ebegin "Fixing permissions"
	chown -R snips:snips "${ROOT}"usr/snips
	for x in data logs msgs rrddata run web device-help etc; do
		chmod -R g+w "${ROOT}usr/snips/${x}" \
			|| die "Unable to chmod ${x}"
	done
	chown root:snips "${ROOT}usr/snips/bin/multiping" || die "chown root failed"
	chown root:snips "${ROOT}usr/snips/bin/etherload" || die "chown root failed"
	chown root:snips "${ROOT}usr/snips/bin/trapmon" || die "chown root failed"
	chmod u+s "${ROOT}usr/snips/bin/multiping" || die "SetUID root failed"
	chmod u+s "${ROOT}usr/snips/bin/etherload" || die "SetUID root failed"
	chmod u+s "${ROOT}usr/snips/bin/trapmon" || die "SetUID root failed"
	eend $?
}



-- 
gentoo-commits@l.g.o mailing list