[gentoo-commits] gentoo-x86 commit in net-misc/openswan: ChangeLog openswan-2.4.9-r1.ebuild openswan-2.4.9.ebuild

[Alin Nastac (mrness)]

mrness      07/09/26 08:14:22

  Modified:             ChangeLog
  Added:                openswan-2.4.9-r1.ebuild
  Removed:              openswan-2.4.9.ebuild
  Log:
  Fix erroneous creation of rundir and subsysdir (#193824). Sanitize the ebuild code.
  (Portage version: 2.1.2.12)

Revision  Changes    Path
1.42                 net-misc/openswan/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/openswan/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/openswan/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/openswan/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/openswan/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	23 Sep 2007 07:32:08 -0000	1.41
+++ ChangeLog	26 Sep 2007 08:14:22 -0000	1.42
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/openswan
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/openswan/ChangeLog,v 1.41 2007/09/23 07:32:08 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/openswan/ChangeLog,v 1.42 2007/09/26 08:14:22 mrness Exp $
+
+*openswan-2.4.9-r1 (26 Sep 2007)
+
+  26 Sep 2007; Alin Năstac <mrness@g.o>
+  +files/openswan-2.4.9-mkdir.patch, -openswan-2.4.9.ebuild,
+  +openswan-2.4.9-r1.ebuild:
+  Fix erroneous creation of rundir and subsysdir (#193824).
+  Sanitize the ebuild code.
 
   23 Sep 2007; Alin Năstac <mrness@g.o> openswan-2.4.9.ebuild:
   Stable on amd64 (#192964).



1.1                  net-misc/openswan/openswan-2.4.9-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/openswan/openswan-2.4.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/openswan/openswan-2.4.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: openswan-2.4.9-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/openswan/openswan-2.4.9-r1.ebuild,v 1.1 2007/09/26 08:14:22 mrness Exp $

inherit eutils linux-info

DESCRIPTION="Open Source implementation of IPsec for the Linux operating system (was SuperFreeS/WAN)."
HOMEPAGE="http://www.openswan.org/"
SRC_URI="http://www.openswan.org/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc ~sparc x86"
IUSE="smartcard extra-algorithms weak-algorithms"

COMMON_DEPEND="!net-misc/strongswan
	>=dev-libs/gmp-4.2.1
	smartcard? ( dev-libs/opensc )"
DEPEND="${COMMON_DEPEND}
	virtual/linux-sources"
RDEPEND="${COMMON_DEPEND}
	virtual/logger
	sys-apps/iproute2"

pkg_setup() {
	linux-info_pkg_setup

	if kernel_is 2 6; then
		einfo "This ebuild will set ${P} to use 2.6 native IPsec (KAME)."
		einfo "KLIPS will not be compiled/installed."
		MYMAKE="programs"

	elif kernel_is 2 4; then
		if ! [ -d /usr/src/linux/net/ipsec ]; then
			eerror "You need to have an IPsec enabled 2.4.x kernel."
			eerror "Ensure you have one running and make a symlink to it in /usr/src/linux"
			die
		fi

		einfo "Using patched-in IPsec code for kernel 2.4"
		einfo "Your kernel only supports KLIPS for kernel level IPsec."
		MYMAKE="confcheck programs"

	else
		die "Unsupported kernel version"
	fi
}

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}"/${P}-gentoo.patch
	epatch "${FILESDIR}"/${P}-mkdir.patch
}

get_make_options() {
	local MY_MAKE_OPTIONS="FINALCONFDIR=/etc/ipsec \
		INC_RCDEFAULT=/etc/init.d \
		INC_USRLOCAL=/usr \
		INC_MANDIR=share/man \
		FINALEXAMPLECONFDIR=/usr/share/doc/${P} \
		FINALDOCDIR=/usr/share/doc/${P}"
	if use smartcard ; then
		MY_MAKE_OPTIONS="${MY_MAKE_OPTIONS} USE_SMARTCARD=true"
	fi
	if use extra-algorithms ; then
		MY_MAKE_OPTIONS="${MY_MAKE_OPTIONS} USE_EXTRACRYPTO=true"
	fi
	if use weak-algorithms ; then
		MY_MAKE_OPTIONS="${MY_MAKE_OPTIONS} USE_WEAKSTUFF=true"
	fi
	echo ${MY_MAKE_OPTIONS}
}

src_compile() {
	emake \
		DESTDIR="${D}" \
		USERCOMPILE="${CFLAGS}" \
		$(get_make_options) \
		${MYMAKE} || die "emake failed"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		USERCOMPILE="${CFLAGS}" \
		$(get_make_options) \
		install || die "emake install failed"

	dosym /etc/ipsec/ipsec.d /etc/ipsec.d

	doinitd "${FILESDIR}"/ipsec || die "failed to install init script"

	dodir /var/run/pluto || die "failed to create /var/run/pluto"
}

pkg_preinst() {
	# Try to fix previous openswan-2.4.9 blooper (#193824)
	if [[ "${ROOT}" == / ]] && has_version "=net-misc/openswan-2.4.9" ; then
		elog "Trying to remove empty {rundir,subsysdir} erroneously created by openswan-2.4.9"
		local base dir
		for base in / /root/ /etc/ ; do
			for dir in rundir subsysdir ; do
				if [[ -d "${base}${dir}" ]]; then
					rmdir "${base}${dir}" \
						&& elog "Empty directory ${base}${dir} has been removed" \
						|| ewarn "Failed to remove ${base}${dir} (perhaps some other package owns it?)"
				fi
			done
		done
	fi
}

pkg_postinst() {
	if kernel_is 2 6; then
		CONFIG_CHECK="~NET_KEY ~INET_XFRM_MODE_TRANSPORT ~INET_XFRM_MODE_TUNNEL ~INET_AH ~INET_ESP ~INET_IPCOMP"
		WARNING_INET_AH="CONFIG_INET_AH:\tmissing IPsec AH support (needed if you want only authentication)"
		WARNING_INET_ESP="CONFIG_INET_ESP:\tmissing IPsec ESP support (needed if you want authentication and encryption)"
		WARNING_INET_IPCOMP="CONFIG_INET_IPCOMP:\tmissing IPsec Payload Compression (required for compress=yes)"
		check_extra_config
	fi
}



-- 
gentoo-commits@g.o mailing list