[gentoo-commits] gentoo-x86 commit in net-libs/gupnp-igd: ChangeLog gupnp-igd-0.2.0.ebuild gupnp-igd-0.1.10.ebuild

[Gilles Dartiguelongue (eva)]

eva         11/11/13 21:34:27

  Modified:             ChangeLog
  Added:                gupnp-igd-0.2.0.ebuild
  Removed:              gupnp-igd-0.1.10.ebuild
  Log:
  Version bump. Make it work with gupnp-0.18. Clean up old revision.
  
  (Portage version: 2.2.0_alpha73/cvs/Linux x86_64)

Revision  Changes    Path
1.31                 net-libs/gupnp-igd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	24 Oct 2011 06:08:54 -0000	1.30
+++ ChangeLog	13 Nov 2011 21:34:27 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gupnp-igd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v 1.30 2011/10/24 06:08:54 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v 1.31 2011/11/13 21:34:27 eva Exp $
+
+*gupnp-igd-0.2.0 (13 Nov 2011)
+
+  13 Nov 2011; Gilles Dartiguelongue <eva@g.o> -gupnp-igd-0.1.10.ebuild,
+  +gupnp-igd-0.2.0.ebuild:
+  Version bump. Make it work with gupnp-0.18. Clean up old revision.
 
   24 Oct 2011; Alexandre Rostovtsev <tetromino@g.o>
   gupnp-igd-0.1.7.ebuild, gupnp-igd-0.1.10.ebuild, gupnp-igd-0.1.11.ebuild:



1.1                  net-libs/gupnp-igd/gupnp-igd-0.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.0.ebuild?rev=1.1&content-type=text/plain

Index: gupnp-igd-0.2.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.0.ebuild,v 1.1 2011/11/13 21:34:27 eva Exp $

EAPI="3"
PYTHON_DEPEND="python? 2:2.5"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.4 3.* *-jython"

inherit autotools eutils python

DESCRIPTION="This is a library to handle UPnP IGD port mapping for GUPnP."
HOMEPAGE="http://gupnp.org"
SRC_URI="http://www.gupnp.org/sites/all/files/sources/${P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+introspection python"

RDEPEND=">=net-libs/gupnp-0.18
	>=dev-libs/glib-2.16:2
	introspection? ( >=dev-libs/gobject-introspection-0.10 )
	python? ( >=dev-python/pygobject-2.16:2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext
	dev-util/gtk-doc-am"

# The only existing test is broken
RESTRICT="test"

pkg_setup() {
	if use python; then
		python_pkg_setup
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.1.11-disable_static_modules.patch

	# Disable byte-compilation of Python modules.
	echo "#!/bin/sh" > py-compile

	# Python bindings are built/installed manually.
	sed -e "/PYTHON_SUBDIR =/s/ python//" -i Makefile.am

	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--disable-static \
		--disable-gtk-doc \
		$(use_enable introspection) \
		$(use_enable python)
}

src_compile() {
	# introspection is built in the same directory and libtool does not handle
	# well dependency like this
	MAKEOPTS="${MAKEOPTS} -j1" default

	if use python; then
		python_copy_sources python

		building() {
			emake \
				PYTHON_INCLUDES="-I$(python_get_includedir)" \
				pyexecdir="$(python_get_sitedir)"
		}
		python_execute_function -s --source-dir python building
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die

	if use python; then
		installation() {
			emake \
				DESTDIR="${D}" \
				pyexecdir="$(python_get_sitedir)" \
				install
		}
		python_execute_function -s --source-dir python installation

		python_clean_installation_image
	fi

	dodoc AUTHORS NEWS README TODO || die
	find "${D}" -name "*.la" -delete
}

pkg_postinst() {
	if use python; then
		python_mod_optimize gupnp
	fi
}

pkg_postrm() {
	if use python; then
		python_mod_cleanup gupnp
	fi
}