Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Sebastien Fabbro (bicatali)" <bicatali@g.o>
Subject: gentoo-x86 commit in dev-python/cvxopt: cvxopt-1.1.5-r1.ebuild ChangeLog cvxopt-1.1.4-r1.ebuild
Date: Sat, 26 May 2012 14:56:34 +0000 (UTC)
bicatali    12/05/26 14:56:34

  Modified:             ChangeLog
  Added:                cvxopt-1.1.5-r1.ebuild
  Removed:              cvxopt-1.1.4-r1.ebuild
  Log:
  fixed typo. removed old
  
  (Portage version: 2.1.10.60/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-python/cvxopt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cvxopt/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cvxopt/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cvxopt/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/cvxopt/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	24 May 2012 15:33:22 -0000	1.9
+++ ChangeLog	26 May 2012 14:56:34 -0000	1.10
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/cvxopt
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/ChangeLog,v 1.9 2012/05/24 15:33:22 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/ChangeLog,v 1.10 2012/05/26 14:56:34 bicatali Exp $
+
+*cvxopt-1.1.5-r1 (26 May 2012)
+
+  26 May 2012; S├ębastien Fabbro <bicatali@g.o> -cvxopt-1.1.4-r1.ebuild,
+  +cvxopt-1.1.5-r1.ebuild, files/cvxopt-1.1.5-setup.patch,
+  -files/cvxopt-setup.patch:
+  fixed typo. removed old
 
   24 May 2012; S├ębastien Fabbro <bicatali@g.o>
   files/cvxopt-1.1.5-setup.patch:



1.1                  dev-python/cvxopt/cvxopt-1.1.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cvxopt/cvxopt-1.1.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cvxopt/cvxopt-1.1.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: cvxopt-1.1.5-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/cvxopt-1.1.5-r1.ebuild,v 1.1 2012/05/26 14:56:34 bicatali Exp $

EAPI=4

SUPPORT_PYTHON_ABIS=1
RESTRICT_PYTHON_ABIS="2.4 2.5 *-jython 2.7-pypy-*"

inherit distutils eutils

DESCRIPTION="Python package for convex optimization"
HOMEPAGE="http://abel.ee.ucla.edu/cvxopt"
SRC_URI="http://abel.ee.ucla.edu/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc +dsdp examples fftw +glpk gsl"

RDEPEND="virtual/blas
	virtual/cblas
	virtual/lapack
	sci-libs/cholmod
	sci-libs/umfpack
	dsdp? ( sci-libs/dsdp )
	fftw? ( sci-libs/fftw:3.0 )
	glpk? ( sci-mathematics/glpk )
	gsl? ( sci-libs/gsl )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( dev-python/sphinx )"

S="${WORKDIR}/${P}/src"

src_prepare(){
	epatch "${FILESDIR}"/${P}-setup.patch
	rm -rf src/C/SuiteSparse*/
	rm -rf ../doc/build # 413905

	pkg_lib() {
		local pylib=\'$(pkg-config --libs-only-l ${1} | sed \
			-e 's/^-l//' \
			-e "s/ -l/\',\'/g" \
			-e 's/.,.pthread//g' \
			-e "s:  ::")\'
		sed -i -e "/_LIB = /s:\(.*\)'${1}'\(.*\):\1${pylib}\2:" setup.py
	}

	use_cvx() {
		if use ${1}; then
			sed -i \
				-e "s/\(BUILD_${1^^} =\) 0/\1 1/" \
				setup.py || die
		fi
	}

	pkg_lib blas
	pkg_lib lapack
	use_cvx gsl
	use_cvx fftw
	use_cvx glpk
	use_cvx dsdp
	distutils_src_prepare
}

src_compile() {
	distutils_src_compile
	use doc && emake -C "${WORKDIR}"/${P}/doc -B html
}

src_test() {
	cd "${WORKDIR}"/${P}/examples/doc/chap8
	testing() {
		PYTHONPATH="$(ls -d ${S}/build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" lp.py
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install
	use doc && dohtml -r "${WORKDIR}"/${P}/doc/build/html/*
	insinto /usr/share/doc/${PF}
	use examples && doins -r "${WORKDIR}"/${P}/examples
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
proj/hardened-dev:master commit in: app-admin/setools/
Next by thread:
gentoo-x86 commit in dev-python/cvxopt/files: cvxopt-1.1.5-setup.patch cvxopt-setup.patch
Previous by date:
proj/hardened-dev:master commit in: app-admin/setools/
Next by date:
gentoo-x86 commit in dev-python/cvxopt/files: cvxopt-1.1.5-setup.patch cvxopt-setup.patch


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.