[gentoo-commits] gentoo-x86 commit in dev-java/icu4j: ChangeLog icu4j-3.6.1.ebuild

[Jean-Noel Rivasseau (elvanor)]

elvanor     08/01/11 15:11:22

  Modified:             ChangeLog
  Added:                icu4j-3.6.1.ebuild
  Log:
  icu4j version bump to 3.6.1, bug #153686.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.17                 dev-java/icu4j/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/icu4j/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	30 May 2007 16:28:09 -0000	1.16
+++ ChangeLog	11 Jan 2008 15:11:22 -0000	1.17
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/icu4j
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/icu4j/ChangeLog,v 1.16 2007/05/30 16:28:09 betelgeuse Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/icu4j/ChangeLog,v 1.17 2008/01/11 15:11:22 elvanor Exp $
+
+*icu4j-3.6.1 (11 Jan 2008)
+
+  11 Jan 2008; Jean-Noël Rivasseau <elvanor@g.o>
+  +files/icu4j-3.6.1-manifest, +icu4j-3.6.1.ebuild:
+  Version bump to 3.6.1, bug #153686. Also now generates an OSGi compliant
+  jar, for Eclipse 3.3.
 
   30 May 2007; Petteri Räty <betelgeuse@g.o> -icu4j-3.0.ebuild:
   Remove generation 1 ebuild.



1.1                  dev-java/icu4j/icu4j-3.6.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/icu4j-3.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/icu4j-3.6.1.ebuild?rev=1.1&content-type=text/plain

Index: icu4j-3.6.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/icu4j/icu4j-3.6.1.ebuild,v 1.1 2008/01/11 15:11:22 elvanor Exp $

# We currently download the Javadoc documentation.
# It could optionally be built using the Ant build file.
# testdata.jar and icudata.jar do not contain *.class files but *.res files
# These *.res data files are needed to built the final jar
# They do not need to be installed however as they will already be present in icu4j.jar

JAVA_PKG_IUSE="source"

inherit java-pkg-2 java-ant-2 java-osgi

DESCRIPTION="ICU4J is a mature, widely used set of Java libraries providing Unicode and Globalization support for software applications."
MY_PV=${PV//./_}

SRC_URI="http://download.icu-project.org/files/${PN}/${PV}/${PN}src_${MY_PV}.jar
	doc? (http://download.icu-project.org/files/${PN}/${PV}/${PN}docs_${MY_PV}.jar)"

HOMEPAGE="http://www.icu-project.org/"
LICENSE="icu"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"

RDEPEND=">=virtual/jre-1.4"

DEPEND="test? ( =virtual/jdk-1.5* )
	!test? ( >=virtual/jdk-1.4 )"

IUSE="doc test"

S="${WORKDIR}"

src_unpack() {
	jar -xf "${DISTDIR}/${PN}src_${MY_PV}.jar" || die "Failed to unpack"

	if use doc; then
		mkdir docs; cd docs
		jar -xf "${DISTDIR}/${PN}docs_${MY_PV}.jar" || die "Failed to unpack docs"
	fi
}

src_compile() {
	eant jar || die "Compile failed"
}

src_install() {
	java-osgi_newjar-fromfile "${PN}.jar" "${FILESDIR}/icu4j-${PV}-manifest" \
		"International Components for Unicode for Java (ICU4J)"
	java-pkg_dojar "${PN}-charsets.jar"

	use doc && dohtml -r readme.html docs/*
	use source && java-pkg_dosrc src/*
}

# Following tests will fail in Sun JDK 6 (at least):
# toUnicode: http://bugs.icu-project.org/trac/ticket/5663
# TimeZoneTransitionAdd: http://bugs.icu-project.org/trac/ticket/5887
# These are bugs in the tests themselves, not in the library

src_test() {
	eant check
}


-- 
gentoo-commits@l.g.o mailing list