[gentoo-commits] gentoo-x86 commit in dev-libs/cyberjack: ChangeLog cyberjack-3.0.4.ebuild

[Wolfram Schlich (wschlich)]

wschlich    07/09/21 00:22:09

  Modified:             ChangeLog
  Added:                cyberjack-3.0.4.ebuild
  Log:
  version bump
  (Portage version: 2.1.3.7)

Revision  Changes    Path
1.6                  dev-libs/cyberjack/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/cyberjack/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/cyberjack/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/cyberjack/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	18 Mar 2007 20:34:56 -0000	1.5
+++ ChangeLog	21 Sep 2007 00:22:09 -0000	1.6
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/cyberjack
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/ChangeLog,v 1.5 2007/03/18 20:34:56 wschlich Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/ChangeLog,v 1.6 2007/09/21 00:22:09 wschlich Exp $
+
+*cyberjack-3.0.4 (20 Sep 2007)
+
+  20 Sep 2007; Wolfram Schlich <wschlich@g.o>
+  +files/cyberjack-3.0.4-udev.patch, +files/cyberjack.rules,
+  +cyberjack-3.0.4.ebuild:
+  version bump
 
 *cyberjack-2.0.14_beta1 (18 Mar 2007)
 



1.1                  dev-libs/cyberjack/cyberjack-3.0.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/cyberjack/cyberjack-3.0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/cyberjack/cyberjack-3.0.4.ebuild?rev=1.1&content-type=text/plain

Index: cyberjack-3.0.4.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/cyberjack-3.0.4.ebuild,v 1.1 2007/09/21 00:22:09 wschlich Exp $

inherit eutils flag-o-matic autotools

MY_P="ctapi-${P/_/}"

DESCRIPTION="REINER SCT cyberJack pinpad/e-com USB user space driver library"
HOMEPAGE="http://www.reiner-sct.de/ http://sourceforge.net/projects/libchipcard/"
SRC_URI="mirror://sourceforge/libchipcard/${MY_P}.tar.gz"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="noudev pcsc-lite"
RDEPEND="
	dev-libs/libusb
	pcsc-lite? (
		sys-apps/pcsc-lite
		dev-util/pkgconfig
	)
"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_P}"

pkg_setup() {
	useq noudev || enewgroup "${PN}"
}

src_unpack() {
	unpack ${A} || die "Unpacking failed."
	cd "${S}" || die "Failed to change to source directory."
	useq noudev || {
		epatch "${FILESDIR}/${P}-udev.patch" || die "Applying udev patch failed."
		cp ${FILESDIR}/cyberjack.sh etc/udev/ || die "Copying udev script failed."
		cp ${FILESDIR}/cyberjack.rules etc/udev/rules.new || die "Copying udev rules failed."
	}
	AT_M4DIR="m4" eautoreconf || die "Adopting configurations failed."
}

src_compile() {
	append-flags -fno-strict-aliasing
	local with_usbdropdir=''
	useq pcsc-lite && with_usbdropdir="--with-usbdropdir=$(pkg-config libpcsclite --variable=usbdropdir)"
	./configure \
		--prefix=/usr \
		--docdir=/usr/share/doc/"${P}" \
		--sysconfdir=/etc/"${PN}" \
		$(use_enable pcsc-lite pcsc) \
		${with_usbdropdir} \
		$(use_enable !noudev udev) \
		|| die "Configuration of package failed."
	emake || die "Compilation of package failed."
}

src_install() {
	emake install DESTDIR="${D}" || die "Installation of package failed."
	dodoc ChangeLog NEWS doc/README.txt
}

pkg_postinst() {
	local conf="/etc/${PN}/${PN}.conf"
	elog
	elog "To configure logging, key beep behaviour etc. you need to"
	elog "copy ${conf}.default"
	elog "to ${conf}"
	elog "and modify the latter as needed."
	elog
	useq noudev || {
		elog "Please run the following command as root to"
		elog "make udevd read the cyberJack rules that were"
		elog "just installed onto your system:"
		elog
		elog "  udevcontrol reload_rules"
		elog
		elog "To be able to use the cyberJack device, you need to"
		elog "be a member of the group 'cyberjack' which has just"
		elog "been added to your system. You can add your user to"
		elog "the group by running the following command as root:"
		elog
		elog "  gpasswd -a youruser cyberjack"
		elog
		elog "Please be aware that you need to re-login to your"
		elog "system for the group membership to take effect."
		elog
	}
}



-- 
gentoo-commits@g.o mailing list