Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Paul Varner (fuzzyray)" <fuzzyray@g.o>
Subject: gentoo-x86 commit in app-portage/gentoolkit: ChangeLog gentoolkit-0.3.0.6-r3.ebuild
Date: Wed, 20 Jun 2012 20:09:15 +0000 (UTC)
fuzzyray    12/06/20 20:09:15

  Modified:             ChangeLog
  Added:                gentoolkit-0.3.0.6-r3.ebuild
  Log:
  Revision bump to add patch for euse to support the md5-dict metadata cache
  format.
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.266                app-portage/gentoolkit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.266&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.266&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/ChangeLog?r1=1.265&r2=1.266

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v
retrieving revision 1.265
retrieving revision 1.266
diff -u -r1.265 -r1.266
--- ChangeLog	28 May 2012 13:49:53 -0000	1.265
+++ ChangeLog	20 Jun 2012 20:09:15 -0000	1.266
@@ -1,6 +1,13 @@
 # ChangeLog for app-portage/gentoolkit
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.265 2012/05/28 13:49:53 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.266 2012/06/20 20:09:15 fuzzyray Exp $
+
+*gentoolkit-0.3.0.6-r3 (20 Jun 2012)
+
+  20 Jun 2012; Paul Varner <fuzzyray@g.o> +gentoolkit-0.3.0.6-r3.ebuild,
+  +files/0.3.0.6-euse-422675.patch:
+  Revision bump to add patch for euse to support the md5-dict metadata cache
+  format.
 
   28 May 2012; Raúl Porcel <armin76@g.o> gentoolkit-0.3.0.5.ebuild:
   alpha/ia64/m68k/s390/sh/sparc stable wrt #411479



1.1                  app-portage/gentoolkit/gentoolkit-0.3.0.6-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0.6-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0.6-r3.ebuild?rev=1.1&content-type=text/plain

Index: gentoolkit-0.3.0.6-r3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0.6-r3.ebuild,v 1.1 2012/06/20 20:09:15 fuzzyray Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.[45]"
PYTHON_USE_WITH="xml"
PYTHON_NONVERSIONED_EXECUTABLES=(".*")

inherit distutils python eutils

DESCRIPTION="Collection of administration scripts for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
SRC_URI="mirror://gentoo/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE=""

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"

# Note: argparse is provided in python 2.7 and 3.2 (Bug 346005)
# Note: dev-lang/python dependencies are so emerge will print a blocker if any
# installed slot of python is not built with +xml.  This is used since
# PYTHON_USE_WITH just dies in the middle of the emerge. See bug 399331.
DEPEND="sys-apps/portage"
RDEPEND="${DEPEND}
	>=dev-lang/python-2.6[xml]
	!>=dev-lang/python-2.6[-xml]
	!<=app-portage/gentoolkit-dev-0.2.7
	dev-python/argparse
	|| ( >=sys-apps/coreutils-8.15 app-misc/realpath sys-freebsd/freebsd-bin )
	sys-apps/gawk
	sys-apps/grep"

distutils_src_compile_pre_hook() {
	echo VERSION="${PVR}" "$(PYTHON)" setup.py set_version
	VERSION="${PVR}" "$(PYTHON)" setup.py set_version \
		|| die "setup.py set_version failed"
}

src_prepare() {
	epatch "${FILESDIR}/${PV}-eread-413577.patch"
	epatch "${FILESDIR}/${PV}-eshowkw-414627.patch"
	epatch "${FILESDIR}/${PV}-gentoolkit-304125.patch"
	epatch "${FILESDIR}/${PV}-euse-410365.patch"
	epatch "${FILESDIR}/${PV}-eshowkw-409449.patch"
	epatch "${FILESDIR}/${PV}-euse-422675.patch"
}

src_install() {
	python_convert_shebangs -r "" build-*/scripts-*
	distutils_src_install

	# Rename the python versions of revdep-rebuild, since we are not ready
	# to switch to the python version yet. Link /usr/bin/revdep-rebuild to
	# revdep-rebuild.sh. Leaving the python version available for potential
	# testing by a wider audience.
	mv "${ED}"/usr/bin/revdep-rebuild "${ED}"/usr/bin/revdep-rebuild.py
	dosym revdep-rebuild.sh /usr/bin/revdep-rebuild

	# Create cache directory for revdep-rebuild
	dodir /var/cache/revdep-rebuild
	keepdir /var/cache/revdep-rebuild
	use prefix || fowners root:root /var/cache/revdep-rebuild
	fperms 0700 /var/cache/revdep-rebuild

	# remove on Gentoo Prefix platforms where it's broken anyway
	if use prefix; then
		elog "The revdep-rebuild command is removed, the preserve-libs"
		elog "feature of portage will handle issues."
		rm "${ED}"/usr/bin/revdep-rebuild
		rm "${ED}"/usr/bin/revdep-rebuild.py
		rm "${ED}"/usr/share/man/man1/revdep-rebuild.1
		rm -rf "${ED}"/etc/revdep-rebuild
		rm -rf "${ED}"/var
	fi

	# Can distutils handle this?
	dosym eclean /usr/bin/eclean-dist
	dosym eclean /usr/bin/eclean-pkg
}

pkg_postinst() {
	distutils_pkg_postinst

	einfo
	einfo "For further information on gentoolkit, please read the gentoolkit"
	einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
	einfo
	einfo "Another alternative to equery is app-portage/portage-utils"
	ewarn
	ewarn "glsa-check since gentoolkit 0.3 has modified some output,"
	ewarn "options and default behavior. The list of injected GLSAs"
	ewarn "has moved to /var/lib/portage/glsa_injected, please"
	ewarn "run 'glsa-check -p affected' before copying the existing checkfile."
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in app-portage/gentoolkit/files: 0.3.0.6-euse-422675.patch
Next by thread:
gentoo-x86 commit in net-analyzer/zabbix/files/1.6.6: zabbix_trapper.conf zabbix_proxy.conf zabbix_server.conf
Previous by date:
gentoo-x86 commit in app-portage/gentoolkit/files: 0.3.0.6-euse-422675.patch
Next by date:
gentoo-x86 commit in media-libs/libdvbpsi: libdvbpsi-0.2.2.ebuild ChangeLog


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.