[gentoo-commits] gentoo-x86 commit in media-sound/vkeybd: ChangeLog vkeybd-0.1.18c.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/07/16 16:26:08

  Modified:             ChangeLog
  Added:                vkeybd-0.1.18c.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.36                 media-sound/vkeybd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/vkeybd/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/vkeybd/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/vkeybd/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/vkeybd/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	16 Jul 2009 08:58:25 -0000	1.35
+++ ChangeLog	16 Jul 2009 16:26:08 -0000	1.36
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/vkeybd
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/vkeybd/ChangeLog,v 1.35 2009/07/16 08:58:25 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/vkeybd/ChangeLog,v 1.36 2009/07/16 16:26:08 ssuominen Exp $
+
+*vkeybd-0.1.18c (16 Jul 2009)
+
+  16 Jul 2009; Samuli Suominen <ssuominen@g.o>
+  +vkeybd-0.1.18c.ebuild, +files/vkeybd-0.1.18c-desktop_entry.patch:
+  Version bump.
 
   16 Jul 2009; Samuli Suominen <ssuominen@g.o>
   vkeybd-0.1.17b-r1.ebuild:



1.1                  media-sound/vkeybd/vkeybd-0.1.18c.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/vkeybd/vkeybd-0.1.18c.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/vkeybd/vkeybd-0.1.18c.ebuild?rev=1.1&content-type=text/plain

Index: vkeybd-0.1.18c.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/vkeybd/vkeybd-0.1.18c.ebuild,v 1.1 2009/07/16 16:26:08 ssuominen Exp $

EAPI=2
inherit eutils toolchain-funcs

DESCRIPTION="A virtual MIDI keyboard for X"
HOMEPAGE="http://www.alsa-project.org/~iwai/alsa.html"
SRC_URI="http://ftp.suse.com/pub/people/tiwai/vkeybd/vkeybd-0.1.18c.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="alsa lash oss"

RDEPEND="alsa? ( media-libs/alsa-lib )
	>=dev-lang/tk-8.3
	lash? ( media-sound/lash )
	x11-libs/libX11"
DEPEND="${RDEPEND}
	x11-proto/xf86bigfontproto
	x11-proto/bigreqsproto
	x11-proto/xextproto
	x11-proto/xcmiscproto"

S=${WORKDIR}/${PN}

pkg_setup() {
	TCL_VERSION=`echo 'puts [info tclversion]' | tclsh`

	vkeybconf="PREFIX=/usr"

	if use alsa; then
		vkeybconf+=" USE_ALSA=1"
		use oss || vkeybconf+=" USE_AWE=0 USE_MIDI=0"
	else
		vkeybconf+=" USE_ALSA=0 USE_AWE=1 USE_MIDI=1"
	fi

	use lash && vkeybconf+=" USE_LASH=1"

	vkeybconf+=" TCL_VERSION=${TCL_VERSION}"
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-desktop_entry.patch
}

src_compile() {
	tc-export CC
	emake ${vkeybconf} COPTFLAGS="${CFLAGS}" || die "emake failed"
}

src_install() {
	emake ${vkeybconf} DESTDIR="${D}" \
		install-all || die "emake install failed"
	dodoc ChangeLog README
}