[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-screensaver: ChangeLog gnome-screensaver-2.20.0.ebuild

[Saleem Abdulrasool (compnerd)]

compnerd    07/10/02 06:36:14

  Modified:             ChangeLog
  Added:                gnome-screensaver-2.20.0.ebuild
  Log:
  version bump for 2.20
  (Portage version: 2.1.3.11)

Revision  Changes    Path
1.53                 gnome-extra/gnome-screensaver/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-screensaver/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-screensaver/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-screensaver/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-screensaver/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	22 Sep 2007 08:57:02 -0000	1.52
+++ ChangeLog	2 Oct 2007 06:36:13 -0000	1.53
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gnome-screensaver
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-screensaver/ChangeLog,v 1.52 2007/09/22 08:57:02 tgall Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-screensaver/ChangeLog,v 1.53 2007/10/02 06:36:13 compnerd Exp $
+
+*gnome-screensaver-2.20.0 (02 Oct 2007)
+
+  02 Oct 2007; Saleem Abdulrasool <compnerd@g.o>
+  +gnome-screensaver-2.20.0.ebuild:
+  version bump for 2.20
 
   22 Sep 2007; Tom Gall <tgall@g.o>
   gnome-screensaver-2.18.2-r1.ebuild:



1.1                  gnome-extra/gnome-screensaver/gnome-screensaver-2.20.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-screensaver/gnome-screensaver-2.20.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-screensaver/gnome-screensaver-2.20.0.ebuild?rev=1.1&content-type=text/plain

Index: gnome-screensaver-2.20.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-screensaver/gnome-screensaver-2.20.0.ebuild,v 1.1 2007/10/02 06:36:13 compnerd Exp $

inherit gnome2

DESCRIPTION="Replaces xscreensaver, integrating with the desktop."
HOMEPAGE="http://live.gnome.org/GnomeScreensaver"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
KERNEL_IUSE="kernel_linux"
IUSE="debug doc libnotify opengl pam xinerama $KERNEL_IUSE"

RDEPEND=">=gnome-base/gconf-2.6.1
	>=x11-libs/gtk+-2.11.5
	>=gnome-base/gnome-vfs-2.12
	>=gnome-base/libglade-2.5.0
	>=gnome-base/gnome-menus-2.12
	>=dev-libs/glib-2.8
	>=gnome-base/libgnomekbd-0.1
	||	(
			>=dev-libs/dbus-glib-0.71
			~sys-apps/dbus-0.62
		)
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXrandr
	x11-libs/libXScrnSaver
	libnotify? ( x11-libs/libnotify )
	opengl?	( virtual/opengl )
	pam? ( virtual/pam )
	!pam? ( kernel_linux? ( sys-apps/shadow ) )
	xinerama?	(
					x11-libs/libXinerama
					x11-proto/xineramaproto
				)"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35
	doc?	(
				app-text/xmlto
				~app-text/docbook-xml-dtd-4.1.2
				~app-text/docbook-xml-dtd-4.4
			)
	x11-proto/xextproto
	x11-proto/randrproto
	x11-proto/scrnsaverproto
	x11-proto/xf86miscproto"

DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF} \
		$(use_enable doc docbook-docs) \
		$(use_enable debug) \
		$(use_with libnotify) \
		$(use_with opengl libgl) \
		$(use_enable pam) \
		$(use_enable xinerama) \
		--enable-locking \
		--with-kbd-layout-indicator \
		--with-gdm-config=/usr/share/gdm/defaults.conf \
		--with-xscreensaverdir=/usr/share/xscreensaver/config \
		--with-xscreensaverhackdir=/usr/lib/misc/xscreensaver"
}

src_install() {
	gnome2_src_install

	# Install the conversion script in the documentation
	dodoc "${S}/data/migrate-xscreensaver-config.sh"
	dodoc "${S}/data/xscreensaver-config.xsl"

	# Conversion information
	sed -e "s:\${PF}:${PF}:" \
		< "${FILESDIR}/xss-conversion.txt" > "${S}/xss-conversion.txt"

	dodoc "${S}/xss-conversion.txt"

	# Non PAM users will need this suid to read the password hashes.
	# OpenPAM users will probably need this too when
	# http://bugzilla.gnome.org/show_bug.cgi?id=370847
	# is fixed.
	if ! use pam ; then
		fperms u+s /usr/libexec/gnome-screensaver-dialog
	fi
}

pkg_postinst() {
	gnome2_pkg_postinst

	ewarn "If you have xscreensaver installed, you probably want to disable it."
	ewarn "To prevent a duplicate Screensaver entry in the menu, you need to"
	ewarn "build xscreensaver with -gnome in the USE flags."
	ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
	echo
	elog "Information for converting screensavers is located in "
	elog "/usr/share/doc/${PF}/xss-conversion.txt.${PORTAGE_COMPRESS}"
}



-- 
gentoo-commits@g.o mailing list