Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Pacho Ramos (pacho)" <pacho@g.o>
Subject: gentoo-x86 commit in gnome-base/nautilus: ChangeLog nautilus-2.28.4-r1.ebuild
Date: Tue, 30 Mar 2010 10:00:20 +0000
pacho       10/03/30 10:00:20

  Modified:             ChangeLog
  Added:                nautilus-2.28.4-r1.ebuild
  Log:
  Revision bump to drop tracker support, being able to stabilize this sooner.
  (Portage version: 2.1.7.17/cvs/Linux x86_64)

Revision  Changes    Path
1.339                gnome-base/nautilus/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/nautilus/ChangeLog?rev=1.339&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/nautilus/ChangeLog?rev=1.339&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/nautilus/ChangeLog?r1=1.338&r2=1.339

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v
retrieving revision 1.338
retrieving revision 1.339
diff -u -r1.338 -r1.339
--- ChangeLog	16 Mar 2010 18:43:03 -0000	1.338
+++ ChangeLog	30 Mar 2010 10:00:20 -0000	1.339
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/nautilus
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.338 2010/03/16 18:43:03 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.339 2010/03/30 10:00:20 pacho Exp $
+
+*nautilus-2.28.4-r1 (30 Mar 2010)
+
+  30 Mar 2010; Pacho Ramos <pacho@g.o> +nautilus-2.28.4-r1.ebuild:
+  Revision bump to drop tracker support and being able to safely stabilize
+  this without requiring tracker stabilization too.
 
   16 Mar 2010; Christian Faulhammer <fauli@g.o>
   nautilus-2.26.4-r1.ebuild:



1.1                  gnome-base/nautilus/nautilus-2.28.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/nautilus/nautilus-2.28.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/nautilus/nautilus-2.28.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: nautilus-2.28.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-2.28.4-r1.ebuild,v 1.1 2010/03/30 10:00:20 pacho Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit eutils gnome2 virtualx

DESCRIPTION="A file manager for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/projects/nautilus/"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~sh ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux"
IUSE="beagle doc gnome xmp"

# not adding gnome-base/gail because it is in >=gtk+-2.13
RDEPEND=">=dev-libs/glib-2.21.3
	>=gnome-base/gnome-desktop-2.25.5
	>=x11-libs/pango-1.1.2
	>=x11-libs/gtk+-2.16.0
	>=dev-libs/libxml2-2.4.7
	>=media-libs/libexif-0.5.12
	>=gnome-base/gconf-2.0
	dev-libs/libunique
	dev-libs/dbus-glib
	x11-libs/libXft
	x11-libs/libXrender
	beagle? ( || (
		dev-libs/libbeagle
		=app-misc/beagle-0.2* ) )
	xmp? ( >=media-libs/exempi-2 )"

DEPEND="${RDEPEND}
	>=dev-lang/perl-5
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40.1
	doc? ( >=dev-util/gtk-doc-1.4 )"
# For eautoreconf
#	gnome-base/gnome-common
#	dev-util/gtk-doc-am"

PDEPEND="gnome? ( >=x11-themes/gnome-icon-theme-1.1.91 )
	>=gnome-base/gvfs-0.1.2"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README THANKS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-update-mimedb
		--disable-packagekit
		--disable-tracker
		$(use_enable beagle)
		$(use_enable xmp)"
}

src_prepare() {
	gnome2_src_prepare

	# FIXME: tarball generated with broken gtk-doc, revisit me.
	if use doc; then
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
			-i gtk-doc.make || die "sed 1 failed"
	else
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/bin/true" \
			-i gtk-doc.make || die "sed 2 failed"
	fi

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed 3 failed"

	# Remove crazy CFLAGS
	sed 's:-DG.*DISABLE_DEPRECATED::g' -i configure.in configure \
		|| die "sed 4 failed"

	# Fix nautilus flipping-out with --no-desktop -- bug 266398
	epatch "${FILESDIR}/${PN}-2.27.4-change-reg-desktop-file-with-no-desktop.patch"
}

src_test() {
	addwrite "/root/.gnome2_private"
	unset SESSION_MANAGER
	unset ORBIT_SOCKETDIR
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "Test phase failed"
}

src_install() {
	gnome2_src_install
	find "${D}" -name "*.la" -delete || die "remove of la files failed"
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "nautilus can use gstreamer to preview audio files. Just make sure"
	elog "to have the necessary plugins available to play the media type you"
	elog "want to preview"
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in dev-vcs/bzr-rewrite: ChangeLog bzr-rewrite-0.6.0.ebuild
Next by thread:
gentoo-x86 commit in gnome-base/nautilus: ChangeLog nautilus-2.28.4-r1.ebuild
Previous by date:
gentoo-x86 commit in dev-vcs/bzr-rewrite: ChangeLog bzr-rewrite-0.6.0.ebuild
Next by date:
gentoo-x86 commit in sci-chemistry/ccpn: ChangeLog ccpn-2.1.3.1_p100330.ebuild


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.