Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Tiziano Mueller (dev-zero)" <dev-zero@g.o>
Subject: gentoo-x86 commit in net-misc/aria2: aria2-1.4.1.ebuild ChangeLog aria2-1.3.0.ebuild aria2-1.2.0.ebuild aria2-1.3.2.ebuild
Date: Fri, 17 Jul 2009 10:55:29 +0000
dev-zero    09/07/17 10:55:29

  Modified:             ChangeLog
  Added:                aria2-1.4.1.ebuild
  Removed:              aria2-1.3.0.ebuild aria2-1.2.0.ebuild
                        aria2-1.3.2.ebuild
  Log:
  Version bump (bug #277753, also corrected bug #270175). Dropped old.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 net-misc/aria2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	10 May 2009 15:23:14 -0000	1.42
+++ ChangeLog	17 Jul 2009 10:55:29 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/aria2
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.42 2009/05/10 15:23:14 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.43 2009/07/17 10:55:29 dev-zero Exp $
+
+*aria2-1.4.1 (17 Jul 2009)
+
+  17 Jul 2009; Tiziano Müller <dev-zero@g.o> -aria2-1.2.0.ebuild,
+  -aria2-1.3.0.ebuild, -aria2-1.3.2.ebuild, +aria2-1.4.1.ebuild:
+  Version bump (bug #277753, also corrected bug #270175). Dropped old.
 
 *aria2-1.3.3 (10 May 2009)
 



1.1                  net-misc/aria2/aria2-1.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/aria2-1.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/aria2-1.4.1.ebuild?rev=1.1&content-type=text/plain

Index: aria2-1.4.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/aria2-1.4.1.ebuild,v 1.1 2009/07/17 10:55:29 dev-zero Exp $

EAPI="2"

DESCRIPTION="A download utility with resuming and segmented downloading with HTTP/HTTPS/FTP/BitTorrent support."
HOMEPAGE="http://aria2.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
IUSE="ares bittorrent expat gnutls metalink nls sqlite ssl test"

CDEPEND="sys-libs/zlib
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.9 )
		!gnutls? ( dev-libs/openssl ) )
	ares? ( >=net-dns/c-ares-1.5.0 )
	bittorrent? (
		gnutls? ( >=net-libs/gnutls-1.2.9 >=dev-libs/libgcrypt-1.2.2 )
		!gnutls? ( dev-libs/openssl ) )
	metalink? (
		!expat? ( >=dev-libs/libxml2-2.6.26 )
		expat? ( dev-libs/expat )
	)
	sqlite? ( dev-db/sqlite:3 )"
DEPEND="${CDEPEND}
	nls? ( sys-devel/gettext )
	test? ( >=dev-util/cppunit-1.12.0 )"
RDEPEND="${CDEPEND}
	nls? ( virtual/libiconv virtual/libintl )"

src_prepare() {
	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
}

src_configure() {
	local myconf="--without-gnutls --without-openssl"
	use ssl && \
		myconf="$(use_with gnutls) $(use_with !gnutls openssl)"

	# Note:
	# - depends on libgcrypt only when using gnutls
	# - links only against libxml2 and libexpat when metalink is enabled
	# - always enable gzip/http compression since zlib should always be available anyway
	# - always enable epoll since we can assume kernel 2.6.x
	# - other options for threads: solaris, pth, win32
	econf \
		--enable-epoll \
		--enable-threads=posix \
		--with-libz \
		$(use_enable nls) \
		$(use_enable metalink) \
		$(use_with expat libexpat) \
		$(use_with !expat libxml2) \
		$(use_with sqlite sqlite3) \
		$(use_enable bittorrent) \
		$(use_with ares libcares) \
		${myconf} \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	rm -rf "${D}/usr/share/doc/aria2"
	dodoc ChangeLog README AUTHORS NEWS
	dohtml README.html doc/aria2c.1.html
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in media-libs/libcanberra/files: libcanberra-0.14-backward-compatibility-libtool.patch
Next by thread:
gentoo-x86 commit in media-sound/kid3: kid3-1.2-r2.ebuild
Previous by date:
gentoo-x86 commit in media-libs/libcanberra/files: libcanberra-0.14-backward-compatibility-libtool.patch
Next by date:
gentoo-x86 commit in profiles: use.local.desc


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.