[gentoo-commits] gentoo-x86 commit in net-voip/gnugk: ChangeLog gnugk-2.2.7.ebuild

[Jeremy Olexa (darkside)]

darkside    09/02/12 04:47:00

  Modified:             ChangeLog
  Added:                gnugk-2.2.7.ebuild
  Log:
  version bump by Mounir Lamouri, bug 251571
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  net-voip/gnugk/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/gnugk/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/gnugk/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/gnugk/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/gnugk/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	16 Aug 2008 16:22:29 -0000	1.5
+++ ChangeLog	12 Feb 2009 04:47:00 -0000	1.6
@@ -1,6 +1,11 @@
 # ChangeLog for net-voip/gnugk
-# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/gnugk/ChangeLog,v 1.5 2008/08/16 16:22:29 tove Exp $
+# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-voip/gnugk/ChangeLog,v 1.6 2009/02/12 04:47:00 darkside Exp $
+
+*gnugk-2.2.7 (12 Feb 2009)
+
+  12 Feb 2009; Jeremy Olexa <darkside@g.o> +gnugk-2.2.7.ebuild:
+  version bump by Mounir Lamouri, bug 251571
 
   16 Aug 2008; Torsten Veller <tove@g.o> metadata.xml:
   Remove stkn from metadata.xml (#27693)



1.1                  net-voip/gnugk/gnugk-2.2.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/gnugk/gnugk-2.2.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/gnugk/gnugk-2.2.7.ebuild?rev=1.1&content-type=text/plain

Index: gnugk-2.2.7.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/gnugk/gnugk-2.2.7.ebuild,v 1.1 2009/02/12 04:47:00 darkside Exp $

EAPI="2"

inherit eutils

DESCRIPTION="GNU H.323 gatekeeper"
HOMEPAGE="http://www.gnugk.org/"
SRC_URI="mirror://sourceforge/openh323gk/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
# dev-db/firebird isn't keyworded for ppc but firebird IUSE is masked for ppc
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc firebird mysql postgres radius linguas_en linguas_es linguas_fr"

# TODO: when h323plus will be in portage tree, add it as || dep with openh323
RDEPEND=">=dev-libs/pwlib-1.7.5.2
	>=net-libs/openh323-1.14.2
	dev-libs/openssl
	firebird? ( dev-db/firebird )
	mysql? ( virtual/mysql )
	postgres? ( virtual/postgresql-base )"
DEPEND="${RDEPEND}
	doc? ( app-text/linuxdoc-tools )"

pkg_setup() {
	if use doc && ! use linguas_en && ! use linguas_es && ! use linguas_fr; then
		elog "No linguas specified."
		elog "English documentation will be installed."
	fi
}

src_prepare() {
	if use firebird; then
		# fix build with firebird 2.1
		epatch "${FILESDIR}"/${P}-firebird-2.1.patch

		# build sqlauth and sqlacc when firebird is supported
		epatch "${FILESDIR}"/${P}-configure.patch
	fi
}

src_configure() {
	# --with-large-fdset=4096 is added because of bug #128102
	# and it is recommanded in the online manual
	econf \
		$(use_enable firebird) \
		$(use_enable mysql) \
		$(use_enable postgres pgsql) \
		$(use_enable radius) \
		--with-large-fdset=4096
}

src_compile() {
	# PASN_NOPRINT should be set for -debug but it's buggy
	# better to prevent issues and keep default settings
	# `make debugdepend debugshared` and `make debug` failed (so no debug)
	# `make optdepend optnoshared` also failed (so no static)

	# fails with -j2
	emake -j1 optdepend optshared || die "emake failed"

	# build tool addpasswd
	emake addpasswd || die "emake addpasswd failed"

	if use doc; then
		cd docs/manual

		if use linguas_en || ( ! use linguas_es && ! use linguas_fr ); then
			emake html || die "emake en doc failed"
		fi

		if use linguas_es; then
			emake html-es || die "emake es doc failed"
		fi

		if use linguas_fr; then
			emake html-fr || die "emake fr doc failed"
		fi
		cd ../..
	fi
}

src_install() {
	dosbin obj_*_*_*/${PN} || die "dosbin failed"
	dosbin obj_*_*_*/addpasswd || die "dosbin failed"

	dodir /etc/${PN}
	insinto /etc/${PN}
	doins etc/* || die "doins etc/* failed"

	dodoc changes.txt readme.txt || die "dodoc failed"

	if use doc; then
		dodoc docs/*.txt docs/*.pdf || die "dodoc failed"

		if use linguas_en || ( ! use linguas_es && ! use linguas_fr ); then
			dohtml docs/manual/manual*.html || die "dohtml failed"
		fi
		if use linguas_fr; then
			dohtml docs/manual/fr/manual-fr*.html || die "dohtml failed"
		fi
		if use linguas_es; then
			dohtml docs/manual/es/manual-es*.html || die "dohtml failed"
		fi
	fi

	doman docs/${PN}.1 || die "doman failed"

	newinitd "${FILESDIR}"/${PN}.rc6 ${PN}
	newconfd "${FILESDIR}"/${PN}.confd ${PN}
}