robbat2     09/11/04 02:20:50

  Modified:             ChangeLog
  Added:                mogilefs-server-2.32.ebuild
  Log:
  Version bump, now with official Postgres support.
  (Portage version: 2.2_rc48/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  dev-perl/mogilefs-server/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-perl/mogilefs-server/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-perl/mogilefs-server/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-perl/mogilefs-server/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-perl/mogilefs-server/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -p -w -b -B -u -u -r1.7 -r1.8
--- ChangeLog	23 Feb 2009 09:59:21 -0000	1.7
+++ ChangeLog	4 Nov 2009 02:20:50 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for dev-perl/mogilefs-server
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-perl/mogilefs-server/ChangeLog,v 1.7 2009/02/23 09:59:21 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-perl/mogilefs-server/ChangeLog,v 1.8 2009/11/04 02:20:50 robbat2 Exp $
+
+*mogilefs-server-2.32 (04 Nov 2009)
+
+  04 Nov 2009; Robin H. Johnson <robbat2@g.o>
+  +mogilefs-server-2.32.ebuild:
+  Version bump, now with official Postgres support.
 
 *mogilefs-server-2.30 (23 Feb 2009)
 



1.1                  dev-perl/mogilefs-server/mogilefs-server-2.32.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-perl/mogilefs-server/mogilefs-server-2.32.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-perl/mogilefs-server/mogilefs-server-2.32.ebuild?rev=1.1&content-type=text/plain

Index: mogilefs-server-2.32.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-perl/mogilefs-server/mogilefs-server-2.32.ebuild,v 1.1 2009/11/04 02:20:50 robbat2 Exp $

EAPI=2
MODULE_AUTHOR="DORMANDO"
inherit perl-module

DESCRIPTION="Server for the MogileFS distributed file system"
HOMEPAGE="http://www.danga.com/mogilefs/"

IUSE="mysql sqlite postgres"

SLOT="0"
LICENSE="|| ( Artistic GPL-2 )"
KEYWORDS="~amd64 ~ppc ~x86"

# Upstream site recommends this,
# but it breaks Perlbal
# dev-perl/Perlbal-XS-HTTPHeaders
DEPEND="dev-perl/Net-Netmask
		>=dev-perl/Danga-Socket-1.61
		>=dev-perl/Sys-Syscall-0.22
		>=dev-perl/Perlbal-1.73
		dev-perl/IO-AIO
		>=dev-perl/Gearman-Server-1.09
		dev-perl/Gearman-Client-Async
		dev-perl/libwww-perl
		>=dev-perl/MogileFS-Client-1.09
		dev-perl/Cache-Memcached
		mysql? ( dev-perl/DBD-mysql )
		postgres? ( dev-perl/DBD-Pg )
		sqlite? ( dev-perl/DBD-SQLite )"
mydoc="CHANGES TODO"

# You need a local MySQL or Postgresql server for this
#SRC_TEST="do"

#PATCHES=(  )

MOGILE_USER="mogile"

pkg_setup() {
	# Warning! It is important that the uid is constant over Gentoo machines
	# As mogilefs may be used with non-local block devices that move!
	enewuser ${MOGILE_USER} 460 -1 -1
}

src_prepare() {
	# If we are not in a cutting edge Git source, we would prefer to not install
	# duplicates of these.
	#sed -i -e '/directory.*mogdeps/d' "${S}"/Makefile.PL
	mv -f "${S}/lib/mogdeps" "${S}"
}

src_compile() {
	export MOGILE_NO_BUILTIN_DEPS=1
	perl-module_src_compile || die "perl-module_src_compile failed"
}

src_install() {
	export MOGILE_NO_BUILTIN_DEPS=1
	perl-module_src_install || die "perl-module_src_install failed"
	cd "${S}"

	newconfd "${FILESDIR}"/mogilefsd-conf.d-2.16 mogilefsd
	newinitd "${FILESDIR}"/mogilefsd-init.d-2.16 mogilefsd

	newconfd "${FILESDIR}"/mogstored-conf.d-2.30 mogstored
	newinitd "${FILESDIR}"/mogstored-init.d-2.30 mogstored

	diropts -m 700 -o ${MOGILE_USER}
	keepdir /var/run/mogile
	keepdir /var/mogdata
	keepdir /mnt/mogilefs
	diropts -m 755 -o root

	dodir /etc/mogilefs
	insinto /etc/mogilefs
	insopts -m 600 -o root -g ${MOGILE_USER}
	newins "${FILESDIR}"/mogilefsd.conf-2.30 mogilefsd.conf
	newins "${FILESDIR}"/mogstored.conf-2.16 mogstored.conf
}

pkg_postinst() {
	chmod 640 "${ROOT}"/etc/mogilefs/{mogilefsd,mogstored}.conf
	chown root:${MOGILE_USER} "${ROOT}"/etc/mogilefs/{mogilefsd,mogstored}.conf
}