[gentoo-commits] gentoo-x86 commit in media-video/x264-encoder: ChangeLog x264-encoder-0.0.20090502.ebuild

[Alexis Ballier (aballier)]

aballier    09/05/03 20:09:15

  Modified:             ChangeLog
  Added:                x264-encoder-0.0.20090502.ebuild
  Log:
  bump a new snapshot
  (Portage version: 2.2_rc32/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 media-video/x264-encoder/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/x264-encoder/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/x264-encoder/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/x264-encoder/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	27 Apr 2009 23:58:54 -0000	1.18
+++ ChangeLog	3 May 2009 20:09:15 -0000	1.19
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/x264-encoder
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.18 2009/04/27 23:58:54 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.19 2009/05/03 20:09:15 aballier Exp $
+
+*x264-encoder-0.0.20090502 (03 May 2009)
+
+  03 May 2009; Alexis Ballier <aballier@g.o>
+  +x264-encoder-0.0.20090502.ebuild,
+  +files/x264-encoder-nolib-20090408.patch:
+  bump a new snapshot
 
   27 Apr 2009; Patrick Lauer <patrick@g.o> x264-encoder-0.0.20081218:
   Bumping yasm dep to >=0.6.1, closes #267711



1.1                  media-video/x264-encoder/x264-encoder-0.0.20090502.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20090502.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20090502.ebuild?rev=1.1&content-type=text/plain

Index: x264-encoder-0.0.20090502.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-0.0.20090502.ebuild,v 1.1 2009/05/03 20:09:15 aballier Exp $

EAPI="1"
inherit multilib eutils toolchain-funcs versionator

MY_P="x264-snapshot-$(get_version_component_range 3)-2245"

DESCRIPTION="A free commandline encoder for X264/AVC streams"
HOMEPAGE="http://www.videolan.org/developers/x264.html"
SRC_URI="ftp://ftp.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug +mp4 +threads"

RDEPEND="mp4? ( >=media-video/gpac-0.4.1_pre20060122 )
	~media-libs/x264-${PV}"

DEPEND="${RDEPEND}
	amd64? ( >=dev-lang/yasm-0.6.1 )
	x86? ( || ( >=dev-lang/yasm-0.6.2 dev-lang/nasm ) )
	x86-fbsd? ( >=dev-lang/yasm-0.6.2 )
	dev-util/pkgconfig"

# Block older than 0.6.2 versions of yasm
# It generates incorect pic code and will cause segfaults
# See http://www.tortall.net/projects/yasm/ticket/114
DEPEND="${DEPEND}
	x86? ( !<dev-lang/yasm-0.6.2 )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-nostrip.patch"
	epatch "${FILESDIR}/${PN}-nolib-20090408.patch"
}

src_compile() {
	local myconf=""
	use debug && myconf="${myconf} --enable-debug"
	./configure --prefix=/usr \
		--libdir=/usr/$(get_libdir) \
		--enable-pic --enable-shared \
		"--extra-cflags=${CFLAGS}" \
		"--extra-ldflags=${LDFLAGS}" \
		"--extra-asflags=${ASFLAGS}" \
		"--host=${CHOST}" \
		${myconf} \
		$(use_enable threads pthread) \
		$(use_enable mp4 mp4-output) \
		|| die "configure failed"
	emake CC="$(tc-getCC)" || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS doc/*.txt
}