[gentoo-commits] gentoo-x86 commit in x11-libs/libnotify: ChangeLog libnotify-0.7.5.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/03/31 08:41:23

  Modified:             ChangeLog
  Added:                libnotify-0.7.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

Revision  Changes    Path
1.80                 x11-libs/libnotify/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libnotify/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libnotify/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libnotify/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	23 Jan 2012 01:50:33 -0000	1.79
+++ ChangeLog	31 Mar 2012 08:41:23 -0000	1.80
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/libnotify
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v 1.79 2012/01/23 01:50:33 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v 1.80 2012/03/31 08:41:23 ssuominen Exp $
+
+*libnotify-0.7.5 (31 Mar 2012)
+
+  31 Mar 2012; Samuli Suominen <ssuominen@g.o> +libnotify-0.7.5.ebuild:
+  Version bump.
 
 *libnotify-0.7.4-r1 (23 Jan 2012)
 



1.1                  x11-libs/libnotify/libnotify-0.7.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libnotify/libnotify-0.7.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libnotify/libnotify-0.7.5.ebuild?rev=1.1&content-type=text/plain

Index: libnotify-0.7.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.5.ebuild,v 1.1 2012/03/31 08:41:23 ssuominen Exp $

EAPI=4
inherit autotools gnome.org

DESCRIPTION="A library for sending desktop notifications"
HOMEPAGE="http://git.gnome.org/browse/libnotify"
SRC_URI="${SRC_URI}
	mirror://gentoo/introspection-20110205.m4.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
IUSE="doc +introspection +symlink test"

RDEPEND=">=dev-libs/glib-2.26
	x11-libs/gdk-pixbuf:2
	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.14 )
	symlink? ( !x11-misc/tinynotify-send[symlink] )
	test? ( x11-libs/gtk+:3 )"
PDEPEND="virtual/notification-daemon"

DOCS=( AUTHORS ChangeLog NEWS )

src_prepare() {
	sed -i -e 's:noinst_PROG:check_PROG:' tests/Makefile.am || die

	if ! use test; then
		sed -i -e '/PKG_CHECK_MODULES(TESTS/d' configure.ac || die
	fi

	if has_version 'dev-libs/gobject-introspection'; then
		eautoreconf
	else
		AT_M4DIR=${WORKDIR} eautoreconf
	fi
}

src_configure() {
	econf \
		--disable-static \
		$(use_enable introspection)
}

src_install() {
	default
	rm -f "${ED}"usr/lib*/${PN}.la

	mv -vf "${ED}"usr/bin/{,${PN}-}notify-send #379941
	use symlink && dosym ${PN}-notify-send /usr/bin/notify-send
}