[gentoo-commits] gentoo-x86 commit in x11-wm/windowmaker: ChangeLog windowmaker-0.92.0-r7.ebuild windowmaker-0.92.0-r6.ebuild

[Harald van Dijk (truedfx)]

truedfx     07/11/22 22:10:00

  Modified:             ChangeLog
  Added:                windowmaker-0.92.0-r7.ebuild
  Removed:              windowmaker-0.92.0-r6.ebuild
  Log:
  Get rid of gettextlib, so that fontconfig works (#199414)
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.92                 x11-wm/windowmaker/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/windowmaker/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/windowmaker/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/windowmaker/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/windowmaker/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	21 Nov 2007 19:54:40 -0000	1.91
+++ ChangeLog	22 Nov 2007 22:09:59 -0000	1.92
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/windowmaker
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/windowmaker/ChangeLog,v 1.91 2007/11/21 19:54:40 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/windowmaker/ChangeLog,v 1.92 2007/11/22 22:09:59 truedfx Exp $
+
+*windowmaker-0.92.0-r7 (22 Nov 2007)
+
+  22 Nov 2007; Harald van Dijk <truedfx@g.o>
+  -windowmaker-0.92.0-r6.ebuild, +windowmaker-0.92.0-r7.ebuild:
+  Get rid of gettextlib, so that fontconfig works (#199414)
 
 *windowmaker-0.92.0-r6 (21 Nov 2007)
 



1.1                  x11-wm/windowmaker/windowmaker-0.92.0-r7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/windowmaker/windowmaker-0.92.0-r7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/windowmaker/windowmaker-0.92.0-r7.ebuild?rev=1.1&content-type=text/plain

Index: windowmaker-0.92.0-r7.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/windowmaker/windowmaker-0.92.0-r7.ebuild,v 1.1 2007/11/22 22:09:59 truedfx Exp $

inherit autotools eutils gnustep-base flag-o-matic

PATCHVER=1
S=${WORKDIR}/${P/windowm/WindowM}

DESCRIPTION="The fast and light GNUstep window manager"
SRC_URI="ftp://ftp.windowmaker.info/pub/source/release/${P/windowm/WindowM}.tar.gz
	http://www.windowmaker.info/pub/source/release/WindowMaker-extra-0.1.tar.gz
	http://www.gentoo.org/~grobian/distfiles/${P}-patchset-${PATCHVER}.tar.bz2"
HOMEPAGE="http://www.windowmaker.info/"

IUSE="gif gnustep jpeg nls png tiff modelock xinerama"
DEPEND="x11-libs/libXv
	x11-libs/libXft
	x11-libs/libXt
	media-libs/fontconfig
	gif? ( >=media-libs/giflib-4.1.0-r3 )
	png? ( >=media-libs/libpng-1.2.1 )
	jpeg? ( >=media-libs/jpeg-6b-r2 )
	tiff? ( >=media-libs/tiff-3.6.1-r2 )
	gnustep? ( >=gnustep-base/gnustep-make-2.0 )"
RDEPEND="${DEPEND}
	nls? ( >=sys-devel/gettext-0.10.39 )"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

src_unpack() {
	is-flag -fstack-protector && filter-flags -fstack-protector \
		&& ewarn "CFLAG -fstack-protector has been disabled, as it is known to cause bugs with WindowMaker (bug #78051)" && ebeep 2
	replace-flags "-Os" "-O2"
	replace-flags "-O3" "-O2"

	unpack ${A}
	cd "${S}"
	local psd="${WORKDIR}"/${P}-patchset-${PATCHVER}

	epatch "${psd}"/WindowMaker-0.92.0-cvs20060123.patch
	epatch "${psd}"/WindowMaker-0.92.0-cvs-gcc41.patch
	epatch "${FILESDIR}"/${PV/0.92/0.91}/wlist-0.9x.patch
	epatch "${FILESDIR}"/${PV}/${P}-gif-before-ungif.patch
	epatch "${FILESDIR}"/${PV}/${P}-math_h.patch

	# Patches from altlinux
	epatch "${psd}"/WindowMaker-0.91.0-alt-session.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-restartscrpt.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-menutrans.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-titlebar.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-clipnotext.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-mmx.patch
	epatch "${psd}"/WindowMaker-0.80.2-cvs-alt-textfield.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-focus.patch

	# New features (cool!)
	epatch "${FILESDIR}"/${PV/0.92/0.91}/singleclick-shadeormaxopts-0.9x.patch2
	epatch "${psd}"/WindowMaker-0.91.0-alt-dockhotkeys.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-vlaad-trance.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-vlaad-newbuttons.patch
	epatch "${psd}"/WindowMaker-0.91.0-alt-adialog.patch
	epatch "${psd}"/WindowMaker-0.91.0-hmepas-minimizeall.patch
	epatch "${psd}"/WindowMaker-0.91.0-hmepas-swmenu_rclick.patch
	epatch "${psd}"/WindowMaker-0.91.0-sga-moving-add.patch
	epatch "${psd}"/WindowMaker-0.91.0-peter-newappicon.patch
	epatch "${psd}"/WindowMaker-0.91.0-peter-mouse-placement.patch
	epatch "${psd}"/WindowMaker-0.91.0-peter-appicon-bouncer2.patch
	epatch "${psd}"/WindowMaker-0.91.0-sga-swpanel-customization.patch
	epatch "${psd}"/WindowMaker-0.92.0-alt-newpo.patch

	# Add UK localisation
	cp "${psd}"/WindowMaker-uk.po po/uk.po
	cp "${psd}"/WPrefs-uk.po WPrefs.app/po/uk.po

	# Add newbuttons resources
	cp "${psd}"/WindowMaker-newbuttons.nextstyle.tiff \
		WPrefs.app/tiff/nextstyle.tiff
	cp "${psd}"/WindowMaker-newbuttons.oldstyle.tiff \
		WPrefs.app/tiff/oldstyle.tiff
	cp "${psd}"/WindowMaker-newbuttons.nextstyle.xpm \
		WPrefs.app/xpm/nextstyle.xpm

	# Fix some paths
	if use gnustep; then
		egnustep_env
	fi
	for file in "${S}"/WindowMaker/*menu*; do
		if [ -r "$file" ]; then
			if use gnustep ; then
				sed -i "s:/usr/local/GNUstep/Applications:${GNUSTEP_SYSTEM_APPS}:g" "$file"
			else
				sed -i "s:/usr/local/GNUstep/Applications/WPrefs.app:/usr/bin/:g;" "$file"
			fi

			sed -i 's:/usr/local/share/WindowMaker:/usr/share/WindowMaker:g;' "$file"
			sed -i 's:/opt/share/WindowMaker:/usr/share/WindowMaker:g;' "$file"
		fi;
	done;

	eautoreconf || die "eautoreconf failed"
}

src_compile() {
	local myconf

	# image format types
	# xpm is provided by X itself
	myconf="--enable-xpm $(use_enable png) $(use_enable jpeg) $(use_enable gif) $(use_enable tiff)"

	# non required X capabilities
	myconf="${myconf} $(use_enable modelock) $(use_enable xinerama)"

	if use gnustep ; then
		egnustep_env
		# Gentoo installs everything in System, make sure configure honors that
		export GNUSTEP_LOCAL_ROOT=${GNUSTEP_SYSTEM_ROOT}
		myconf="${myconf} --with-gnustepdir=${GNUSTEP_SYSTEM_ROOT}"
	fi

	if use nls; then
		[ -z "$LINGUAS" ] && export LINGUAS="`ls po/*.po | sed 's:po/\(.*\)\.po$:\1:'`"
	else
		myconf="${myconf} --disable-locale"
	fi

	# enable new features, need to be done via defines
	append-flags -DBOUNCE_APP -DNEWAPPICON -DVIRTUAL_DESKTOP

	# Solaris has inet_aton, but it's hidden in -lresolv
	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lresolv

	# default settings with $myconf appended
	econf \
		--sysconfdir=/etc/X11 \
		--with-x \
		--enable-usermenu \
		--with-pixmapdir=/usr/share/pixmaps \
		--with-nlsdir=/usr/share/locale \
		${myconf} || die

	emake || die "windowmaker: make has failed"

	# WindowMaker Extra Package (themes and icons)
	cd ../WindowMaker-extra-0.1
	econf || die "windowmaker-extra: configure has failed"
	emake || die "windowmaker-extra: make has failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "windowmaker: install has failed."

	dodoc AUTHORS BUGFORM BUGS ChangeLog COPYING* INSTALL* FAQ* \
		  MIRRORS README* NEWS TODO

	# WindowMaker Extra
	cd ../WindowMaker-extra-0.1
	emake DESTDIR="${D}" install || die "windowmaker-extra: install failed"

	newdoc README README.extra

	# create wmaker session shell script
	echo "#!/usr/bin/env bash" > wmaker
	echo "/usr/bin/wmaker" >> wmaker
	exeinto /etc/X11/Sessions/
	doexe wmaker

	insinto /etc/X11/dm/Sessions
	doins "${FILESDIR}"/wmaker.desktop
	make_desktop_entry /usr/bin/wmaker
}



-- 
gentoo-commits@g.o mailing list