Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Zac Medico (zmedico)" <zmedico@g.o>
Subject: gentoo-x86 commit in app-text/calibre: calibre-0.5.14.ebuild ChangeLog calibre-0.5.13.ebuild calibre-0.5.11.ebuild calibre-0.5.12.ebuild
Date: Tue, 02 Jun 2009 00:52:23 +0000
zmedico     09/06/02 00:52:23

  Modified:             ChangeLog
  Added:                calibre-0.5.14.ebuild
  Removed:              calibre-0.5.13.ebuild calibre-0.5.11.ebuild
                        calibre-0.5.12.ebuild
  Log:
  0.5.14 bump and remove older versions.
  (Portage version: 2.2_rc33_p13615/cvs/Linux i686)

Revision  Changes    Path
1.26                 app-text/calibre/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	25 May 2009 23:23:36 -0000	1.25
+++ ChangeLog	2 Jun 2009 00:52:23 -0000	1.26
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/calibre
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v 1.25 2009/05/25 23:23:36 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v 1.26 2009/06/02 00:52:23 zmedico Exp $
+
+*calibre-0.5.14 (02 Jun 2009)
+
+  02 Jun 2009; Zac Medico <zmedico@g.o> -calibre-0.5.11.ebuild,
+  -calibre-0.5.12.ebuild, -calibre-0.5.13.ebuild, +calibre-0.5.14.ebuild:
+  0.5.14 bump and remove older versions.
 
 *calibre-0.5.13-r2 (25 May 2009)
 



1.1                  app-text/calibre/calibre-0.5.14.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/calibre-0.5.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/calibre-0.5.14.ebuild?rev=1.1&content-type=text/plain

Index: calibre-0.5.14.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/calibre-0.5.14.ebuild,v 1.1 2009/06/02 00:52:23 zmedico Exp $

EAPI=2
NEED_PYTHON=2.6

inherit python distutils eutils fdo-mime bash-completion

MY_P="${P/_p/-p}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="Ebook management application."
HOMEPAGE="http://calibre.kovidgoyal.net"
SRC_URI="http://calibre.kovidgoyal.net/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"

KEYWORDS="~amd64 ~x86"

SLOT="0"

IUSE=""

# libusb-compat is untested
SHARED_DEPEND=">=dev-lang/python-2.6[sqlite]
	>=dev-python/setuptools-0.6_rc5
	>=dev-python/imaging-1.1.6
	dev-libs/libusb:0
	>=dev-python/PyQt4-4.4.2[webkit]
	>=dev-python/mechanize-0.1.11
	>=media-gfx/imagemagick-6.3.5
	>=x11-misc/xdg-utils-1.0.2
	>=dev-python/dbus-python-0.82.2
	>=dev-python/lxml-2.1.5
	>=dev-python/python-dateutil-1.4.1
	>=dev-python/beautifulsoup-3.0.5
	>=dev-python/dnspython-1.6.0
	>=sys-apps/help2man-1.36.4
	>=dev-python/pyPdf-1.12
	>=app-text/pdftk-1.12"

RDEPEND="$SHARED_DEPEND
	>=dev-python/reportlab-2.1
	!dev-python/cherrypy
	!dev-python/cssutils
	!dev-python/django-tagging
	!dev-python/odfpy"

DEPEND="$SHARED_DEPEND
	dev-python/setuptools
	>=gnome-base/librsvg-2.0.0
	>=x11-misc/xdg-utils-1.0.2-r2
	sys-apps/help2man"

src_prepare() {
	# Removing the post_install call. We'll do that stuff in src_install.
	sed -i -e "/if 'install'/,/subprocess.check_call/d" \
		setup.py || die "couldn't remove post_install call"
	# For help2man to succeed, we need to tell it the path to the tools.
	sed -i -e "s:\('help2man',\) \(prog\):\1 \'PYTHONPATH=\"${D}$(python_get_sitedir)\" \' + \'${D}usr/bin/\' + \2:" \
		src/calibre/linux.py || die "sed'ing in the IMAGE path failed"
	# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
	# calls xdg-desktop-menu (bug #258938). This also prevents
	# "${D}"/usr/share/applications/{mimeinfo.cache,defaults.list}
	# from being installed (we don't want them anyway).
	sed -i -e "s:xdg-desktop-menu install:xdg-desktop-menu install --mode user:" \
		src/calibre/linux.py || die "sed'ing in the IMAGE path failed"
	distutils_src_prepare
}

src_install() {
	pushd "${S}"/build
	ln -s lib\.* lib
	popd
	distutils_src_install

	# Create directory before running the postinst script
	# otherwise it will bail out.
	dodir /usr/share/icons/hicolor
	dodir /etc/xdg/menus
	dodir /usr/share/applications
	dodir /usr/share/desktop-directories
	dodir /usr/share/applnk
	dodir /usr/share/mime/packages

	# Bypass the default kde-config output, and force it to
	# tell xdg-mime to use a different path.
	cat - > "${T}/kde-config" <<EOF
#!/bin/bash

case \$1:\$2 in
	--version:) echo -e "Qt: 3.3.8\nKDE: 3.5.8\nkde-config: 1.0" ;;
	--path:mime) echo "${D}/usr/share/mimelnk/" ;;
esac
EOF

	chmod +x "${T}/kde-config"

	PATH="${T}:${PATH}" KDEDIRS="${D}/usr" XDG_DATA_DIRS="${D}/usr/share" DESTDIR="${D}" PYTHONPATH="${S}/build/lib" \
		python "${S}"/src/${PN}/linux.py \
		--use-destdir --do-not-reload-udev-hal \
		--group-file="${ROOT}"/etc/group --dont-check-root \
		|| die "post-installation failed."

	# The menu entries end up here due to '--mode user' being added to
	# xdg-desktop-menu options in src_prepare.
	domenu "$HOME"/.local/share/applications/*.desktop || \
		die "failed to install .desktop menu files"

	# Move the bash-completion file and properly install it.
	mv "${D}"/etc/bash_completion.d/calibre "${S}/" \
		|| die "cannot move the bash-completion file"
	dobashcompletion "${S}"/calibre
	find "${D}"/etc -type d -empty -delete

	# Removing junk.
	rm -r "${D}"/usr/share/mime/{subclasses,XMLnamespaces,globs{,2},mime.cache,magic,aliases,types,treemagic,{generic-,}icons} \
		"${D}"/usr/share/{applnk,desktop-directories} \
		"${D}$(python_get_sitedir)"/pyPdf
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	distutils_pkg_postinst
	bash-completion_pkg_postinst
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in net-im/psi: psi-0.13_rc1.ebuild
Next by thread:
gentoo-x86 commit in sys-cluster/charm: metadata.xml charm-6.1.2.ebuild
Previous by date:
gentoo-x86 commit in net-im/psi: psi-0.13_rc1.ebuild
Next by date:
gentoo-x86 commit in sys-cluster/charm: metadata.xml charm-6.1.2.ebuild


Updated Oct 08, 2010

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.