Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Ulrich Mueller (ulm)" <ulm@g.o>
Subject: gentoo-x86 commit in app-text/a2ps: ChangeLog a2ps-4.13c-r6.ebuild
Date: Tue, 22 Jan 2008 11:20:55 +0000
ulm         08/01/22 11:20:55

  Modified:             ChangeLog
  Added:                a2ps-4.13c-r6.ebuild
  Log:
  Fix Emacs support, bug 202331.
  (Portage version: 2.1.4)

Revision  Changes    Path
1.65                 app-text/a2ps/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/a2ps/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	24 May 2007 17:52:25 -0000	1.64
+++ ChangeLog	22 Jan 2008 11:20:54 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/a2ps
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/a2ps/ChangeLog,v 1.64 2007/05/24 17:52:25 beandog Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/a2ps/ChangeLog,v 1.65 2008/01/22 11:20:54 ulm Exp $
+
+*a2ps-4.13c-r6 (22 Jan 2008)
+
+  22 Jan 2008; Ulrich Mueller <ulm@g.o> +files/50a2ps-gentoo.el,
+  +a2ps-4.13c-r6.ebuild:
+  Fix Emacs support, bug 202331.
 
   24 May 2007; Steve Dibb <beandog@g.o> a2ps-4.13c-r5.ebuild:
   Fix mktemp deps for x86-fbsd



1.1                  app-text/a2ps/a2ps-4.13c-r6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/a2ps-4.13c-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/a2ps/a2ps-4.13c-r6.ebuild?rev=1.1&content-type=text/plain

Index: a2ps-4.13c-r6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/a2ps/a2ps-4.13c-r6.ebuild,v 1.1 2008/01/22 11:20:54 ulm Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit eutils autotools elisp-common

S=${WORKDIR}/${PN}-${PV:0:4}
DESCRIPTION="Any to PostScript filter"
HOMEPAGE="http://www.inf.enst.fr/~demaille/a2ps/"
SRC_URI="mirror://gentoo/${P}.tar.gz
	cjk? ( mirror://gentoo/${P}-ja_nls.patch.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="cjk emacs nls tetex vanilla"

DEPEND=">=dev-util/gperf-2.7.2
	|| ( >=dev-util/yacc-1.9.1 sys-devel/bison )
	virtual/ghostscript
	>=app-text/psutils-1.17
	emacs? ( virtual/emacs )
	tetex? ( virtual/tetex )
	nls? ( sys-devel/gettext )"
RDEPEND="virtual/ghostscript
	|| ( sys-apps/mktemp sys-freebsd/freebsd-ubin )
	>=app-text/psutils-1.17
	emacs? ( virtual/emacs )
	tetex? ( virtual/tetex )
	nls? ( virtual/libintl )"

SITEFILE=50${PN}-gentoo.el

src_unpack() {
	unpack ${P}.tar.gz
	cd "${S}"

	epatch "${FILESDIR}/${PN}-4.13-select-freebsd.patch"
	epatch "${FILESDIR}/${P}-locale-gentoo.diff"
	epatch "${FILESDIR}/${PN}-4.13c-stdarg.patch"
	use vanilla || epatch "${FILESDIR}/${PN}-4.13-stdout.diff"
	epatch "${FILESDIR}/${PV}-gcc34.patch"
	use cjk && epatch "${DISTDIR}/${P}-ja_nls.patch.gz"

	# improve tempfile handling
	epatch "${FILESDIR}/${P}-fixps.patch"
	epatch "${FILESDIR}/${P}-psmandup.diff"

	# fix fnmatch replacement, bug #134546
	epatch "${FILESDIR}/${P}-fnmatch-replacement.patch"

	# fix sandbox violation, bug #79012
	sed -i -e 's:$acroread -helpall:acroread4 -helpall:' configure configure.in

	# fix emacs printing, bug #114627
	epatch "${FILESDIR}/a2ps-4.13c-emacs.patch"

	# fix psset with sed-4.1, bug #126403
	epatch "${FILESDIR}/a2ps-4.13c-psset.patch"

	# fix >=autoconf-2.60, bug 138161
	epatch "${FILESDIR}/a2ps-4.13-fixcachecheck.patch"

	# fix chmod error, #167670
	epatch "${FILESDIR}/a2ps-4.13-manpage-chmod.patch"

	AT_M4DIR="m4" eautoreconf || die "eautoreconf failed"
}

src_compile() {
	addpredict /usr/$(get_libdir)/mozilla-firefox/components/xpti.dat
	addpredict /usr/$(get_libdir)/mozilla-firefox/components/xpti.dat.tmp
	addpredict /usr/$(get_libdir)/mozilla-firefox/components/compreg.dat.tmp

	addpredict /usr/$(get_libdir)/mozilla/components/xpti.dat
	addpredict /usr/$(get_libdir)/mozilla/components/xpti.dat.tmp

	#export YACC=yacc
	econf --sysconfdir=/etc/a2ps \
		--includedir=/usr/include \
		$(useq emacs || echo EMACS=no) \
		$(use_enable nls) || die "econf failed"

	export LANG=C

	# sometimes emake doesn't work
	make || die "make failed"
}

src_install() {
	einstall \
		sysconfdir=${D}/etc/a2ps \
		includedir=${D}/usr/include \
		lispdir="${D}${SITELISP}/${PN}" \
		|| die "einstall failed"

	dosed /etc/a2ps/a2ps.cfg

	# bug #122026
	sed -i "s:^countdictstack: \0:" "${D}"/usr/bin/psset || die "sed failed"

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" \
			|| die "elisp-site-file-install failed"
	fi

	dodoc ANNOUNCE AUTHORS ChangeLog FAQ NEWS README* THANKS TODO
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}



-- 
gentoo-commits@g.o mailing list


Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in net-im/psi: ChangeLog psi-0.10-r4.ebuild psi-0.10.ebuild psi-0.10-r2.ebuild
Next by thread:
gentoo-x86 commit in app-text/a2ps: ChangeLog a2ps-4.13c-r6.ebuild
Previous by date:
gentoo-x86 commit in net-mail/dovecot: ChangeLog dovecot-1.0.10.ebuild
Next by date:
gentoo commit in xml/htdocs/main/en: lists.xml


Updated Sep 08, 2011

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.