Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Mike Frysinger (vapier)" <vapier@g.o>
Subject: gentoo-x86 commit in media-libs/netpbm: ChangeLog netpbm-10.26.45.ebuild
Date: Fri, 28 Sep 2007 00:57:40 +0000
vapier      07/09/28 00:57:40

  Modified:             ChangeLog
  Added:                netpbm-10.26.45.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.3.9, RepoMan options: --force)

Revision  Changes    Path
1.164                media-libs/netpbm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.164&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/netpbm/ChangeLog?rev=1.164&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/netpbm/ChangeLog?r1=1.163&r2=1.164

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v
retrieving revision 1.163
retrieving revision 1.164
diff -u -r1.163 -r1.164
--- ChangeLog	10 Jul 2007 09:49:31 -0000	1.163
+++ ChangeLog	28 Sep 2007 00:57:39 -0000	1.164
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/netpbm
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.163 2007/07/10 09:49:31 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/ChangeLog,v 1.164 2007/09/28 00:57:39 vapier Exp $
+
+*netpbm-10.26.45 (28 Sep 2007)
+
+  28 Sep 2007; Mike Frysinger <vapier@g.o>
+  +files/netpbm-10.26.45-headers.patch, +netpbm-10.26.45.ebuild:
+  Version bump.
 
 *netpbm-10.26.44 (10 Jul 2007)
 



1.1                  media-libs/netpbm/netpbm-10.26.45.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/netpbm/netpbm-10.26.45.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/netpbm/netpbm-10.26.45.ebuild?rev=1.1&content-type=text/plain

Index: netpbm-10.26.45.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/netpbm/netpbm-10.26.45.ebuild,v 1.1 2007/09/28 00:57:39 vapier Exp $

inherit flag-o-matic toolchain-funcs eutils multilib

MAN_VER=10.30
DESCRIPTION="A set of utilities for converting to/from the netpbm (and related) formats"
HOMEPAGE="http://netpbm.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tgz
	mirror://gentoo/${PN}-${MAN_VER}-manpages.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 mips s390 sh sparc x86"
IUSE="svga jpeg tiff png zlib"

DEPEND="jpeg? ( >=media-libs/jpeg-6b )
	tiff? ( >=media-libs/tiff-3.5.5 )
	png? ( >=media-libs/libpng-1.2.1 )
	zlib? ( sys-libs/zlib )
	svga? ( media-libs/svgalib )
	media-libs/jbigkit
	media-libs/jasper
	media-libs/urt"

netpbm_libtype() {
	case ${CHOST} in
		*-darwin*) echo dylib;;
		*)         echo unixshared;;
	esac
}
netpbm_libsuffix() {
	local suffix=$(get_libname)
	echo ${suffix//\.}
}
netpbm_ldshlib() {
	case ${CHOST} in
		*-darwin*) echo '-dynamiclib -install_name $(SONAME)';;
		*)         echo '-shared -Wl,-soname,$(SONAME)';;
	esac
}
netpbm_config() {
	use $1 && echo -l${2:-$1} || echo NONE
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/netpbm-10.30-build.patch
	epatch "${FILESDIR}"/netpbm-10.26.45-headers.patch

	rm -f configure
	cp Makefile.config.in Makefile.config
	cat >> Makefile.config <<-EOF
	# Gentoo toolchain options
	CC = $(tc-getCC)
	CC_FOR_BUILD = $(tc-getBUILD_CC)
	AR = $(tc-getAR)
	RANLIB = $(tc-getRANLIB)
	STRIPFLAG =
	CFLAGS_SHLIB = -fPIC

	NETPBMLIBTYPE = $(netpbm_libtype)
	NETPBMLIBSUFFIX = $(netpbm_libsuffix)
	LDSHLIB = $(netpbm_ldshlib)

	# Gentoo build options
	TIFFLIB = $(netpbm_config tiff)
	JPEGLIB = $(netpbm_config jpeg)
	PNGLIB = $(netpbm_config png)
	ZLIB = $(netpbm_config zlib z)
	LINUXSVGALIB = $(netpbm_config svga vga)

	# Use system versions instead of bundled
	JBIGLIB = -ljbig
	JBIGHDR_DIR =
	JASPERLIB = -ljasper
	JASPERHDR_DIR =
	URTLIB = -lrle
	URTHDR_DIR =
	EOF

	# Sparc support ...
	replace-flags -mcpu=ultrasparc "-mcpu=v8 -mtune=ultrasparc"
	replace-flags -mcpu=v9 "-mcpu=v8 -mtune=v9"
}

src_install() {
	make package pkgdir="${D}"/usr || die "make package failed"

	[[ $(get_libdir) != "lib" ]] && mv "${D}"/usr/lib "${D}"/usr/$(get_libdir)

	# Remove cruft that we don't need, and move around stuff we want
	rm "${D}"/usr/include/shhopt.h
	rm -f "${D}"/usr/bin/{doc.url,manweb}
	rm -rf "${D}"/usr/man/web
	rm -rf "${D}"/usr/link
	rm -f "${D}"/usr/{README,VERSION,config_template,pkginfo}
	dodir /usr/share
	mv "${D}"/usr/man "${D}"/usr/share/
	mv "${D}"/usr/misc "${D}"/usr/share/netpbm

	dodoc README
	cd doc
	GLOBIGNORE='*.html:.*' dodoc *
	dohtml -r .

	cd "${WORKDIR}"/${PN}-${MAN_VER}-manpages || die
	doman *.[0-9]
	dodoc README* gen-netpbm-manpages
}



-- 
gentoo-commits@g.o mailing list


Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in media-libs/netpbm: netpbm-10.26.42.ebuild netpbm-10.26.43.ebuild netpbm-10.36.0.ebuild
Next by thread:
gentoo-x86 commit in media-libs/netpbm/files: netpbm-10.26.45-headers.patch digest-netpbm-10.26.45
Previous by date:
gentoo-x86 commit in media-libs/netpbm: netpbm-10.26.42.ebuild netpbm-10.26.43.ebuild netpbm-10.36.0.ebuild
Next by date:
gentoo-x86 commit in media-libs/netpbm/files: netpbm-10.26.45-headers.patch digest-netpbm-10.26.45


Updated May 09, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.