Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Bernard Cafarelli (voyageur)" <voyageur@g.o>
Subject: gentoo-x86 commit in x11-misc/google-gadgets: metadata.xml ChangeLog google-gadgets-0.11.0.ebuild
Date: Mon, 01 Jun 2009 22:50:41 +0000
voyageur    09/06/01 22:50:41

  Modified:             metadata.xml ChangeLog
  Added:                google-gadgets-0.11.0.ebuild
  Log:
  Version bump, performance improvement, reduced memory consumption, new backends for webkit-gtk and libsoup, and bugfixes. ~hppa and ~ppc64 keywords temporarly removed pending bug #272194
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  x11-misc/google-gadgets/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	10 Dec 2008 15:05:19 -0000	1.2
+++ metadata.xml	1 Jun 2009 22:50:41 -0000	1.3
@@ -6,4 +6,8 @@
 		<email>voyageur@g.o</email>
 		<name>Bernard Cafarelli</name>
 	</maintainer>
+	<use>
+		<flag name="soup">Enables XML HTTP request extension based on <pkg>net-libs/libsoup</pkg></flag>
+		<flag name="webkit">Enables browser element and script runtime based on <pkg>net-libs/webkit-gtk</pkg></flag>
+	</use>
 </pkgmetadata>



1.25                 x11-misc/google-gadgets/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	11 Apr 2009 19:30:29 -0000	1.24
+++ ChangeLog	1 Jun 2009 22:50:41 -0000	1.25
@@ -1,6 +1,14 @@
 # ChangeLog for x11-misc/google-gadgets
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v 1.24 2009/04/11 19:30:29 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v 1.25 2009/06/01 22:50:41 voyageur Exp $
+
+*google-gadgets-0.11.0 (01 Jun 2009)
+
+  01 Jun 2009; Bernard Cafarelli <voyageur@g.o>
+  +google-gadgets-0.11.0.ebuild, metadata.xml:
+  Version bump, performance improvement, reduced memory consumption, new
+  backends for webkit-gtk and libsoup, and bugfixes. ~hppa and ~ppc64
+  keywords temporarly removed pending bug #272194
 
   11 Apr 2009; Raúl Porcel <armin76@g.o>
   google-gadgets-0.10.5.ebuild:



1.1                  x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild?rev=1.1&content-type=text/plain

Index: google-gadgets-0.11.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.11.0.ebuild,v 1.1 2009/06/01 22:50:41 voyageur Exp $

EAPI=2

inherit base autotools multilib eutils fdo-mime

MY_PN=${PN}-for-linux
MY_P=${MY_PN}-${PV}

DESCRIPTION="Cool gadgets from Google for your Desktop"
HOMEPAGE="http://code.google.com/p/google-gadgets-for-linux/"
SRC_URI="http://${MY_PN}.googlecode.com/files/${MY_P}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~x86"
IUSE="+dbus debug +gtk +qt4 +gstreamer networkmanager soup startup-notification webkit"

# Weird things happen when we start mix-n-matching, so for the time being
# I've just locked the deps to the versions I had as of Summer 2008. With any
# luck, they'll be stable when we get to stabling this package.

RDEPEND="
	>=dev-libs/libxml2-2.6.32
	net-libs/xulrunner:1.9
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXext
	dbus? ( sys-apps/dbus )
	gstreamer? (
		>=media-libs/gstreamer-0.10.19
		>=media-libs/gst-plugins-base-0.10.19
	)
	gtk? (
		>=dev-libs/atk-1.22.0
		gnome-base/librsvg
		>=net-misc/curl-7.18.2
		>=x11-libs/cairo-1.6.4
		>=x11-libs/gtk+-2.12.10
		>=x11-libs/pango-1.20.3
		dbus? ( >=dev-libs/dbus-glib-0.74 )
	)
	networkmanager? ( net-misc/networkmanager )
	qt4? (
		>=x11-libs/qt-core-4.4.0
		>=x11-libs/qt-opengl-4.4.0
		>=x11-libs/qt-script-4.4.0
		>=x11-libs/qt-webkit-4.4.0
		>=x11-libs/qt-xmlpatterns-4.4.0
		dbus? ( >=x11-libs/qt-dbus-4.4.0 )
	)
	soup? ( >=net-libs/libsoup-2.26 )
	startup-notification? ( x11-libs/startup-notification )
	webkit? ( >=net-libs/webkit-gtk-1.0.3 )
"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.20
"

S="${WORKDIR}/${MY_P}"

RESTRICT="test"

pkg_setup() {
	# If a non-google, non-qt4 and non-gtk host system for google-gadgets is ever developed,
	# I'll consider changing the error below.
	if ! use gtk && ! use qt4; then
		eerror "You must choose which toolkit to build for. Either qt4 or gtk can be"
		eerror "chosen. For qt4, see also above. To enable \$toolkit, do:"
		eerror "echo \"${CATEGORY}/${PN} \$toolkit\" >> /etc/portage/package.use"
		die "You need to choose a toolkit"
	fi

	if ! use gstreamer; then
		ewarn "Disabling gstreamer disables the multimedia functions of ${PN}."
		ewarn "This is not recommended. To enable gstreamer, do:"
		ewarn "echo \"${CATEGORY}/${PN} gstreamer\" >> /etc/portage/package.use"
	fi
}

src_prepare() {
	sed -i -r \
		-e '/^GGL_SYSDEPS_INCLUDE_DIR/ c\GGL_SYSDEPS_INCLUDE_DIR=$GGL_INCLUDE_DIR' \
		configure.ac||die "404"
	eautoreconf
}

src_configure() {
	#For the time being, the smjs-script runtime is required for both gtk and qt
	#versions, but the goal is to make the qt4 version depend only on qt-script.
	has_pkg_smjs=no \
	econf	--disable-dependency-tracking \
		--disable-update-desktop-database \
		--disable-update-mime-database \
		--disable-werror \
		--enable-libxml2-xml-parser \
		--enable-smjs-script-runtime \
		--with-gtkmozembed=libxul \
		--with-smjs-cppflags=-I/usr/include/nspr \
		--with-smjs-libdir=/usr/$(get_libdir)/xulrunner-1.9 \
		--with-smjs-incdir=/usr/include/xulrunner-1.9/unstable \
		--with-browser-plugins-dir=/usr/$(get_libdir)/nsbrowser/plugins \
		--with-ssl-ca-file=/etc/ssl/certs/ca-certificates.crt \
		--with-oem-brand=Gentoo \
		$(use_enable debug) \
		$(use_enable dbus libggadget-dbus) \
		$(use_enable gstreamer gst-audio-framework) \
		$(use_enable gstreamer gst-video-element) \
		$(use_enable soup soup-xml-http-request) \
		$(use_enable webkit webkit-script-runtime) \
		$(use_enable webkit gtkwebkit-browser-element) \
		$(use_enable gtk gtk-host) \
		$(use_enable gtk libggadget-gtk ) \
		$(use_enable gtk gtkmoz-browser-element) \
		$(use_enable gtk gtk-edit-element) \
		$(use_enable gtk gtk-flash-element) \
		$(use_enable gtk gtk-system-framework) \
		$(use_enable gtk curl_xml_http_request) \
		$(use_enable qt4 qt-host) \
		$(use_enable qt4 libggadget-qt) \
		$(use_enable qt4 qt-edit-framework) \
		$(use_enable qt4 qt-system-framework) \
		$(use_enable qt4 qtwebkit-browser-element) \
		$(use_enable qt4 qt-xml-http-request) \
		$(use_enable qt4 qt-script-runtime)
}

src_test() {
	#If someone wants to guarantee that emake will not make
	#tests fail promiscuosly, please do, otherwise we're using make.
	make check &> "${WORKDIR}"/check
}

src_install() {
	base_src_install
	dodoc ChangeLog README
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in net-voip/telepathy-gabble: ChangeLog telepathy-gabble-0.7.28.ebuild
Next by thread:
gentoo-x86 commit in sys-apps/hal: ChangeLog hal-0.5.12_rc1-r6.ebuild hal-0.5.12_rc1-r5.ebuild
Previous by date:
gentoo-x86 commit in net-voip/telepathy-gabble: ChangeLog telepathy-gabble-0.7.28.ebuild
Next by date:
gentoo-x86 commit in sys-apps/hal: ChangeLog hal-0.5.12_rc1-r6.ebuild hal-0.5.12_rc1-r5.ebuild


Updated Apr 18, 2011

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.