eva         10/02/14 23:55:39

  Modified:             ChangeLog
  Added:                libgsf-1.14.17.ebuild
  Removed:              libgsf-1.14.10.ebuild
  Log:
  Version bump. Fix a crash in xml parser, don't call gnome_vfs_init in python binding.
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.154                gnome-extra/libgsf/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/libgsf/ChangeLog?rev=1.154&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/libgsf/ChangeLog?rev=1.154&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/libgsf/ChangeLog?r1=1.153&r2=1.154

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/ChangeLog,v
retrieving revision 1.153
retrieving revision 1.154
diff -u -r1.153 -r1.154
--- ChangeLog	18 Jan 2010 00:15:53 -0000	1.153
+++ ChangeLog	14 Feb 2010 23:55:38 -0000	1.154
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/libgsf
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/ChangeLog,v 1.153 2010/01/18 00:15:53 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/ChangeLog,v 1.154 2010/02/14 23:55:38 eva Exp $
+
+*libgsf-1.14.17 (14 Feb 2010)
+
+  14 Feb 2010; Gilles Dartiguelongue <eva@g.o>
+  -libgsf-1.14.10.ebuild, +libgsf-1.14.17.ebuild:
+  Version bump. Fix a crash in xml parser, don't call gnome_vfs_init in
+  python binding.
 
   18 Jan 2010; Jeroen Roovers <jer@g.o> libgsf-1.14.15.ebuild:
   Stable for HPPA (bug #281427).



1.1                  gnome-extra/libgsf/libgsf-1.14.17.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/libgsf/libgsf-1.14.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/libgsf/libgsf-1.14.17.ebuild?rev=1.1&content-type=text/plain

Index: libgsf-1.14.17.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgsf/libgsf-1.14.17.ebuild,v 1.1 2010/02/14 23:55:38 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit autotools eutils gnome2 python multilib

DESCRIPTION="The GNOME Structured File Library"
HOMEPAGE="http://www.gnome.org/"
SRC_URI="${SRC_URI}
	mirror://gentoo/gnome-mplayer-0.9.6-gconf-2.m4.tgz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="bzip2 doc gnome gtk python thumbnail"

RDEPEND="
	>=dev-libs/glib-2.16
	>=dev-libs/libxml2-2.4.16
	sys-libs/zlib
	bzip2? ( app-arch/bzip2 )
	gnome? (
		>=gnome-base/libbonobo-2
		>=gnome-base/gnome-vfs-2.2 )
	gtk? ( >=x11-libs/gtk+-2 )
	python? (
		>=dev-python/pygobject-2.10
		>=dev-python/pygtk-2.10 )
	thumbnail? ( >=gnome-base/gconf-2 )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-util/intltool-0.35.0
	dev-util/gtk-doc-am
	doc? ( >=dev-util/gtk-doc-1 )"

PDEPEND="gnome? ( media-gfx/imagemagick )"

DOCS="AUTHORS BUGS ChangeLog HACKING NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--with-gio
		--disable-static
		$(use_with bzip2 bz2)
		$(use_with gnome gnome-vfs)
		$(use_with gnome bonobo)
		$(use_with python)
		$(use_with gtk gdk-pixbuf)
		$(use_with thumbnail gconf)"
}

src_prepare() {
	gnome2_src_prepare

	cp "${WORKDIR}/gnome-mplayer-0.9.6-gconf-2.m4" m4/ \
		|| die "failed to copy gconf macro"

	# Fix gconf automagic, bug #289856
	epatch "${FILESDIR}/${PN}-1.14.16-gconf-automagic.patch"

	# Fix useless variable in toplevel Makefile.am, bug #298813
	epatch "${FILESDIR}/${PN}-1.14.16-automake-fixes.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile
}

pkg_preinst() {
	gnome2_pkg_preinst
	preserve_old_lib /usr/$(get_libdir)/libgsf-1.so.1
	preserve_old_lib /usr/$(get_libdir)/libgsf-gnome-1.so.1
}

pkg_postinst() {
	gnome2_pkg_postinst
	if use python; then
		python_need_rebuild
		python_mod_optimize $(python_get_sitedir)/gsf
	fi

	preserve_old_lib_notify /usr/$(get_libdir)/libgsf-1.so.1
	preserve_old_lib_notify /usr/$(get_libdir)/libgsf-gnome-1.so.1
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/gsf
}