Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Michael Sterrett (mr_bones_)" <mr_bones_@g.o>
Subject: gentoo-x86 commit in games-puzzle/neverball: neverball-1.5.1.ebuild ChangeLog
Date: Wed, 08 Apr 2009 16:52:09 +0000
mr_bones_    09/04/08 16:52:09

  Modified:             ChangeLog
  Added:                neverball-1.5.1.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.7/cvs/Linux i686)

Revision  Changes    Path
1.32                 games-puzzle/neverball/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-puzzle/neverball/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	3 Apr 2009 16:33:57 -0000	1.31
+++ ChangeLog	8 Apr 2009 16:52:09 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for games-puzzle/neverball
 # Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/neverball/ChangeLog,v 1.31 2009/04/03 16:33:57 tcunha Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/neverball/ChangeLog,v 1.32 2009/04/08 16:52:09 mr_bones_ Exp $
+
+*neverball-1.5.1 (08 Apr 2009)
+
+  08 Apr 2009; Michael Sterrett <mr_bones_@g.o>
+  +neverball-1.5.1.ebuild:
+  version bump
 
   03 Apr 2009; Tiago Cunha <tcunha@g.o> neverball-1.5.0.ebuild:
   stable amd64, bug 264698



1.1                  games-puzzle/neverball/neverball-1.5.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/neverball-1.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/neverball/neverball-1.5.1.ebuild?rev=1.1&content-type=text/plain

Index: neverball-1.5.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/neverball/neverball-1.5.1.ebuild,v 1.1 2009/04/08 16:52:09 mr_bones_ Exp $

EAPI=2
inherit eutils games

DESCRIPTION="Clone of Super Monkey Ball using SDL/OpenGL"
HOMEPAGE="http://icculus.org/neverball/"
SRC_URI="http://icculus.org/neverball/${P}.tar.gz"

LICENSE="GPL-2 BitstreamVera"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls"
RESTRICT="test"

RDEPEND="media-libs/libsdl[joystick]
	media-libs/sdl-ttf
	media-libs/libpng
	media-libs/jpeg
	media-libs/libvorbis
	virtual/opengl
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	sys-devel/gettext"

src_prepare() {
	sed -i \
		-e '/CONFIG_DATA/s:"\./data":"'${GAMES_DATADIR}/${PN}'":g' \
		-e '/CONFIG_LOCALE/s:"\./data":"/usr/share/locale":g' \
		share/base_config.h \
		|| die "sed failed"
	sed -i \
		-e 's:mapc:neverball-mapc:g' \
		-e 's:MAPC:NEVERBALL-MAPC:g' \
		-e '1 s/ 1 / 6 /' \
		dist/mapc.1 \
		|| die "sed failed"
	sed -i \
		-e 's:-O2:$(E_CFLAGS):' \
		-e "/^MAPC_TARG/s/mapc/${PN}-mapc/" \
		Makefile \
		|| die "sed failed"
}

src_compile() {
	LINGUAS= \
	emake \
		ENABLE_NLS=$(use nls && echo 1 || echo 0) \
		E_CFLAGS="${CFLAGS}" \
		|| die "emake failed"
}

src_install() {
	dogamesbin ${PN}-mapc neverball neverputt || die "dogamesbin failed"
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r data/* || die "doins failed"
	if use nls ; then
		insinto /usr/share
		doins -r locale || die "doins failed"
	fi
	dodoc CHANGES README

	newicon dist/neverball_512.png neverball.png
	newicon dist/neverputt_512.png neverputt.png
	doman dist/*.6
	newman dist/mapc.1 neverball-mapc.6
	make_desktop_entry neverball Neverball
	make_desktop_entry neverputt Neverputt neverputt

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "${P} will overwrite existing high-score files, so back them up if you want to preserve your old scores and progress."
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in x11-wm/fluxbox: fluxbox-1.1.0.1.ebuild ChangeLog fluxbox-1.1.1.ebuild
Next by thread:
gentoo-x86 commit in games-puzzle/neverball: neverball-1.5.1.ebuild ChangeLog
Previous by date:
gentoo-x86 commit in eclass: git.eclass
Next by date:
gentoo-x86 commit in dev-scheme/chicken: ChangeLog chicken-3.3.0.ebuild


Updated Mar 31, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.