[gentoo-commits] gentoo-x86 commit in app-editors/nano: ChangeLog nano-2.1.6-r2.ebuild

[Mike Frysinger (vapier)]

vapier      08/10/19 06:56:40

  Modified:             ChangeLog
  Added:                nano-2.1.6-r2.ebuild
  Log:
  Add fix from upstream for cutting at end of file #240330 by amadeus.bit.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.26.2 x86_64)

Revision  Changes    Path
1.218                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.218&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.218&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?r1=1.217&r2=1.218

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.217
retrieving revision 1.218
diff -u -r1.217 -r1.218
--- ChangeLog	8 Oct 2008 10:09:57 -0000	1.217
+++ ChangeLog	19 Oct 2008 06:56:40 -0000	1.218
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.217 2008/10/08 10:09:57 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.218 2008/10/19 06:56:40 vapier Exp $
+
+*nano-2.1.6-r2 (19 Oct 2008)
+
+  19 Oct 2008; Mike Frysinger <vapier@g.o>
+  +files/nano-2.1.6-cut-last.patch, +nano-2.1.6-r2.ebuild:
+  Add fix from upstream for cutting at end of file #240330 by amadeus.bit.
 
   08 Oct 2008; Raúl Porcel <armin76@g.o> nano-2.0.9.ebuild,
   nano-2.1.5.ebuild:



1.1                  app-editors/nano/nano-2.1.6-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.6-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.6-r2.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.1.6-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.1.6-r2.ebuild,v 1.1 2008/10/19 06:56:40 vapier Exp $

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
	inherit subversion
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug justify minimal ncurses nls slang spell unicode"

DEPEND=">=sys-libs/ncurses-5.2
	nls? ( sys-devel/gettext )
	!ncurses? ( slang? ( sys-libs/slang ) )"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		subversion_src_unpack
	else
		unpack ${A}
	fi
	cd "${S}"
	epatch "${FILESDIR}"/${P}-cut-paste-segv.patch
	epatch "${FILESDIR}"/${P}-cut-last.patch #240330
	if [[ ! -e configure ]] ; then
		./autogen.sh || die "autogen failed"
	fi
}

src_compile() {
	local myconf=""
	use ncurses \
		&& myconf="--without-slang" \
		|| myconf="${myconf} $(use_with slang)"

	econf \
		--bindir=/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		${myconf} \
		|| die "configure failed"
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml *.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano

	insinto /usr/share/nano
	local f
	for f in "${FILESDIR}"/*.nanorc ; do
		[[ -e ${D}/usr/share/nano/${f##*/} ]] && continue
		doins "${f}" || die
		echo "# include \"/usr/share/nano/${f##*/}\"" >> "${D}"/etc/nanorc
	done
}

pkg_postinst() {
	elog "More helpful info about nano, visit the GDP page:"
	elog "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}