Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "seemant (seemant)" <seemant@g.o>
Subject: gentoo-x86 commit in app-crypt/mit-krb5: ChangeLog mit-krb5-1.5.3-r1.ebuild mit-krb5-1.4.3-r3.ebuild
Date: Fri, 07 Sep 2007 06:27:33 +0000
seemant     07/09/07 06:27:33

  Modified:             ChangeLog
  Added:                mit-krb5-1.5.3-r1.ebuild
  Removed:              mit-krb5-1.4.3-r3.ebuild
  Log:
  removed the 1.4 stuff, because it's totally unmaintained upstream and here.  Bumped to 1.5.3-r1 for the newest security fix. See bug #191301
  (Portage version: 2.1.3.7)

Revision  Changes    Path
1.162                app-crypt/mit-krb5/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/mit-krb5/ChangeLog?rev=1.162&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/mit-krb5/ChangeLog?rev=1.162&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/mit-krb5/ChangeLog?r1=1.161&r2=1.162

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v
retrieving revision 1.161
retrieving revision 1.162
diff -u -r1.161 -r1.162
--- ChangeLog	7 Sep 2007 06:03:15 -0000	1.161
+++ ChangeLog	7 Sep 2007 06:27:33 -0000	1.162
@@ -1,6 +1,13 @@
 # ChangeLog for app-crypt/mit-krb5
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v 1.161 2007/09/07 06:03:15 seemant Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/ChangeLog,v 1.162 2007/09/07 06:27:33 seemant Exp $
+
+*mit-krb5-1.5.3-r1 (07 Sep 2007)
+
+  07 Sep 2007; Seemant Kulleen <seemant@g.o>
+  -mit-krb5-1.4.3-r3.ebuild, +mit-krb5-1.5.3-r1.ebuild:
+  removed the 1.4 stuff, because it's totally unmaintained upstream and here.
+  Bumped to 1.5.3-r1 for the newest security fix. See bug #191301
 
   07 Sep 2007; Seemant Kulleen <seemant@g.o>
   -mit-krb5-1.5.2-r1.ebuild, -mit-krb5-1.5.2-r2.ebuild,



1.1                  app-crypt/mit-krb5/mit-krb5-1.5.3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.5.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.5.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: mit-krb5-1.5.3-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/mit-krb5/mit-krb5-1.5.3-r1.ebuild,v 1.1 2007/09/07 06:27:33 seemant Exp $

inherit eutils flag-o-matic versionator autotools

PATCHV="0.2"
MY_P=${P/mit-}
P_DIR=$(get_version_component_range 1-2)
S=${WORKDIR}/${MY_P}/src
DESCRIPTION="MIT Kerberos V"
HOMEPAGE="http://web.mit.edu/kerberos/www/"
SRC_URI="http://web.mit.edu/kerberos/dist/krb5/${P_DIR}/${MY_P}-signed.tar
	http://dev.gentoo.org/~seemant/distfiles/${P}-patches-${PATCHV}.tar.bz2
	mirror://gentoo/${P}-patches-${PATCHV}.tar.bz2"

PATCHDIR="${WORKDIR}/patch"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="krb4 tcl ipv6 doc"

RDEPEND="!virtual/krb5
	sys-libs/com_err
	sys-libs/ss
	tcl? ( dev-lang/tcl )"
DEPEND="${RDEPEND}
	doc? ( virtual/tetex )"
PROVIDE="virtual/krb5"

src_unpack() {
	unpack ${A}
	unpack ./${MY_P}.tar.gz
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-lazyldflags.patch
	EPATCH_SUFFIX="patch" epatch "${PATCHDIR}"
	ebegin "Reconfiguring configure scripts (be patient)"
	cd "${S}"/appl/telnet
	eautoconf --force -I "${S}"
	eend $?
}

src_compile() {
	econf \
		$(use_with krb4) \
		$(use_with tcl) \
		$(use_enable ipv6) \
		--enable-shared \
		--with-system-et --with-system-ss \
		--enable-dns-for-realm \
		--enable-kdc-replay-cache || die

	emake -j1 || die

	if use doc ; then
		cd ../doc
		for dir in api implement ; do
			make -C ${dir} || die
		done
	fi
}

src_test() {
	einfo "Testing is being debugged, disabled for now"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		EXAMPLEDIR=/usr/share/doc/${PF}/examples \
		install || die

	keepdir /var/lib/krb5kdc

	cd ..
	dodoc README
	dodoc doc/*.ps
	doinfo doc/*.info*
	dohtml -r doc/*

	use doc && dodoc doc/{api,implement}/*.ps

	for i in {telnetd,ftpd} ; do
		mv "${D}"/usr/share/man/man8/${i}.8 "${D}"/usr/share/man/man8/k${i}.8
		mv "${D}"/usr/sbin/${i} "${D}"/usr/sbin/k${i}
	done

	for i in {rcp,rlogin,rsh,telnet,ftp} ; do
		mv "${D}"/usr/share/man/man1/${i}.1 "${D}"/usr/share/man/man1/k${i}.1
		mv "${D}"/usr/bin/${i} "${D}"/usr/bin/k${i}
	done

	newinitd "${FILESDIR}"/mit-krb5kadmind.initd mit-krb5kadmind
	newinitd "${FILESDIR}"/mit-krb5kdc.initd mit-krb5kdc

	insinto /etc
	newins ${D}/usr/share/doc/${PF}/examples/krb5.conf krb5.conf.example
	newins ${D}/usr/share/doc/${PF}/examples/kdc.conf kdc.conf.example
}

pkg_postinst() {
	elog "See /usr/share/doc/${PF}/html/krb5-admin/index.html for documentation."
}



-- 
gentoo-commits@g.o mailing list


Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in net-misc/nxclient: ChangeLog
Next by thread:
gentoo-x86 commit in sys-fs/udev: ChangeLog udev-115-r2.ebuild
Previous by date:
gentoo-x86 commit in net-misc/nxclient: ChangeLog
Next by date:
gentoo-x86 commit in sys-fs/udev: ChangeLog udev-115-r2.ebuild


Updated Mar 31, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.