[gentoo-commits] gentoo-x86 commit in net-misc/tightvnc: ChangeLog tightvnc-1.3.9-r1.ebuild

[Steve Dibb (beandog)]

beandog     07/10/17 23:32:58

  Modified:             ChangeLog
  Added:                tightvnc-1.3.9-r1.ebuild
  Log:
  Fix DEPEND/RDEPEND
  (Portage version: 2.1.3.12)

Revision  Changes    Path
1.114                net-misc/tightvnc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/tightvnc/ChangeLog?rev=1.114&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/tightvnc/ChangeLog?rev=1.114&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/tightvnc/ChangeLog?r1=1.113&r2=1.114

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tightvnc/ChangeLog,v
retrieving revision 1.113
retrieving revision 1.114
diff -u -r1.113 -r1.114
--- ChangeLog	27 Jun 2007 16:36:18 -0000	1.113
+++ ChangeLog	17 Oct 2007 23:32:58 -0000	1.114
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/tightvnc
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tightvnc/ChangeLog,v 1.113 2007/06/27 16:36:18 lavajoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tightvnc/ChangeLog,v 1.114 2007/10/17 23:32:58 beandog Exp $
+
+*tightvnc-1.3.9-r1 (17 Oct 2007)
+
+  17 Oct 2007; Steve Dibb <beandog@g.o> +tightvnc-1.3.9-r1.ebuild:
+  Fix DEPEND/RDEPEND
 
   27 Jun 2007; Joe Peterson <lavajoe@g.o> files/1.3.9-fbsd.patch,
   tightvnc-1.3.9.ebuild:



1.1                  net-misc/tightvnc/tightvnc-1.3.9-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/tightvnc/tightvnc-1.3.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/tightvnc/tightvnc-1.3.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: tightvnc-1.3.9-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tightvnc/tightvnc-1.3.9-r1.ebuild,v 1.1 2007/10/17 23:32:58 beandog Exp $

inherit eutils toolchain-funcs

IUSE="java tcpd server"

S="${WORKDIR}/vnc_unixsrc"
DESCRIPTION="A great client/server software package allowing remote network access to graphical desktops."
SRC_URI="mirror://sourceforge/vnc-tight/${P}_unixsrc.tar.bz2"
HOMEPAGE="http://www.tightvnc.com/"

KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~sparc ~x86 ~x86-fbsd"
LICENSE="GPL-2"
SLOT="0"

RDEPEND="~media-libs/jpeg-6b
	server? (
		media-fonts/font-misc-misc
		media-fonts/font-cursor-misc
		x11-apps/rgb
		x11-apps/xauth
		x11-apps/xsetroot
	)
	x11-libs/libX11
	x11-libs/libXaw
	x11-libs/libXmu
	x11-libs/libXp
	x11-libs/libXt
	tcpd? ( >=sys-apps/tcp-wrappers-7.6-r2 )
	java? ( || ( >=virtual/jdk-1.3.1 >=virtual/jre-1.3.1 ) )"
DEPEND="${RDEPEND}
	x11-proto/xextproto
	x11-proto/xproto
	server? (
		x11-proto/inputproto
		x11-proto/kbproto
		x11-proto/printproto
	)
	>=x11-misc/imake-1
	x11-misc/gccmakedep
	x11-misc/makedepend
	!net-misc/vnc"

src_unpack() {

	if ! use server;
	then
		echo
		einfo "The 'server' USE flag will build tightvnc's server."
		einfo "If '-server' is chosen only the client is built to save space."
		einfo "Stop the build now if you need to add 'server' to USE flags.\n"
		ebeep
		epause 5
	fi

	unpack ${A} && cd "${S}"
	epatch "${FILESDIR}/${PN}-1.3.8-pathfixes.patch" # fixes bug 78385 and 146099
	epatch "${FILESDIR}/${PN}-1.3.8-imake-tmpdir.patch" # fixes bug 23483
	epatch "${FILESDIR}/${PN}-1.3.8-darwin.patch" # fixes bug 89908
	use mips && epatch "${FILESDIR}/${PN}-1.3.8-mips.patch"
	epatch "${FILESDIR}"/server-CVE-2007-1003.patch
	epatch "${FILESDIR}"/server-CVE-2007-1351-1352.patch
	epatch "${FILESDIR}"/${PV}-fbsd.patch

}

src_compile() {
	xmkmf -a || die "xmkmf failed"

	make CDEBUGFLAGS="${CFLAGS}" World || die

	if use server; then
		cd Xvnc && ./configure || die "Configure failed."
		if use tcpd; then
			local myextra="-lwrap"
			make EXTRA_LIBRARIES="${myextra}" \
				CDEBUGFLAGS="${CFLAGS}"  \
				EXTRA_DEFINES="-DUSE_LIBWRAP=1" || die
		else
			make CDEBUGFLAGS="${CFLAGS}" || die
		fi
	fi

}

src_install() {
	# the web based interface and the java viewer need the java class files
	if use java; then
		insinto /usr/share/tightvnc/classes
		doins classes/*
	fi

	dodir /usr/share/man/man1 /usr/bin
	./vncinstall "${D}"/usr/bin "${D}"/usr/share/man || die "vncinstall failed"

	if use server; then
		newconfd "${FILESDIR}"/tightvnc.confd vnc
		newinitd "${FILESDIR}"/tightvnc.initd vnc
	else
		rm -f "${D}"/usr/bin/vncserver
		rm -f "${D}"/usr/share/man/man1/{Xvnc,vncserver}*
	fi

	doicon "${FILESDIR}"/vncviewer.png
	make_desktop_entry vncviewer vncviewer vncviewer.png Network

	dodoc ChangeLog README WhatsNew
	use java && dodoc "${FILESDIR}"/README.JavaViewer
	newdoc vncviewer/README README.vncviewer
}



-- 
gentoo-commits@g.o mailing list