[gentoo-commits] gentoo-x86 commit in x11-wm/awesome: ChangeLog awesome-3.2.1-r2.ebuild

[Matsuu Takuto (matsuu)]

matsuu      09/04/16 16:45:15

  Modified:             ChangeLog
  Added:                awesome-3.2.1-r2.ebuild
  Log:
  Defined PREFIX and SYSCONFDIR.
  (Portage version: 2.1.6.11/cvs/Linux x86_64)

Revision  Changes    Path
1.65                 x11-wm/awesome/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/awesome/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/awesome/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/awesome/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	12 Apr 2009 04:32:13 -0000	1.64
+++ ChangeLog	16 Apr 2009 16:45:15 -0000	1.65
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/awesome
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v 1.64 2009/04/12 04:32:13 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v 1.65 2009/04/16 16:45:15 matsuu Exp $
+
+*awesome-3.2.1-r2 (16 Apr 2009)
+
+  16 Apr 2009; MATSUU Takuto <matsuu@g.o> +awesome-3.2.1-r2.ebuild:
+  Defined PREFIX and SYSCONFDIR.
 
 *awesome-3.2.1-r1 (12 Apr 2009)
 



1.1                  x11-wm/awesome/awesome-3.2.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/awesome/awesome-3.2.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/awesome/awesome-3.2.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: awesome-3.2.1-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/awesome-3.2.1-r2.ebuild,v 1.1 2009/04/16 16:45:15 matsuu Exp $

EAPI="2"
inherit cmake-utils eutils

DESCRIPTION="A dynamic floating and tiling window manager"
HOMEPAGE="http://awesome.naquadah.org/"
SRC_URI="http://awesome.naquadah.org/download/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
#IUSE="dbus doc bash-completion"
IUSE="dbus doc"

RDEPEND=">=dev-lang/lua-5.1
	>=dev-libs/glib-2
	dev-libs/libev
	dev-util/gperf
	media-libs/imlib2[png]
	sys-libs/ncurses
	x11-libs/cairo[xcb]
	x11-libs/libX11[xcb]
	>=x11-libs/libxcb-1.1
	>=x11-libs/pango-1.19.3
	>=x11-libs/xcb-util-0.3.3
	dbus? ( >=sys-apps/dbus-1 )"

DEPEND="${RDEPEND}
	app-text/asciidoc
	app-text/xmlto
	>=dev-util/cmake-2.6
	dev-util/pkgconfig
	x11-proto/xcb-proto
	>=x11-proto/xproto-7.0.11
	doc? (
		app-doc/doxygen
		dev-util/luadoc
		media-gfx/graphviz
	)"

RDEPEND="${RDEPEND}
	app-shells/bash
	|| (
		x11-misc/gxmessage
		x11-apps/xmessage
	)
	|| (
		x11-terms/eterm
		x11-misc/habak
		x11-wm/windowmaker
		media-gfx/feh
		x11-misc/hsetroot
		( media-gfx/imagemagick x11-apps/xwininfo )
		media-gfx/xv
		x11-misc/xsri
		media-gfx/xli
		x11-apps/xsetroot
	)"
#		media-gfx/qiv (media-gfx/pqiv doesn't work)
#		x11-misc/chbg #68116
#	bash-completion? ( app-shells/bash-completion )

DOCS="AUTHORS BUGS PATCHES README STYLE"

src_configure() {
	local myargs="all"

	mycmakeargs="${mycmakeargs}
		-DPREFIX=/usr
		-DSYSCONFDIR=/etc
		$(cmake-utils_use_with dbus DBUS)"

	if use doc ; then
		mycmakeargs="${mycmakeargs} -DGENERATE_LUADOC=ON"
		myargs="${myargs} doc"
	else
		mycmakeargs="${mycmakeargs} -DGENERATE_LUADOC=OFF"
	fi
	cmake-utils_src_configure ${myargs}
}

src_install() {
	cmake-utils_src_install

	if use doc ; then
		(
			cd "${WORKDIR}"/${PN}_build/doc
			mv html doxygen
			dohtml -r doxygen || die
		)
		mv "${D}"/usr/share/doc/${PN}/luadoc "${D}"/usr/share/doc/${PF}/html/luadoc || die
	fi
	rm -rf "${D}"/usr/share/doc/${PN} || die

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}"/${PN}-session ${PN} || die
}