Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Bjarke Istrup Pedersen (gurligebis)" <gurligebis@g.o>
Subject: gentoo-x86 commit in net-irc/psybnc: psybnc-2.3.2.9.ebuild ChangeLog metadata.xml psybnc-2.3.2.7-r2.ebuild
Date: Sun, 14 Dec 2008 18:23:14 +0000
gurligebis    08/12/14 18:23:14

  Modified:             ChangeLog metadata.xml psybnc-2.3.2.7-r2.ebuild
  Added:                psybnc-2.3.2.9.ebuild
  Log:
  Bumping to 2.3.2.9, fixing both #172650 and #246596
  (Portage version: 2.2_rc17/cvs/Linux 2.6.28-rc8 i686)

Revision  Changes    Path
1.8                  net-irc/psybnc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/psybnc/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	6 May 2007 12:41:07 -0000	1.7
+++ ChangeLog	14 Dec 2008 18:23:14 -0000	1.8
@@ -1,6 +1,14 @@
 # ChangeLog for net-irc/psybnc
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/psybnc/ChangeLog,v 1.7 2007/05/06 12:41:07 genone Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/psybnc/ChangeLog,v 1.8 2008/12/14 18:23:14 gurligebis Exp $
+
+*psybnc-2.3.2.9 (14 Dec 2008)
+
+  14 Dec 2008; Bjarke Istrup Pedersen <gurligebis@g.o>
+  +files/psybnc-2.3.2.9-oidentd.patch, +files/oidentd.conf.psybnc,
+  +files/psybnc-oidentd.initd, metadata.xml, psybnc-2.3.2.7-r2.ebuild,
+  +psybnc-2.3.2.9.ebuild:
+  Bumping to 2.3.2.9, fixing both #172650 and #246596
 
   06 May 2007; Marius Mauch <genone@g.o> psybnc-2.3.2.7-r2.ebuild:
   Replacing einfo with elog



1.3                  net-irc/psybnc/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/psybnc/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	26 Feb 2007 00:03:08 -0000	1.2
+++ metadata.xml	14 Dec 2008 18:23:14 -0000	1.3
@@ -6,5 +6,8 @@
 		<email>gurligebis@g.o</email>
 		<name>Bjarke Istrup Pedersen</name>
 	</maintainer>
+	<use>
+		<flag name='oidentd'>Adds support for oidentd</flag>
+	</use>
 	<longdescription>psyBNC is a multi-user and multi-server gateway to IRC networks</longdescription>
 </pkgmetadata>



1.4                  net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild?r1=1.3&r2=1.4

Index: psybnc-2.3.2.7-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- psybnc-2.3.2.7-r2.ebuild	6 May 2007 12:41:07 -0000	1.3
+++ psybnc-2.3.2.7-r2.ebuild	14 Dec 2008 18:23:14 -0000	1.4
@@ -1,6 +1,6 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild,v 1.3 2007/05/06 12:41:07 genone Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.7-r2.ebuild,v 1.4 2008/12/14 18:23:14 gurligebis Exp $
 
 inherit eutils versionator toolchain-funcs
 MY_PV="$(replace_version_separator 3 -)"
@@ -26,9 +26,9 @@
 
 src_unpack() {
 	unpack ${A}
-	cd ${S}
+	cd "${S}"
 
-	epatch ${FILESDIR}/compile.diff
+	epatch "${FILESDIR}/compile.diff"
 
 	# Useless files
 	rm -f */INFO
@@ -84,7 +84,7 @@
 	newinitd "${FILESDIR}"/psybnc.initd psybnc
 	newconfd "${FILESDIR}"/psybnc.confd psybnc
 
-	dodoc CHANGES COPYING FAQ README SCRIPTING TODO
+	dodoc CHANGES FAQ README SCRIPTING TODO
 	docinto example-script
 	dodoc scripts/example/DEFAULT.SCRIPT
 }



1.1                  net-irc/psybnc/psybnc-2.3.2.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.9.ebuild?rev=1.1&content-type=text/plain

Index: psybnc-2.3.2.9.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/psybnc/psybnc-2.3.2.9.ebuild,v 1.1 2008/12/14 18:23:14 gurligebis Exp $

inherit eutils versionator toolchain-funcs flag-o-matic
MY_PV="$(replace_version_separator 3 -)"
PSYBNC_HOME="/var/lib/psybnc"

DESCRIPTION="psyBNC is a multi-user and multi-server gateway to IRC networks"
HOMEPAGE="http://www.psybnc.at/index.html"
SRC_URI="http://www.psybnc.at/download/beta/psyBNC-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="ipv6 ssl oidentd"

DEPEND="ssl? ( >=dev-libs/openssl-0.9.7d )
		oidentd? ( >=net-misc/oidentd-2.0 )"
RDEPEND="${DEPEND}"
S="${WORKDIR}"/"${PN}"

pkg_setup() {
	enewgroup psybnc
	enewuser psybnc -1 -1 ${PSYBNC_HOME} psybnc
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/compile.diff"

	# add oidentd
	use oidentd && epatch "${FILESDIR}/${P}-oidentd.patch"

	# Useless files
	rm -f */INFO

	# Prevent stripping the binary
	sed -i -e "/@strip/ d" tools/autoconf.c

	# Pretend we already have a certificate, we generate it in pkg_config
	mkdir key
	touch key/psybnc.cert.pem

	if [[ -f ${ROOT}/usr/share/psybnc/salt.h ]]
	then
		einfo "Using existing salt.h for password encryption"
		cp "${ROOT}"/usr/share/psybnc/salt.h salt.h
	fi
}

src_compile() {
	use ipv6 || rm -f tools/chkipv6.c
	use ssl || rm -f tools/chkssl.c

	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" || die "emake failed"
}

src_install() {
	dobin psybnc

	insinto /usr/share/psybnc
	doins -r help lang salt.h
	fperms 0600 /usr/share/psybnc/salt.h

	insinto /etc/psybnc
	doins "${FILESDIR}"/psybnc.conf

	keepdir "${PSYBNC_HOME}"/{log,motd,scripts}
	dosym /usr/share/psybnc/lang "${PSYBNC_HOME}"/lang
	dosym /usr/share/psybnc/help "${PSYBNC_HOME}"/help

	fowners psybnc:psybnc "${PSYBNC_HOME}"/{,log,motd,scripts} /etc/psybnc/psybnc.conf
	fperms 0750 "${PSYBNC_HOME}"/{,log,motd,scripts}
	fperms 0640 /etc/psybnc/psybnc.conf

	if use ssl
	then
		keepdir /etc/psybnc/ssl
		dosym /etc/psybnc/ssl "${PSYBNC_HOME}"/key
	else
		# Drop SSL listener from psybnc.conf
		sed -i -e "/^# Default SSL listener$/,+4 d" "${D}"/etc/psybnc/psybnc.conf
	fi

	if use oidentd
	then
		insinto /etc
		doins "${FILESDIR}"/oidentd.conf.psybnc
		fperms 640 /etc/oidentd.conf.psybnc
		# install init-script with oidentd-support
		newinitd "${FILESDIR}"/psybnc-oidentd.initd psybnc
	else
		# install init-script without oidentd-support
		newinitd "${FILESDIR}"/psybnc.initd psybnc
	fi

	newconfd "${FILESDIR}"/psybnc.confd psybnc

	dodoc CHANGES FAQ README SCRIPTING TODO
	docinto example-script
	dodoc scripts/example/DEFAULT.SCRIPT
}

pkg_config() {
	if use ssl
	then
		if [[ -f ${ROOT}/etc/psybnc/ssl/psybnc.cert.pem || -f ${ROOT}/etc/psybnc/ssl/psybnc.key.pem ]]
		then
			ewarn "Existing /etc/psybnc/psybnc.cert.pem or /etc/psybnc/psybnc.key.pem found!"
			ewarn "Remove /etc/psybnc/psybnc.*.pem and run emerge --config =${CATEGORY}/${PF} again."
			return
		fi

		einfo "Generating certificate request..."
		openssl req -new -out "${ROOT}"/etc/psybnc/ssl/psybnc.req.pem -keyout "${ROOT}"/etc/psybnc/ssl/psybnc.key.pem -nodes
		einfo "Generating self-signed certificate..."
		openssl req -x509 -days 365 -in "${ROOT}"/etc/psybnc/ssl/psybnc.req.pem -key "${ROOT}"/etc/psybnc/ssl/psybnc.key.pem -out "${ROOT}"/etc/psybnc/ssl/psybnc.cert.pem
		einfo "Setting permissions on files..."
		chown root:psybnc "${ROOT}"/etc/psybnc/ssl/psybnc.{cert,key,req}.pem
		chmod 0640 "${ROOT}"/etc/psybnc/ssl/psybnc.{cert,key,req}.pem
	fi
}

pkg_postinst() {
	if use ssl
	then
		elog
		elog "Please run \"emerge --config =${CATEGORY}/${PF}\" to create needed SSL certificates."
	fi
	if use oidentd
	then
		elog
		elog "You have enabled oidentd-support. You will need to set"
		elog "up your /etc/oident.conf file before running psybnc. An example"
		elog "for psyBNC can be found under /etc/oident.conf.psybnc."
	fi
	elog
	elog "You can connect to psyBNC on port 23998 with user gentoo and password gentoo."
	elog "Please edit the psyBNC configuration at /etc/psybnc/psybnc.conf to change this."
	elog
	elog "To be able to reuse an existing psybnc.conf, you need to make sure that the"
	elog "old salt.h is available at /usr/share/psybnc/salt.h when compiling a new"
	elog "version of psyBNC. It is needed for password encryption and decryption."
	elog
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in sys-kernel/gentoo-sources: ChangeLog gentoo-sources-2.6.27-r6.ebuild
Next by thread:
gentoo-x86 commit in net-irc/psybnc/files: psybnc-oidentd.initd oidentd.conf.psybnc psybnc-2.3.2.9-oidentd.patch
Previous by date:
gentoo-x86 commit in profiles: ChangeLog use.local.desc
Next by date:
gentoo-x86 commit in net-irc/psybnc/files: psybnc-oidentd.initd oidentd.conf.psybnc psybnc-2.3.2.9-oidentd.patch


Updated Jan 18, 2011

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.