Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Julian Ospald (hasufell)" <hasufell@g.o>
Subject: gentoo-x86 commit in games-fps/urbanterror: metadata.xml ChangeLog urbanterror-4.1.1.ebuild Manifest
Date: Thu, 24 May 2012 23:37:47 +0000 (UTC)
hasufell    12/05/24 23:37:47

  Added:                metadata.xml ChangeLog urbanterror-4.1.1.ebuild
                        Manifest
  Log:
  initial import wrt #203296 thanks to Mr_Bones_
  
  (Portage version: 2.2.0_alpha107/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  games-fps/urbanterror/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>games</herd>
	<maintainer>
		<email>hasufell@g.o</email>
		<name>Julian Ospald</name>
	</maintainer>
	<use>
		<flag name="server">Build server target</flag>
	</use>
</pkgmetadata>



1.1                  games-fps/urbanterror/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for games-fps/urbanterror
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/urbanterror/ChangeLog,v 1.1 2012/05/24 23:37:46 hasufell Exp $

*urbanterror-4.1.1 (24 May 2012)

  24 May 2012; Julian Ospald <hasufell@g.o> +urbanterror-4.1.1.ebuild,
  +files/urbanterror-4.1.1-build.patch, +files/urbanterror-4.1.1-minizip.patch,
  +metadata.xml:
  initial import wrt #203296 thanks to Mr_Bones_




1.1                  games-fps/urbanterror/urbanterror-4.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/urbanterror-4.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/urbanterror-4.1.1.ebuild?rev=1.1&content-type=text/plain

Index: urbanterror-4.1.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/urbanterror/urbanterror-4.1.1.ebuild,v 1.1 2012/05/24 23:37:46 hasufell Exp $

EAPI=3

inherit eutils games

MY_PV=${PV//./}
IOQ3_SVN=1807
IOQ3_PATCH=ioq3-${IOQ3_SVN}-urt-251210-git-nobumpy

DESCRIPTION="Hollywood tactical shooter based on the ioquake3 engine"
HOMEPAGE="http://www.urbanterror.info/home/"
SRC_URI="http://dev.gentoo.org/~hasufell/distfiles/ioquake3-${IOQ3_SVN}.tar.bz2
	http://dev.gentoo.org/~hasufell/distfiles/${IOQ3_PATCH}.tar.xz
	ftp://ftp.snt.utwente.nl/pub/games/${PN}/old/UrbanTerror_${MY_PV:0:2}_FULL.zip
	http://upload.wikimedia.org/wikipedia/en/5/56/Urbanterror.svg -> ${PN}.svg"

LICENSE="GPL-2 Q3AEULA"
SLOT="0"
KEYWORDS="~amd64 ~x86 -*"
IUSE="+curl dedicated openal server speex vorbis"

RDEPEND="
	sys-libs/zlib[minizip]
	!dedicated? (
		media-libs/ftgl
		media-libs/freetype
		media-libs/libsdl[X,opengl]
		virtual/opengl
		curl? ( net-misc/curl )
		openal? ( media-libs/openal )
		speex? ( media-libs/speex )
		vorbis? ( media-libs/libogg media-libs/libvorbis )
	)"
# server target needs libsdl and some 
# other headers for build-time
# added them for dedicated useflag
DEPEND="${RDEPEND}
	app-arch/unzip
	virtual/pkgconfig
	dedicated? (
		media-libs/libsdl
		curl? ( net-misc/curl )
		speex? ( media-libs/speex )
	)"

S=${WORKDIR}/ioquake3

src_prepare() {
	epatch "${FILESDIR}"/${P}-minizip.patch \
		"${WORKDIR}"/${IOQ3_PATCH}.patch \
		"${FILESDIR}"/${P}-build.patch

	# unbundle
	rm -r code/zlib || die
	rm code/qcommon/unzip.{c,h}  || die
	rm code/qcommon/ioapi.{c,h}  || die
	rm -r code/{FTGL,FT2,SDL12,libs/win32} || die

	# set svn version
	sed \
		-e 's/SVN_REV=$(shell LANG=C svnversion .)/SVN_REV='${IOQ3_SVN}'M/' \
		-i Makefile || die "setting svn version failed"

	# fix case sensitivity
	mv "${WORKDIR}/UrbanTerror/q3ut4/demos/tutorial.dm_68" \
		"${WORKDIR}/UrbanTerror/q3ut4/demos/TUTORIAL.dm_68" || die
}

src_compile() {
	buildit() { use $1 && echo 1 || echo 0 ; }
	nobuildit() { use $1 && echo 0 || echo 1 ; }

	emake \
		ARCH=$(usex amd64 "x86_64" "i386") \
		DEFAULT_BASEDIR="${GAMES_DATADIR}/${PN}" \
		BUILD_CLIENT=$(nobuildit dedicated) \
		BUILD_CLIENT_SMP=$(nobuildit dedicated) \
		BUILD_SERVER=$(usex dedicated "1" "$(buildit server)") \
		USE_CODEC_VORBIS=$(buildit vorbis) \
		USE_VOIP=$(buildit speex) \
		USE_OPENAL=$(buildit openal) \
		USE_CURL=$(buildit curl) \
		USE_INTERNAL_SPEEX=0 \
		USE_INTERNAL_ZLIB=0 \
		USE_LOCAL_HEADERS=0 \
		OPTIMIZEVM="" \
		Q="" \
		release || die
}

src_install() {
	local my_arch=$(usex amd64 "x86_64" "i386")

	insinto /usr/share/icons/hicolor/scalable/apps
	doins "${DISTDIR}"/${PN}.svg

	dodoc ChangeLog NOTTODO README TODO {md4,voip}-readme.txt

	insinto "${GAMES_DATADIR}"/${PN}/q3ut4
	doins -r "${WORKDIR}"/UrbanTerror/q3ut4/{*.pk3,demos/,description.txt} || die

	if use !dedicated ; then
		newgamesbin build/release-linux-${my_arch}/ioquake3-smp.${my_arch} ${PN} || die
		make_desktop_entry ${PN} "UrbanTerror"
	fi

	if use dedicated || use server ; then
		newgamesbin build/release-linux-${my_arch}/ioq3ded.${my_arch} ${PN}-dedicated || die
		newins "${WORKDIR}"/UrbanTerror/q3ut4/mapcycle.txt mapcycle.txt.example || die
		newins "${WORKDIR}"/UrbanTerror/q3ut4/server.cfg q3config_server.cfg.example || die
	fi

	prepgamesdirs
}



1.1                  games-fps/urbanterror/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-fps/urbanterror/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
AUX urbanterror-4.1.1-build.patch 970 RMD160 b6d6b0a1ff10eae81b94afa70af3c3b4109a6047 SHA1 18060bca56cf103404393a11458e5b4ef1c9615f SHA256 686f183961c0ec1690696a64785bba7dbf38f7f8cf78d4cc6f8b403698342542
AUX urbanterror-4.1.1-minizip.patch 773 RMD160 e8e70690da9ac6f433c1bb7e07e2c7f821de9bc4 SHA1 d333733aece4944fae3c29cca358c9b433c41cc2 SHA256 0e6a1144bbc47c1dfcad6565c9bb7eb07b843992a0da673644d25cc08b32df9b
DIST UrbanTerror_41_FULL.zip 754307397 RMD160 e7b46b8b70364f1556f057ab9adb35a54bd2b9a2 SHA1 bbe4262bc46f3ef43525ef338bdda05debf3e2c4 SHA256 5706957783d0e4e77fcc4bbbc2df83aefc0f9a6388f6a63b60947e84f9ed265f
DIST ioq3-1807-urt-251210-git-nobumpy.tar.xz 276824 RMD160 598293efce60617b75bfc4df4c1167d2a3e3614d SHA1 88151fea0323f96c762f62af2b13fcfef3bde4c8 SHA256 9f14d629f2a9c8fe0a593b5a08d1ceadec6a22c387806d9e5f50e22a537c2b74
DIST ioquake3-1807.tar.bz2 7054317 RMD160 6623385aa294907452816febdecfa5658eac8b17 SHA1 8470d58ac60da14b1e86d5944f1cd32198ab2baf SHA256 10d3fcee3cf41a063e686048740417c8d58496f3dff5745f897a8803318850c2
DIST urbanterror.svg 1592 RMD160 dd7cbf6216cc623fa9a14e0c384d662aa45657fb SHA1 6819d4d3d772fc4c7fe5004d17c8fc0a1cb46cab SHA256 0d7eb12a8fe8380e0d89199621414dd56ecdfe8a8b99eec5b95d925294521de9
EBUILD urbanterror-4.1.1.ebuild 3285 RMD160 a030023639b13266b9596eb48546ce1f66c863f7 SHA1 f2e62e3bbcf20c4b60a2cc91f35fc3186e2dd621 SHA256 21782dd1eb03c98f377c02c23580d7347c804e54a9ef61c2f16a359efb9c9cef
MISC ChangeLog 381 RMD160 94d9a7cb92c73c62ff341a9590b4d6dc67960451 SHA1 cf051bff69429d2b23dfbd58aa9925d4d58f1a02 SHA256 6ddac2445c3aac29c835415014266cbed274134316da6785d746d58898e8eacd
MISC metadata.xml 318 RMD160 00348c6cc873cad7f935bdfb1b8980fd56f83ccb SHA1 4cde241e5ede17b342532a615e156ebbadab3cfc SHA256 b92be79db64aa9495fc0540dcb2e8744d440938bc3fdf7a20fcc7ad2d45b084c





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in games-fps/urbanterror/files: - New directory
Next by thread:
gentoo-x86 commit in games-fps/urbanterror/files: urbanterror-4.1.1-minizip.patch urbanterror-4.1.1-build.patch
Previous by date:
gentoo-x86 commit in games-fps/urbanterror/files: - New directory
Next by date:
gentoo-x86 commit in games-fps/urbanterror/files: urbanterror-4.1.1-minizip.patch urbanterror-4.1.1-build.patch


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.