[gentoo-commits] gentoo-x86 commit in sys-power/cpufrequtils: ChangeLog cpufrequtils-008.ebuild

[Mike Frysinger (vapier)]

vapier      10/07/05 19:43:34

  Modified:             ChangeLog
  Added:                cpufrequtils-008.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.51                 sys-power/cpufrequtils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufrequtils/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufrequtils/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufrequtils/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/cpufrequtils/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	31 Mar 2010 21:32:11 -0000	1.50
+++ ChangeLog	5 Jul 2010 19:43:34 -0000	1.51
@@ -1,6 +1,11 @@
 # ChangeLog for sys-power/cpufrequtils
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufrequtils/ChangeLog,v 1.50 2010/03/31 21:32:11 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufrequtils/ChangeLog,v 1.51 2010/07/05 19:43:34 vapier Exp $
+
+*cpufrequtils-008 (05 Jul 2010)
+
+  05 Jul 2010; Mike Frysinger <vapier@g.o> +cpufrequtils-008.ebuild:
+  Version bump.
 
   31 Mar 2010; Jonathan Callen <abcd@g.o> cpufrequtils-007.ebuild:
   Bump to EAPI=3, add prefix keywords



1.1                  sys-power/cpufrequtils/cpufrequtils-008.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufrequtils/cpufrequtils-008.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufrequtils/cpufrequtils-008.ebuild?rev=1.1&content-type=text/plain

Index: cpufrequtils-008.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufrequtils/cpufrequtils-008.ebuild,v 1.1 2010/07/05 19:43:34 vapier Exp $

EAPI="3"

inherit eutils toolchain-funcs multilib

DESCRIPTION="Userspace utilities for the Linux kernel cpufreq subsystem"
HOMEPAGE="http://www.kernel.org/pub/linux/utils/kernel/cpufreq/cpufrequtils.html"
SRC_URI="mirror://kernel/linux/utils/kernel/cpufreq/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="debug nls"

DEPEND="sys-fs/sysfsutils"

ft() { use $1 && echo true || echo false ; }

src_prepare() {
	epatch "${FILESDIR}"/${PN}-007-build.patch
	epatch "${FILESDIR}"/${PN}-007-nls.patch #205576 #292246
}

src_configure() {
	export DEBUG=$(ft debug) V=true NLS=$(ft nls)
	unset bindir sbindir includedir localedir confdir
	export mandir="${EPREFIX}/usr/share/man"
	export libdir="${EPREFIX}/usr/$(get_libdir)"
	export docdir="${EPREFIX}/usr/share/doc/${PF}"
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		LD="$(tc-getCC)" \
		AR="$(tc-getAR)" \
		STRIP=: \
		RANLIB="$(tc-getRANLIB)" \
		LIBTOOL="${EPREFIX}"/usr/bin/libtool \
		INSTALL="${EPREFIX}"/usr/bin/install \
		|| die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README

	newinitd "${FILESDIR}"/${PN}-init.d-006 ${PN} || die
	newconfd "${FILESDIR}"/${PN}-conf.d-006 ${PN}
}